Plus de 7 conditions

[Boby71C]

Bonjour à tous
Je viens de faire une recherche sur le sujet, mais avec ma maladresse habituelle, je n'ai pas trouvé ma réponse. Veuillez m'en excuser.
Je sais que le sujet a déjà été commenté mais je n'arrive pas à mettre la mains dessus😱 😱

Mon souci:
mettre 11 conditions dans 1 cellule !!

J'y arrive jusqu'à 8 mais ensuite, impossible.
Voici ma formule:
=SI(B3=1;26;SI(B3=2;23;SI(B3=3;21;SI(B3=4;19;SI(B3=5;17;SI(B3=6;15;SI(B3=7;13;SI(B3=8;11;""))))))))

Je n'arrive pas à y imbriquer:
Si(B3=9;10)
Si(B3=10;9)
Si(B3=F;0)

Merci pour votre aide
@+

 

[mjo]

Re : Plus de 7 conditions

Bonjour,

La méthode la plus aisée est d'établir un tableau de comparaison.
En colonne X : 1, 2, 3, ...,F
En colonne Y : 26, 23; 21, ...,0
Puis la formule : RECHERCHEV(B3;X1:Y11;2;0)
La fonction RECHERCHEV peut être remplacée par un INDEX EQUIV

Une autre méthode est la fonction Choisir :
=SI(B3="F";0;CHOISIR(B3;25;23;21;19;17;15;13;11;10;9))

Puis il reste la formule :
=SI(ET(A1>0;A1<11);(27-2*A1)+OU(A1=1;A1=9;A1=10)+(A1=10);SI(A1="F";0;""))

mjo

 

[Monique]

Re : Plus de 7 conditions

Bonjour,

La somme de 2 formules :
=SI(B3=1;26;SI(B3=2;23;SI(B3=3;21;SI(B3=4;19;SI(B3 =5;17;SI(B3=6;15;SI(B3=7;13;SI(B3=8;11;0))))))))+SI(B3=6;10;SI(B3=10;6;SI(B3="F";0;0)))

Sans SI()
=(B3=1)*26+(B3=2)*23+(B3=3)*21+(B3=4)*19+(B3 =5)*17+(B3=6)*15+(B3=7)*13+(B3=8)*11+(B3=9)*10+(B3=10)*9+(B3="F")*0
Idem
=(B3=1)*26+(B3=2)*23+(B3=3)*21+(B3=4)*19+(B3 =5)*17+(B3=6)*15+(B3=7)*13+(B3=8)*11+(B3=9)*10+(B3=10)*9

Ou bien faire un tableau de correspondance
1,2,3, etc de F2 à F12
26, 23, 21, etc en face, de G2 à G12
=INDEX($G$2:$G$12;EQUIV(B3;$F$2:$F$12;0))
ou bien
=RECHERCHEV(B3;$F$2:$G$12;2;0)

 

[Omicron]

Re : Plus de 7 conditions

Bonjour à Boby, Mjo et Tous,

Effectivement l'utilisation de recherchev est certainement la solution la plus adaptée.

en pièce jointe : un petit Exemple.

Choisis une valeur dans la cellule rouge, le résultat de la traduction à l'aide de la matrice verte apparaîtra dans la cellule jaune.

Bye ...

 

[Gruick]

Re : Plus de 7 conditions

Bonsoir à tous,
Pas la peine de chercher la complication :
=SI(B3=1;26)+SI(B3=2;23)+SI(B3=3;21)+SI(B3=4;19)+SI(B3 =5;17)+SI(B3=6;15)+SI(B3=7;13)+SI(B3=8;11)+SI(B3=9;10)+SI(B3=10;9)+SI(B3="F";0)
Vu qu'il n'y a qu'une réponse par critère, et que chaque critère est différent.
Gruick

 

[Boby71C]

Re : Plus de 7 conditions

Bonjour les amis
Merci pour toutes 😱 😱 vos réponses. J'ai mis en application la fonction "Choisir" de Mjo qui marche trés bien. je vous promet d'éssayer toutes vos solutions pour ma connaissance personnelle.

Merci à vous et bon Dimanche
@+

 

[Boby71C]

Re : Plus de 7 conditions

Bonsoir à tous
Encore une fois, EXCELLENTE préstation que vous nous avez apportée.
Il y avait une petite erreur ici:

La somme de 2 formules :
=SI(B3=1;26;SI(B3=2;23;SI(B3=3;21;SI(B3=4;19;SI(B3 =5;17;SI(B3=6;15;SI(B3=7;13;SI(B3=8;11;0))))))))+S I(B3=6;10;SI(B3=10;6;SI(B3="F";0;0)))

et une là:
=SI(B3=1;26)+SI(B3=2;23)+SI(B3=3;21)+SI(B3=4;19)+S I(B3 =5;17)+SI(B3=6;15)+SI(B3=7;13)+SI(B3=8;11)+SI(B3=9 ;10)+SI(B3=10;9)+SI(B3="F";0)

Ces 2 petites erreurs m'ont permis de décortiquer vos formules, excellent pour les néophytes😛 . Malgré celà, je vous renouvel à tous un GRAND Merci. Vous êtes fantastiques.
Je vais me construire un petit fichier pense bête pour éssayer de ne plus trop vous ennuyer. Celà ne m'empéchera pas de venir très souvent sur Xld qui pour moi est mon Forum N° 1

Merci à tous et vive Xld
@+

 

[Gruick]

Re : Plus de 7 conditions

Salut Boby71C et à tous,
Les "petites erreurs" sont apparues à l'affichage du message, j'ai essayé de la corriger sans succès.
Pour ton petit lexique, je te précise que ma solution n'est valable que dans le cas où chaque condition n'appelle qu'une réponse. (une négative n'est pas utile). Cette réponse peut être le même d'ailleurs.
Cependant, il y a une autre limite, celle de la longueur de la formule.
A plus et merci pour tes louanges.
Gruick