Ordre d'arrivee tierce

franck62223 · 18 Décembre 2014

Bonjour,
Dans le cadre d'un fichier excel qui contient des arrivées de quinté + tiercé et quarté, je rentre 8 chevaux et j'aimerai indiquer si dans les 8 chevaux donnés par les pronostiqueurs si il y a un TIERCE ordre ou un désordre ?

Merci D'AVANCE
ex chevaux donnés : 8/5/4/7/16/17/18/13
arrivée tiercé 4/5/13
donc arrivée désordre

CISCO · 18 Décembre 2014

Re : Ordre d'arrivee tierce

Bonsoir

Essaye en Y4 avec

Code:

SI(ESTNUM(CHERCHE(L4&";"&"*"&M4&";"&"*"&N4&";";B4&";"&C4&";"&D4&";"&E4&";"&F4&";"&G4&";"&H4&";"&I4));"ordre";SI(NB.SI(B4:I4;L4)*NB.SI(B4:I4;M4)*NB.SI(B4:I4;N4)=1;"désordre";""))

@ plus

mapomme · 19 Décembre 2014

Re : Ordre d'arrivee tierce

Bonsoir franck62223, CISCO,

Un essai avec une autre formule en Y4:

Code:

=SI( X4<>"Tiercé";"";SI(ET(EQUIV($L$4;$B4:$I4;0)<EQUIV($M$4;$B4:$I4;0);EQUIV($M$4;$B4:$I4;0)<EQUIV($N$4;$B4:$I4;0));"ordre";"désordre"))

franck62223 · 19 Décembre 2014

Re : Ordre d'arrivee tierce

CISCO à dit:

Bonsoir

Essaye en Y4 avec

Code:

SI(ESTNUM(CHERCHE(L4&";"&"*"&M4&";"&"*"&N4&";";B4&";"&C4&";"&D4&";"&E4&";"&F4&";"&G4&";"&H4&";"&I4));"ordre";SI(NB.SI(B4:I4;L4)*NB.SI(B4:I4;M4)*NB.SI(B4:I4;N4)=1;"désordre";""))

@ plus

MERCI BEAUCOUP j'ai essayé ça marche je vais essayer de l'adapter avec le quarté et le quinté, si je n'y arrive pas je vous solliciterai encore.
Encore merci beaucoup

CISCO · 19 Décembre 2014

Re : Ordre d'arrivee tierce

Bonjour à tous, bonjour mapomme

Ma dernière proposition ne doit pas donner le bon résultat dans tous les cas.
Par exemple, si le tiercé est 1, 10, 4, et que dans ta liste, tu as par exemple 11, 10 et 4, elle va renvoyer "ordre", parcequ'elle à pris en compte le 1 final du 11, puis le 10 et le 4. Il faut donc démarrer la formule par un ";"&L4, et non pas par L4 directement, pour créer une différence entre le dernier 1 du 11, et un 1 seul. Idem pour B4.
A la fin de la formule, il faut aussi faire une correction : dans le cas où on aurait N4=I4, et puisqu'on fait le test sur N4&";", il faut aussi le faire sur I4&";". Ce qui donne

Code:

SI(ESTNUM(CHERCHE(";"&L4&";"&"*"&M4&";"&"*"&N4&";";";"&B4&";"&C4&";"&D4&";"&E4&";"&F4&";"&G4&";"&H4&";"&I4&";"));"ordre";SI(NB.SI(B4:I4;L4)*NB.SI(B4:I4;M4)*NB.SI(B4:I4;N4)=1;"désordre";""))

A toi de vérifier.

@ plus

P.S : La proposition de mapomme est plus courte, et plus fine. Autant faire avec 🙂

mapomme · 20 Décembre 2014

Re : Ordre d'arrivee tierce

Bonjour franck62223, CISCO, à tous,

Un essai avec des formules plus concises:

Formule n° 1 en Y4 (à tirer vers le bas) pour Tiercé dans l'ordre ou non :

Code:

=SI(X4<>"Tiercé";"";SI(SOMMEPROD(N(EQUIV($L$4:$M$4;$B4:$I4;0)<=EQUIV($M$4:$N$4;$B4:$I4;0)))=2 ;"ordre";"désordre"))

Formule n° 2 en AA4 (à tirer vers le bas) pour Quarté dans l'ordre ou non :

Code:

=SI(Z4<>"Quarté";"";SI(SOMMEPROD(N(EQUIV($L$4:$N$4;$B4:$I4;0)<=EQUIV($M$4:$O$4;$B4:$I4;0)))=3 ;"ordre";"désordre"))

Formule n° 3 en AC4 (à tirer vers le bas) pour quinté dans l'ordre ou non :

Code:

=SI(AB4<>"quinté";"";SI(SOMMEPROD(N(EQUIV($L$4:$O$4;$B4:$I4;0)<=EQUIV($M$4:$P$4;$B4:$I4;0)))=4 ;"ordre";"désordre"))

Ordre d'arrivee tierce

franck62223

XLDnaute Nouveau

Pièces jointes

CISCO

XLDnaute Barbatruc

mapomme

XLDnaute Barbatruc

franck62223

XLDnaute Nouveau

CISCO

XLDnaute Barbatruc

mapomme

XLDnaute Barbatruc

Pièces jointes

Discussions similaires

Ordre d'arrivee tierce

franck62223

XLDnaute Nouveau

Pièces jointes

CISCO

XLDnaute Barbatruc

mapomme

XLDnaute Barbatruc

franck62223

XLDnaute Nouveau

CISCO

XLDnaute Barbatruc

mapomme

XLDnaute Barbatruc

Pièces jointes

Discussions similaires

Privacy & Transparency

Privacy & Transparency