Ouvrir une feuille précise d'un fichier excel sans redirection (vba)

[Alexander]

Bonjour le forum,
J'expose mon problème : je travail sur un powerpoint avec plusieurs diapos qui contiennent plusieurs boutons qui ouvrent différents fichiers doc, excel, pdf...
Seulement j'ai plusieurs boutons qui doivent ouvrir des feuilles différentes appartenant au même fichier excel.
Pour l'instant j'ai fait une macro qui ouvre le fichier excel et qui se redirige vers la feuille concerné :

Sub Groupe_électrogène()
Dim OFS As Office.FileSearch
Dim i As Integer
Dim adresse As String
Dim appExcel As Excel.Application
Dim appwbExcel As Excel.Workbook


Set OFS = Application.FileSearch
With OFS
.NewSearch
.FileType = msoFileTypeOfficeFiles
.FileName = "DU évaluation risques.xls"
.LookIn = "C:\gpp"
.SearchSubFolders = True
.LastModified = msoLastModifiedAnyTime
If .Execute(SortBy:=msoSortByLastModified, SortOrder:=msoSortOrderDescending) > 0 Then

adresse = .FoundFiles(1)

Set appExcel = CreateObject("Excel.Application")
appExcel.Visible = True
Set appwbExcel = appExcel.Workbooks.open(adresse)
appwbExcel.Worksheets(" ! Fiche 15 Gpe électro").Select

Else
MsgBox "Aucun fichier n'a été trouvé."
End If
End With
End Sub

Quand j'exécute cette macro, le fichier excel s'ouvre d'abord sur la feuille "fiche 23" (la feuille où j'étais la dernière fois que j'ai enregistré le fichier) et après un temps d'attente excel sélectionne la feuille concernée : "! Fiche 15 GPE électro".

J'aimerais savoir s'il est possible d'ouvrir directement la feuille excel concernée à l'ouverture du fichier sans faire de redirection ?

 

[phlaurent55]

Re : Ouvrir une feuille précise d'un fichier excel sans redirection (vba)

Bonjour alexander,

essaie en faisant passer la seconde ligne en dernier

Set appExcel = CreateObject("Excel.Application") 
    appExcel.Visible = True 
    Set appwbExcel = appExcel.Workbooks.open(adresse)
    appwbExcel.Worksheets(" ! Fiche 15 Gpe électro").Select

comme ceci:

Set appExcel = CreateObject("Excel.Application") 
    Set appwbExcel = appExcel.Workbooks.open(adresse)
    appwbExcel.Worksheets(" ! Fiche 15 Gpe électro").Select
    appExcel.Visible = True

à+

Philippe

 

[Alexander]

Re : Ouvrir une feuille précise d'un fichier excel sans redirection (vba)

Salut le Forum

Merci Philippe pour ta réponse
ça marche nickel c'est exactement ce que je voulais =)
a+