Nom du fichier dans cellule

[Tomtom]

Bonjour,

Comment faire pour insérer le nom du fichier excel en cours dans une cellule sans avoir le chemin d'accès de ce fichier.

Merci.

 

[STéphane]

bonjour


1ère méthode : écrivez les fonctions ci-dessous suivantes dans une feuille de code, vous pouvez alors sélectionner ces deux fonctions dans le menu "fx" à "fonctions personnalisées".

function nomOnglet()
nomOnglet = activesheet.name
end function

function nomFichier()
nomFichier = activeworkbook.name
end function

Nom du classeur : activeworkbook.name
Nom complet du classeur : activeworkbook.fullname

2ème méthode : par l'intermédiaire de formules "existantes" toutes très longues.

attention, il faudra peut-êtrecorriger un ou deux trucs



1. Chemin d'accès complet : "C:\Temp[Test.xls]Feuil1"
=CELLULE("filename";A1)

2. Répertoire : "C:\Temp"
=GAUCHE(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1))-2)

3. Nom du classeur seul : "Test.xls"
=STXT(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1))+1;
SOMME(TROUVE({"[";"]"};CELLULE("filename";A1))*{-1;1})-1)

4. Nom de la feuille : "Feuil1"
=STXT(CELLULE("filename";A1);TROUVE("]";CELLULE("filename";A1))+1;32)
=STXT(CELLULE("filename";A62);TROUVE("]";CELLULE("filename";A62))+1;NBCAR(CELLULE("filename";A62))-TROUVE("]";CELLULE("filename";A62)))

5. Répertoire + classeur : "C:\Temp\Test.xls"
=SUBSTITUE(GAUCHE(CELLULE("filename";A1);TROUVE("]"; CELLULE("filename";A1))-1);"[";"")

6. Nom du classeur et de la feuille : "[Test.xls]Feuil1"
=STXT(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1));300)

 

[pmfontaine]

Bonjour,
je suis intéressé par la récupération du nom de fichier suivant la première méthode "fonctions personnalisées".
Mais je n'arrive pas à la mettre en application, pouvez-vous me donner des précision, ou un exemple concret dans un fichier.
Merci d'avance
pmfontaine