XL 2016 Nombre de lignes différentes destination/données

[Jakes]

Bonjour et meilleurs vœux

Je cherche en utilisant la poignée de recopie, comment continuer verticalement et régulièrement (toujours 7 lignes) pour réaliser ceci:

En cellule C1 =Moyenne(B6:B12)

En cellule C2 =Moyenne(B13:B19)

En cellule C3 =Moyenne(B20:B26)

et ainsi de suite

Par avance merci

 

[Dudu2]

Bonjour,
En C1: =MOYENNE(INDIRECT("B" & LIGNE(A1) * 7 - 1 & ":B" & LIGNE(A2) * 7 - 2))
Et tirer vers le bas.

Ça doit pouvoir se faire plus élégamment avec un DECALER.

 

[mapomme]

Bonsoir,
EN C1 : =MOYENNE(DECALER(B$6:B$12;7*(LIGNE()-1);0))

 

[chris]

Bonjour

Nombre de lignes différentes destination/données

Je cherche en utilisant la poignée de recopie, comment continuer verticalement et régulièrement (toujours 7 lignes) pour réaliser ceci: En cellule C1 =Moyenn...

forum.excel-pratique.com

=MOYENNE(DECALER(B$1;LIGNE()*7-2;0;7))

 

[Dudu2]

Oui en DECALER c'est mieux:
En C1: =MOYENNE(DECALER(B$1;LIGNE(A1) * 7 - 2;0;7;1))

 

[Jakes]

Merci beaucoup à tous
Pouvez-vous m'expliquer la logique du 7-2, je ne connais pas cette fonction DECALER.
B1 est le titre de la colonne
Je vais être amené à l'utiliser dans d'autres conditions (autres lignes, décalage 5 ou 6 lignes, autres colonnes)
Merci

 

[chris]

RE

je ne connais pas cette fonction DECALER

Au, lieu de cross poster, il est mieux de demander une explication après avoir regardé l'aide en ligne d'Excel sur cette fonction.
Elle sert à déterminer une plage dont on ne connait pas l'adresse et/ou la taille mais que l'on peut déterminer par rapport à un point connu.
le plus simple ici serait à mon avis

=MOYENNE(DECALER(B$6;LIGNE()*7-7;0;7))

On connait le point de départ B$6 et on doit avoir une hauteur de 7 lignes et donc se décaler de 7 lignes en 7 lignes

Donc partant de B6 on ne se décale pas en C1 mais on se décale de
1 fois 7 lignes en C2
2 fois 7 lignes en C3
3 fois 7 lignes en C4
etc

en utilisant le numéro de ligne de la formule en colonne C, qui est 1 puis 2 puis 3... on a le nombre de fois mais comme il ne faut pas se décaler dès la 1ère formule, on soustrait 7
Ce qui donnera pour le décalage 0, 7, 14, 21...

 

[Jakes]

Bonjour,
Je n'arrivais pas à reproduire ce que me disait l'aide d'Excel, c'est pourquoi j'ai utilisé le forum.
J'ai enfin réussi à comprendre le fonctionnement de cette fonction grâce à vous.
Merci beaucoup pour les explications, ainsi qu'aux autres membres qui ont bien voulu m'aider.