Numero de page dans cellule...

[Absinth]

Hello,

Petite question:

Y a t il une formule pour que dans une case, j'obtienne:

page x / y

ou x est la page courante et y le nombre total de page...

(je ne sais pas à l'avance combien de pages au total fera le document à l'impression...)

PS: par page j'entends les pages imprimées, pas les feuilles du classeur 😉

Merci d'avance
Absinth

 

[filiph79]

Re : Numero de page dans cellule...

Bonjour le forum, absinth,

pourquoi mettre le numéro de page dans une cellule alors que les entetes et pieds de page sont prévus pour ça ?

Fichier / Mise en Page

A+

 

[Absinth]

Re : Numero de page dans cellule...

Hello,

euh, et bien parce que ce sont des fiches de securité norme ISO je-ne-sais-plus-quel-numero machin et que la mise en page doit etre selon leurs normes... avec le n° de page dans une case à droite du titre... 😉

 

[ftho]

Re : Numero de page dans cellule...

Bonjour,

Il n'y a pas une "formule" mais il y a moyen de le faire via la petite usine à gaz ci-dessous en comptant les sauts de page.
Remarque : il faut que la zone d'impression soit préalablement définie.

Sub test_numpage()
Dim i As Integer, j As Integer, c As Range

'si la zone d'impression est vide on quitte la procédure
If ActiveSheet.PageSetup.PrintArea = "" Then Exit Sub

'en cas de sélection d'une cellule en dehors de la zone d'impression
Set c = Intersect(Range(ActiveCell.Address), Range(ActiveSheet.PageSetup.PrintArea))
    If c Is Nothing Then
        MsgBox "veuillez sélectionner une cellule dans la zone d'impression"
        Exit Sub
    End If

'comptage du nombre de sauts de page horizontaux jusqu'à la cellule active
For i = 1 To ActiveSheet.HPageBreaks.Count
    If ActiveSheet.HPageBreaks(i).Location.Row > ActiveCell.Row Then Exit For
Next

'comptage du nombre de sauts de page verticaux jusqu'à la cellule active
For j = 1 To ActiveSheet.VPageBreaks.Count
    If ActiveSheet.VPageBreaks(j).Location.Column > ActiveCell.Column Then Exit For
Next

'vérification de la mise en page
Select Case ActiveSheet.PageSetup.Order
Case Is = xlOverThenDown
i = (i - 1) * (ActiveSheet.VPageBreaks.Count + 1)
Case Is = xlDownThenOver
j = (j - 1) * (ActiveSheet.HPageBreaks.Count + 1)
End Select

'insertion du numéro de page dans la cellule active
ActiveCell = "p." & i + j & "/" & (ActiveSheet.HPageBreaks.Count + 1) * (ActiveSheet.VPageBreaks.Count + 1)

End Sub

 

[Absinth]

Re : Numero de page dans cellule...

😱

la "petite" usine à gaz?...😉

Merci beaucoup 😀