PDFCreator ne pas enregister

[Arpette]

Bonsoir à toutes et à tous,
j'ai un bout de code qui me transforme en PDF une feuille active d'excel, ça m'ouvre la boite de dialog de PDFCréator pour envoyer un mail, le problème c'est que ça m'oblige à enregistrer alors que je veux juste l'envoyer. Si quelqu'un à une idée.
Merci de votre aide
@+

Sub ToPdf()
Set pdfjob = CreateObject("PDFCreator.clsPDFCreator")
    Application.ActivePrinter = "PDFCreator sur Ne00:"
    ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True
End Sub

 

[kiki29]

Re : PDFCreator ne pas enregister

Salut,eh oui pour l'envoyer il faut tout d'abord le générer et donc l'enregistrer

Dans le dossier d'installation de PDFCreator C:\Program Files\PDFCreator
Lancer PDFCretor.exe,Menu Imprimante / Options
Dans liste de gauche Parametrer Enregistrment et Enregistrement Automatique

Sinon tu trouveras des exemples pour sauver sous un nom voulu dans un dossier voulu un fcihier PDF et envoyer en EMail , 2 exmples ci-dessous

Option Explicit

Sub TstPdfCreator()
Dim JobPDF As Object
Dim sNomPDF As String
Dim sCheminPDF As String
    
    sNomPDF = "commande_" & Range("B13") & ".pdf"
    sCheminPDF = ThisWorkbook.Path & "\"

    If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    Set JobPDF = CreateObject("PDFCreator.clsPDFCreator")

    With JobPDF
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Initialisation de PDFCreator impossible", vbCritical + vbOKOnly, "PDFCreator"
            Exit Sub
        End If
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
        .cOption("AutosaveDirectory") = sCheminPDF
        .cOption("AutosaveFilename") = sNomPDF
        
        '   0=PDF, 1=Png, 2=jpg, 3=bmp, 4=pcx, 5=tif, 6=ps, 7=eps, 8=txt
        .cOption("AutosaveFormat") = 0
        .cClearCache
    End With

    ActiveWorkbook.PrintOut copies:=1, ActivePrinter:="PDFCreator"

    'Fichier dans la file d'attente
    Do Until JobPDF.cCountOfPrintjobs = 1
        DoEvents
    Loop
    JobPDF.cPrinterStop = False

    'Attendre que la file d'attente soit vide
    Do Until JobPDF.cCountOfPrintjobs = 0
        DoEvents
    Loop
    JobPDF.cClose
    Set JobPDF = Nothing
End Sub

Sub Tst_EmailPdfCreator()
Dim objMessage As Object
Dim JobPDF As Object
Dim sNomPDF As String
Dim sCheminPDF As String
    
    sNomPDF = "Essai_PdfCreator.pdf"
    sCheminPDF = ThisWorkbook.Path & "\"

    If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    Set JobPDF = CreateObject("PDFCreator.clsPDFCreator")

    With JobPDF
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Initialisation de PDFCreator impossible", vbCritical + vbOKOnly, "PDFCreator"
            Exit Sub
        End If
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
        .cOption("AutosaveDirectory") = sCheminPDF
        .cOption("AutosaveFilename") = sNomPDF

        '   0=PDF, 1=Png, 2=jpg, 3=bmp, 4=pcx, 5=tif, 6=ps, 7=eps, 8=txt
        .cOption("AutosaveFormat") = 0

        .cClearCache
    End With

    ActiveSheet.PrintOut copies:=1, ActivePrinter:="PDFCreator"

    'Fichier dans la file d'attente
    Do Until JobPDF.cCountOfPrintjobs = 1
        DoEvents
    Loop
    JobPDF.cPrinterStop = False

    'Attendre que la file d'attente soit vide
    Do Until JobPDF.cCountOfPrintjobs = 0
        DoEvents
    Loop

    JobPDF.cClose
    Set JobPDF = Nothing

    Set objMessage = CreateObject("CDO.Message")
    With objMessage
        .Subject = "Example"
        .From = "www@wwwww.fr"
        .To = "yyyyy@wttttt.fr"
        .TextBody = "Texte dans le corps de message"
        .AddAttachment sCheminPDF & sNomPDF
        .Send
    End With

    Set objMessage = Nothing
End Sub

 

[Arpette]

Re : PDFCreator ne pas enregister

Bonsoir kiki, merci de me me répondre, donc je l'enregistre et je le kill derrière. Ce qui est bizarre, dans la boite de dialogue PDFCreator, il y a un bouton enregistrer et un bouton envoyer mail😕.
@+

 

[kiki29]

Re : PDFCreator ne pas enregister

Re,oui mais à priori via ce bouton il doit générer ce fichier, l'envoyer, puis le détruire