Autres Problème d'étoiles à supprimer lors d'un scan avec douchette

[a26]

Bonjour,
Lors d'un scan de code barre 39 le résultat chiffré apparaît avec une étoile avant et après le chiffre.
Comme ceci : *25* alors que j'aimerai seulement 25
Des membres du forum m'ont donné une worksheet change qui ne fonctionne pas pour une variable non définie.
Pouvez-vous me conseiller sur ce problème.
Merci beaucoup.
a26

 

[job75]

Bonjour a26,

Dans le code de la feuille où s'inscrivent les résultats collez cette macro :

Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
Cells.Replace "~*", "", xlPart
Application.EnableEvents = True
End Sub

La plage où s'inscrivent les résultats est à mettre au format Texte s'il y a des nombres commençant par zéro.

A+

 

[sylvanu]

Bonjour A26,
Un essai en PJ avec :

Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, Range("D5")) Is Nothing Then
        If Left(Target, 1) = "*" And Right(Target, 1) = "*" Then
            Application.EnableEvents = False
            Range(Target.Address) = Val(Mid(Target, 2, Len(Target) - 1))
            Application.EnableEvents = True
        End If
    End If
End Sub

Le Application.EnableEvents = False évite de boucler sur la macro puisque la macro écrit dans l'adress qui l'a appelée.

 

[a26]

Merci job75 c'est impeccable.
Peux-tu me rajouter le code qui m'informe d'un seuil chiffré à ne pas dépasser qui se trouve en G2 ceci en cas d'erreur de scan.

 

[a26]

Merci sylvanu pour ta proposition qui fonctionne très bien aussi dans ta pièce jointe mais qui ne fonctionne pas dans mon classeur. Je dois oublier quelque chose ?

 

[job75]

Pour avertir quand la valeur en G2 est dépassée :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim maxi#
maxi = Val(Replace([G2], ",", "."))
Application.EnableEvents = False
Cells.Replace "~*", "", xlPart
Set Target = Intersect(Target, UsedRange)
If Not Target Is Nothing Then
    For Each Target In Target 'si entrées multiples
        If IsNumeric(Target) Then If CDbl(Target) > maxi Then Target.Select: MsgBox "Limite " & maxi & " dépassée !", 48: Exit For
    Next
End If
Application.EnableEvents = True
End Sub

 

[job75]

J'ai corrigé le post #6 pour le calcul de maxi et CDbl va mieux que Val.

 

[a26]

Un très très grand merci job75. Cela fonctionne impeccablement bien.
Bonne fin de journée,
a26

 

[a26]

Si j'ai bien compris écrire maxi = CDbl ???

 

[job75]

Si j'ai bien compris écrire maxi = CDbl ???

Non, CDbl s'utilise quand on sait que la variable (Target) est numérique.

G2 peut ne pas être numérique c'est pourquoi j'utilise la fonction Val (avec Replace).