Pourquoi cette formule retour 0?

[XGuarden]

Bonjours.
LA formule suivante retourne 14
=SOMME(SI(NomEleveGarde=$A38;GardeLundi))

La formule suivante retourne 21
=SOMME(SI(SemaineGarde=$A$5;GardeLundi))

Maos la formule suivante retourne 0
=SOMME(SI(ET(NomEleveGarde=$A38;SemaineGarde=$A$5;GardeLundi);GardeLundi))

Pourtant, il y a des donnée et je valdie corectement mes formule matriciel.

Qui peu m'expliquer pourquoi sa ne fonctionner pas? MErci d'avance

 

[Sylvie]

Bonsoir XGuarden, le forum

ne pourrais tu pas nous adresser un fichier pour comprendre sur pièce ?
(Ca serait tellement plus facile pour nous pauvres lecteurs)

Merci

 

[XGarden]

Si tu verrai le fichier en question, tu passerai plsu de temps a essyer de le ocmprendre qu'a essyer de résoudre le probleme tellement il est en bon chinois lol.

Nah mais je me dit que se probleme doit simplment etre une erreur de logique. Si toutefois ta besoin d'un fichier, je peu en fournir un. Mais je doute que sa soit d'une grande utilité pour ce cas si.

 

[Monique]

Re,

A mon avis, (mais sans fichier, on joue aux devinettes)
le nom de A38 est sur la même ligne que le 14
la semaine garde de A5 est sur la même ligne que le 21
Et ce sont 2 lignes différentes

Pour la 1ère, tu aurais la même chose avec :
=SOMMEPROD((NomEleveGarde=$A38)*1;GardeLundi)
=SOMMEPROD((NomEleveGarde=$A38)*GardeLundi)
=SOMME.SI(NomEleveGarde;$A38;GardeLundi)

Pour la 2ème :
=SOMMEPROD((SemaineGarde=$A$5)*1;GardeLundi)
=SOMMEPROD((SemaineGarde=$A$5)*GardeLundi)
=SOMME.SI(SemaineGarde;$A$5;GardeLundi)

Pour la 3ème :
=SOMMEPROD((NomEleveGarde=$A38)*(SemaineGarde=$A$5);GardeLundi)
La 3ème à valider en matriciel :
=SOMME(SI(NomEleveGarde=$A38;SI(SemaineGarde=$A$5;GardeLundi)))
=SOMME(SI((NomEleveGarde=$A38)*(SemaineGarde=$A$5);GardeLundi))

 

[XGarden]

Nice =:0) Et vitesse d'éxécution?

 

[AV]

Ave,

=SOMME(SI(ET(NomEleveGarde=$A38;SemaineGarde=$A$5;GardeLundi);GardeLundi))
''...Qui peu m'expliquer pourquoi sa ne fonctionner pas?..''

La raison est que la fonction ET (pas plus que OU d'ailleurs) ne se prête aux calculs matriciels.
Tu as donc une erreur de syntaxe !
Les alternative pourraient être (selon les types de données dans les plages) :
Validations matricielles :
=SOMME(SI((NomEleveGarde=$A38)*(SemaineGarde=$A$5);GardeLundi;''))
=SOMME((NomEleveGarde=$A38)*(SemaineGarde=$A$5)*(GardeLundi))
Validation normale :
=SOMMEPROD((NomEleveGarde=$A$38)*(SemaineGarde=$A$5);GardeLundi)

AV [aaa]