Problème de format de date qui reste en texte

[Chris57]

Bonjour à tous,

je suis sur que ce pb a déjà été évoqué sur le forum mais pas moyen de remettre la main dessus :
j'ai un fichier excel qui récupère des données de ma station météo toutes les 5 min.
La date et l'heure du relevés sont sous la forme :

Colonne A Colonne B
DATE HEURE
20100417 102417
20100417 102917
20100417 103838
20100417 104338
20100417 104838
20100417 105338
20100417 105838
20100417 110338
20100417 110838
20100417 111338
20100417 111838
20100417 112338
20100417 112838
20100417 113338
20100417 113838
20100417 114338
20100417 114838
20100417 115338
20100417 115838
20100417 120338
20100417 120838


J'aimerai récupérer ça sous le format jj/mmmm/aaaa h:mm;@
J'ai donc mis ceci dans une formule de ce type

=(DROITE(A5;2) & "/" & GAUCHE(DROITE(A5;4);2) &"/"& GAUCHE(A5;4))+((B5*$BN$1)/500)

mais le résultat est en format texte et n'est pas reconnu par excel comme une date.

Quelqu'un a une idée ?

 

[jeanpierre]

Re : Problème de format de date qui reste en texte

Bonjour Chris57,

Pas testé, mais avec et si ta formule est bonne :

=((DROITE(A5;2) & "/" & GAUCHE(DROITE(A5;4);2) &"/"& GAUCHE(A5;4))+((B5*$BN$1)/500))*1

Sinon, dépose un exemple pour travailler sur du concret.

Bon dilmanche.

Jean-Pierre

 

[JCGL]

Re : Problème de format de date qui reste en texte

Bonjour à tous,

Peux-tu essayer avec :

=(DROITE(A2;2) & "/" & STXT(A2;5;2)&"/"& GAUCHE(A2;4)&" "&GAUCHE(B2;2)&":"&STXT(B2;3;2)&":"&DROITE(B2;2))*1

Au format : jj/mm/aaaa hh:mm:ss

A+ à tous

 

[Tibo]

Re : Problème de format de date qui reste en texte

Bonjour,

Une autre approche avec :

=TEXTE(GAUCHE(A1;8);"0000-00-00")+TEXTE(DROITE(A1;6);"00"":""00"":""00")

à tester quand même

@+

Edit : mal lu, j'ai cru que les données étaient dans une seule colonne ...

@+

Edit :

Formule adaptée :

=TEXTE(A1;"0000-00-00")+((B1*$BN$1)/500)

avec le format adapté

pas compris le calcul (B1*$B$N1)/500 ...

@+

 

[piga25]

Re : Problème de format de date qui reste en texte

Bonjour à tous

Salut JCGL

Un essai avec si toutes les données sont en colonne A.

=(DROITE(A2;2) & "/" & STXT(A2;5;2)&"/"& GAUCHE(A2;4)&" "&GAUCHE(A2;2)&":"&STXT(A2;3;2)&":"&DROITE(A2;2))*1

Edit
Comme tibo mal lu pensai que tout était en colonne A.
La solution de JCGL fonctionne

 

[JCGL]

Re : Problème de format de date qui reste en texte

Bonjour à tous,
Salut Piga,
Salut Tibo,

Juste pour saluer Patrick 🙂 et Tibo 🙂 et leur dire que notre autre Forum préféré est en pleine mutation donc quelques soucis en vue... Arf... Arf... (passage de .net en .fr. Vincent est à l'œuvre mais il n'a pas forcément le temps nécessaire...)

A++ les 🙂
A+ à tous

 

[piga25]

Re : Problème de format de date qui reste en texte

Bonjour à tous,
Salut JCGL,

Pas de de soucis pour l'autre Forum, je m'en doutais un peu.
Bon courage à Vincent.

 

[ROGER2327]

Re : Problème de format de date qui reste en texte

Bonjour à tous

Une proposition calculée (i.e. sans manipulation de chaînes de caractères) :

[COLOR="DarkSlateGray"][B]=DATE(ENT(C1/10000);(MOD(C1;10000)-MOD(C1;100))/100;MOD(C1;100))+((MOD(D1;100)/3+(MOD(D1;10000)-MOD(D1;100))/5)/1200+ENT(D1/10000))/24[/B][/COLOR]

ROGER2327
#3201

 

[Chris57]

Re : Problème de format de date qui reste en texte

Merci à tous pour votre aide précieuse !!! Effectivement la date est en colonne A et l'heure en colonne B.

Mais ROGER2327, je comprends pas ta formule qui récupère des données en C1...


Sinon j'ai testé les
=TEXTE(A5;"0000-00-00")+((B5*$BN$1)/500)

ainsi que
=TEXTE(GAUCHE(A6;8);"0000-00-00")+TEXTE(DROITE(A6;6);"00"":""00"":""00")

et ça marche, excel les considère bien comme des dates !! Génial !!


Par contre je me suis trompé avec les heures : le forum du logiciel en question m'a exliqué que par exemple 102417 correspond à 10h24 et 17 sec

Il va falloir que je trouve un moyen d'extraire heure et minute de ces valeurs (les secondes importe peu)

 

[Chris57]

Re : Problème de format de date qui reste en texte

J'ai trouvé avec la formule de Piga25 :
=(GAUCHE(B5;2)&":"&STXT(B5;3;2)&":"&DROITE(B5;2))*1

et ça fontionne !!
En fait l'astuce est le *1 qui permet de revalider la cellule !

 

[ROGER2327]

Re : Problème de format de date qui reste en texte

Re...

(...) Mais ROGER2327, je comprends pas ta formule qui récupère des données en C1... (...)

Etourderie de ma part ! Il s'agit des colonnes A et B au lieu de C et D :

[COLOR="DarkSlateGray"][B]=DATE(ENT(A1/10000);(MOD(A1;10000)-MOD(A1;100))/100;MOD(A1;100))+((MOD(B1;100)/3+(MOD(B1;10000)-MOD(B1;100))/5)/1200+ENT(B1/10000))/24[/B][/COLOR]

ROGER2327
#3202

 

[JCGL]

Re : Problème de format de date qui reste en texte

Bonjour à tous,

J'ai trouvé avec la formule de Piga25 :

=(GAUCHE(B5;2)&":"&STXT(B5;3;2)&":"&DROITE(B5;2))*1

Il me semble que je t'avais soumis cette proposition à 13:00...

A+ à tous

 

[Chris57]

Re : Problème de format de date qui reste en texte

Effectivement, mais je suis au boulot là, en poste de midi, et je n'ai pas eu le temps de me connecter avant... et là j'ai lu trop vite les réponses et j'ai du sauter la tienne...

désolé !!!


Encore merci à tous !!

 

[Tibo]

Re : Problème de format de date qui reste en texte

re,

en reprenant les propositions faites en début d'après midi :

=TEXTE(A1;"0000-00-00")+TEXTE(B1;"00"":""00"":""00")

Ca donne également le bon résultat

@+

 

[JCGL]

Re : Problème de format de date qui reste en texte

Message annulé...