Probleme avec SOMMEPROD

[bobjazz]

Bonjour le Forum

J'ai un souci avec la fonction
dans une cellule j'ai
=SOMMEPROD((O$9:O$77=$G$6:$M$6)*($G$9:$M$77))
Cela fonctionne trés bien, mais je voudrais faire le calcul suivant
=SOMMEPROD((O$70:BN$70=$G$6:$M$6)*($G$70:$M$70))
pour remplacer cette fonction
=(NB.SI(O70:BN70;"MS")*G70)+(NB.SI(O70:BN70;"I")*H70)+(NB.SI(O70:BN70;"E1")*I70)+(NB.SI(O70:BN70;"E2")*J70)*(NB.SI(O70:BN70;"E3")*K70)+(NB.SI(O70:BN70;"R")*L70)+(NB.SI(O70:BN70;"MA")*M70)
qui se met à buguer depuis que j'ai 7 SI.
je pense que c'est que je compare 2 lignes et non 1 ligne avec une colonne, mais je n'arrive pas

Dans mon fichier j'ai reduit le nombre de lignes
Merci pour l'aide
bobjazz

 

[2passage]

Re : Probleme avec SOMMEPROD

Bonjour,

Ligne ou colonne, ça n'a pas d'importance, mais il me semble qu'il faut que les matrices aient le même nombre de valeurs :
O$70:BN$70 (52 cellules) = $G$6:$M$6 (7 cellules)

J'ai essayé de m'y retrouver dans ton fichier exemple, mais les colonnes ont dû changer et j'ai un peu de mal.

A plus

 

[Monique]

Re : Probleme avec SOMMEPROD

Bonjour,

Je ne peux plus ouvrir les .zip depuis… aujourd'hui

Fais un essai comme ça (c'est du pifomètre, sans fichier) :
=SOMMEPROD(NB.SI(O$70:BN$70;$G$6:$M$6)*1;$G$70:$M$70)

avec les codes MS, I, E1, E2, E3, R et MA en G6:M6
en ayant saisi
des MS, I, E1, E2, E3, R et MA éparpillés en O70:BN70
et des nombres en G70:M70

 

[bobjazz]

Re : Probleme avec SOMMEPROD

Bonjour Monique et 2passage

Même sans ZIP et le pifomètre fonctionne toujours aussi bien, parfait

Peux tu expliquer "NB.SI(O$70:BN$70;$G$6:$M$6)*1" dans ta fonction STP
Si tu peux

Merci à vous deux et au forum

bobjazz

 

[Monique]

Re : Probleme avec SOMMEPROD

Re,

C'est au cas où il y aurait du texte dans certaines cellules en O70:BN70
Le résultat est rendu numérique.
C'était du pifomètre prévisionnel

Une toute petite plage, du texte en C5
=SOMMEPROD(NB.SI(D5:H5;A1:C1)*1;A5:C5)
ça donne :
=SOMMEPROD({3.1.0}*1;{2.4."Zz"})

Mais celle-ci marche aussi :
=SOMMEPROD(NB.SI(D5:H5;A1:C1);A5:C5)
Elle donne =SOMMEPROD({3.1.0};{2.4."r"})

Par contre celle-ci ne fonctionne pas s'il y a du texte en C5 par exemple :
=SOMMEPROD(NB.SI(D5:H5;A1:C1)*A5:C5)
=SOMMEPROD({3.1.0}*{2.4."Zz"})
0*Zz, ça ne va pas

 

[bobjazz]

Re : Probleme avec SOMMEPROD

RE Monique

Merci pour ton explication, mais honnêtement je vais bien la décortiquer ce soir, pas tout compris

Merci encore pour ta patience et celle du Forum


bobjazz