Position de la dernière valeur d'une ligne

[ThunderPaT]

Bonjour à tous,
j'aimerais savoir s'il existe une formule permettant de trouver le mois en cours dans le fichier en exemple ci-joint.

Merci d'avance !! 😉

 

[Tibo]

Re : Position de la dernière valeur d'une ligne

Bonjour,

Une solution avec une formule matricielle :

=DROITE(INDEX($A$1:$O$1;MAX((D2:O2<>"")*(COLONNE($D$2:$O$2))));2)*1

Formule matricielle à valider par CTRL + MAJ + ENTREE

@+

 

[2passage]

Re : Position de la dernière valeur d'une ligne

Bonjour,

Pas mieux, formule matricielle aussi :

=MAX(COLONNE(D2:O2)*SI(D2:O2<>"";1;0))-3

le -3 est pour faire correspondre le mois à la colonne (janvier = colonne 4... etc...)

++

 

[tototiti2008]

Re : Position de la dernière valeur d'une ligne

Bonjour ThunderPat, Bonjour Tibo,

ça a l'air de marcher :

=CNUM(DROITE(RECHERCHE(9^9;D2:O2;D$1:O$1);2))

même si je ne sais pas trop si RECHERCHE réagit toujours bien...

Edit : Bonjour 2passage

 

[Raja]

Re : Position de la dernière valeur d'une ligne

Bonjour, Salut Tibo,

Une solution sans la forme matricielle :

=DROITE(INDEX($D$1:$O$1;EQUIV(RECHERCHE(9^9;$D$2:$O$2);$D$2:$O$2;0));2)

édit : salut 2passage, tototiti2008

 

[abcd]

Re : Position de la dernière valeur d'une ligne

Bonjour, salut 2passage, Tibo et tototiti,

Autre possibilité (non matricielle) :
=EQUIV(RECHERCHE(9^9;D2:O2);D2:O2;0)

abcd

 

[ThunderPaT]

Re : Position de la dernière valeur d'une ligne

Merci et bonjour à tous,

toutes ces solutions marchent (félicitation !! 🙂 ) mais je vais garder celle de "abcd" qui est la plus simple à utiliser.

Encore merci !!!! 😀

 

[ThunderPaT]

Re : Position de la dernière valeur d'une ligne

Re tous !!

en faite j'ai trouvé un pb avec les formules, je m'explique.

Si on met : 0,5 en septembre et en novembre => resultat = 9 (donc pb on devrait avoir 11)

Par contre si on met : 0,5 en septembre et 0,1 en novembre => résultat = 11 ( ??? pourquoi dans ce cas là ça marche ??)

Je suis perplexe et je ne comprend pas pourquoi.... Et vous ?

tototiti2008 => Ta formule marche dans tous les cas !!! bravo 🙂

 

[Tibo]

Re : Position de la dernière valeur d'une ligne

re,

Tout petit détail, la formule de abcd est plus pratique, mais en cas de présence de doublons, la formule EQUIV va retourner le rang de la 1ère valeur égale à la dernière.

Reste donc à voir s'il peut ou pas y avoir des doublons

Bonne soirée à tous

@+

 

[ThunderPaT]

Re : Position de la dernière valeur d'une ligne

Ok merci de l'explication !!

Bon je vais utiliser la formule de "tototiti2008" pour plus de sécurité 🙂

Merci pour la rapidité des réponses et bonne soirée à tous !!

@+

 

[abcd]

Re : Position de la dernière valeur d'une ligne

Salut à vous tous,

Tibo, je crois qu'il se fait tard et qu'un peu de sommeil te ferait du bien (lol).
As-tu essayé ma formule avec des doublons ?

Le problème avec les formules de 2passage et de Tibo est que c'est la valeur max qui est cherchée.
Il faut donc que les valeurs en ligne 2 soient triées en ordre croissant pour obtenir le bon résultat, ce qui était le cas (hazard ?) pour l'exemple initial.

La différence entre la formule de tototiti et la mienne est que celle de tototiti récupère le numéro du mois en ligne 1, alors que j'avais remarqué que le numéro du mois était le même que celui de la colonne dans le tableau D :O.
D'où formule plus courte.


abcd

 

[Tibo]

Re : Position de la dernière valeur d'une ligne

Bonjour abcd,

J'ai refait un essai avec le fichier de ThunderPat en mettant 0,16 dans les cellules suivantes : H2, I2 et K2

Donc présence de doublons.

Dans ce cas, ta formule s'arrête bien sur le premier 0,16 trouvé et va retourner 5 comme résultat.

La formule que j'avais proposé (matricielle) recherche le MAX du n° de colonne <>"", donc peu importe que les données soient dans un ordre ou pas.

Reste à voir si j'avais bien tout compris de la question initiale.

@+

 

[tototiti2008]

Re : Position de la dernière valeur d'une ligne

Bonjour Tibo, abcd,

malheureusement, en effet, EQUIV joue des tours dans ce cas... bien vu Tibo, ça ne m'avait pas sauté aux yeux.

 

[ThunderPaT]

Re : Position de la dernière valeur d'une ligne

Mon problème aura eu le mérite d'avoir créer un mini-débat très instructif !!

Encore merci à vous tous de m'avoir bien aidé 😉