XL 2016 Présence dans un intervalle

[fabriciolig]

Bonjour,

je cherche une formule me permettant d'indiquer la présence d'un individu ayant fait un test;

Dans mon exemple, la personne ACTHERGALLE est venue plusieurs fois (cf. premier tableau) mais sur le deuxième petit tableau à droite en bleu on voit que le test a été réalisé le 22/11/2023. Je cherche donc une formule qui me permet d"indiquer la venue dans laquelle elle a fait ce test dans le premier tableau
J'espère que cela est clair
En vous remerciant par avance

David

 

[Lolote83]

Bonjour,
En cellule L2=INDEX($E$2:$E$22;EQUIV(J2;$C$2:$C$22;0))
Si j'ai bien compris
@+ Lolote83

 

[fabriciolig]

Bonjour,
En cellule L2=INDEX($E$2:$E$22;EQUIV(J2;$C$2:$C$22;0))
Si j'ai bien compris
@+ Lolote83

Merci pour votre retour rapide,
cela ne marche pas tout à fait d'autant que dans mon exemple les dates de début et de fin sont identiques mais il arrive parfois que ces deux dates soient différentes. Il faut donc inclure également une notion de date de test supérieure à date de début et date de test inférieure à date de fin

Merci
David

 

[Lolote83]

Re bonjour,
Pourrait-on avoir dans ce cas un exemple plus précis avec des données correspondant plus à la réalité avec aussi le résultat souhaité.
@+ Lolote83

 

[chris]

Bonjour
Les dates des 2 tableaux sont en fait des textes : il faut commencer par les convertit en date

Ensuite ceci en G2, à étirer vers le bas fonctionne

=NB.SI.ENS($J$2:$J$5;C2;$K$2:$K$5;D2;$L$2:$L$5;">="&E2;$L$2:$L$5;"<="&F2)

Utiliser 2 tableaux structurés serait mieux :

Cela donnerait une formule se propageant automatiquement et une évolutivité

=NB.SI.ENS(Tests[NOM];[@NOM];Tests[PRENOM];[@PRENOM];Tests[DATETPT];">="&[@DEBUT];Tests[DATETPT];"<="&[@FIN])

EDIT
Si tu veux la date une autre formule dépend de ta version EXCEL

pour 2019 et plus

=FILTRE(Tests[DATETPT];(Tests[NOM]=[@NOM])*(Tests[PRENOM]=[@PRENOM])*(Tests[DATETPT]>=[@DEBUT])*(Tests[DATETPT]<=[@FIN]);"")

 

[fabriciolig]

Bonjour, merci pour votre retour, oui c'est exactement cela que je recherchais ! un grand merci à la fois pour votre aide et aussi pour les précieux conseils !
C'est vraiment top !

David

 

[Lolote83]

Re bonjour,
Houlà, je crois que je suis totalement à coté de la plaque, je n'avais pas compris la demande
Heureusement que @chris est passé par là
@+ Lolote83

 

[chris]

RE
Voir mes corrections dans le message et le changement de la pièce jointe

Je viens de voir que tu as 2016 donc la formule pour récupérer la date devient :

=SIERREUR(SI(ET(DECALER(Tests[[#En-têtes];[DATETPT]];EQUIV([@NOM]&[@PRENOM];Tests[NOM]&Tests[PRENOM];0);0)>=[@DEBUT];DECALER(Tests[[#En-têtes];[DATETPT]];EQUIV([@NOM]&[@PRENOM];Tests[NOM]&Tests[PRENOM];0);0)<=[@FIN]);DECALER(Tests[[#En-têtes];[DATETPT]];EQUIV([@NOM]&[@PRENOM];Tests[NOM]&Tests[PRENOM];0);0);"");"")