Plusieurs resultats sur une seul boite de dialogue userform vba

Private Sub Bc_rechercher_Click()
Dim P As Range, indice_ligne&, sMessage$
Dim nbMedaille%, Drapeau_trouvé As Boolean
Set P = Range("Vols"): nom = Zt_Saisie.Value
Drapeau_trouvé = False
For indice_ligne = 1 To P.Rows.Count
If P.Cells(indice_ligne, 3).Value = nom Then
nbdevols = P.Cells(indice_ligne + 1, 1)
sMessage = sMessage & nom & " posséde  " & nbdevols & vbCrLf
Drapeau_trouvé = True
End If
Next
If Drapeau_trouvé = False Then
MsgBox "La destination renseignée est inconnue.", vbCritical, "Erreur"
Else
MsgBox sMessage
End If
End Sub

Private Sub Bc_rechercher_Click()
Dim P As Range, nom$, lig&, flag As Boolean
Set P = Range("Vols"): nom = UCase(Zt_Saisie)
With UserForm2.ListBox1
  .Clear
  For lig = 1 To P.Rows.Count
    If UCase(P.Cells(lig, 3)) Like nom & "*" Then
      .AddItem P.Cells(lig, 1)
      .List(.ListCount - 1, 1) = Format(P.Cells(lig, 2), "hh:mm")
      .List(.ListCount - 1, 2) = P.Cells(lig, 3)
      flag = True
    End If
  Next
  If flag Then
    .Parent.Caption = "Vols à destination de " & nom & "..."
    .Parent.Show
  Else
    MsgBox "La destination renseignée est inconnue !", vbCritical, "Erreur"
  End If
End With
End Sub

Private Sub ListBox1_Click()
Application.Goto Rows(ListBox1), True 'sélection dans la feuille
End Sub

Private Sub Bc_rechercher_Click()
Dim P As Range, nom$, lig&
Set P = [Vols]: nom = UCase(Zt_Saisie)
With UserForm2.ListBox1
  .Clear
  For lig = 1 To P.Rows.Count
    If UCase(P.Cells(lig, 3)) Like nom & "*" Then
      .AddItem P(lig, 1).Row 'repérage en 1ère colonne masquée
      .List(.ListCount - 1, 1) = P.Cells(lig, 1)
      .List(.ListCount - 1, 2) = Format(P.Cells(lig, 2), "hh:mm")
      .List(.ListCount - 1, 3) = P.Cells(lig, 3)
    End If
  Next
  If .ListCount Then
    .Parent.Caption = "Vols à destination de " & nom & "..."
    .Parent.Show
  Else
    MsgBox "La destination renseignée est inconnue !", vbCritical, "Erreur"
  End If
End With
End Sub

Private Sub Bc_rechercher_Click()
Dim P As Range, nom$, h&, t, liste(), i&, n&
Set P = [Données!Vols]: nom = UCase(Zt_Saisie) & "*"
h = Application.CountIf(P.Columns(3), nom)
If h Then
  t = P.Columns(1).Resize(, 3) 'matrice, plus rapide
  ReDim liste(1 To h, 1 To 4)
  For i = 1 To UBound(t)
    If UCase(t(i, 3)) Like nom Then
      n = n + 1
      liste(n, 1) = i: liste(n, 2) = t(i, 1)
      liste(n, 3) = Format(t(i, 2), "hh:mm"): liste(n, 4) = t(i, 3)
    End If
  Next
  With UserForm2
    .ListBox1.List = liste
    .Caption = "Vols à destination de " & Left(nom, Len(nom) - 1) & "..."
    .Show 0 'non modal
  End With
Else
  MsgBox Left(nom, Len(nom) - 1) & "... introuvable !", vbCritical, "Erreur"
  With Zt_Saisie: .SetFocus: .SelStart = 0: .SelLength = Len(nom): End With
End If
End Sub