Ne pas calculer le X

[Clochard]

Bonjour le Forum....

J'ai cette formule qui me donne dans une plage le nombre de chèque emis dans le mois...

=NB.SI(L10:T30;"<>")

Qui fonctionne bien....
Mais lorsque le chèque est encaissé par le detinataire j'ai du ajouté une colonne pour y placer un X pour contrôler ceux qui restent à être encaissés....

Mais là... ma formule prend en considération les X que j'y ajoute et fausse ainsi le total de chèque émis....
D'après vous...
Que devrais-ja ajouter à ma formule pour qu'il ne prenne pas en compte les X

Merci d'y regarder et bonne journée

Clochard

 

[Brigitte]

Re : Ne pas calculer le X

Bonsoir,

Avec un sommeprod, tu peux combiner des critères, par exemple :

=sommeprod((1èreplage="telle chose")*(2ème plage<>"X")*1

te calculera tout ce qui :

- dans la première plage, correspond au mot "telle chose" (entre guillemets pour un mot, sans guillemets pour une référence à une cellule ou une référence de cellule)

et

- dans la deuxième plage, ne contient pas de "x" (idem ci-dessus).

Je ne peux te donner la formule exacte, n'ayant pas le fichier ni les données, mais seulement une plage de L à T (dont je ne sais pas les titres de colonnes) et ne sachant pas quelle colonne contient ou non le fameux "x".

En revanche, je suis interrogative face à ta formule avec nb.si. A quoi correspond le signe <> ? Différent de quoi ???

 

[Clochard]

Re : Ne pas calculer le X

Merci de me répondre Brigite,

Les <> sont d'après moi dans le de calculer combien de fois il y a un montant d'inscrit dans une des cellules de la plage L10:T30


Clochard

 

[Brigitte]

Re : Ne pas calculer le X

Re,

Pourrais tu, soit nous joindre un petit bout de fichier (j'ai du mal à imaginer que tes chiffres sont dans toute la plage...) soit nous dire ce que tu as comme titre dans tes colonnes de L à T (la même chose ?) et les "x" de chèques, sont où, dans quelle colonne ?

Ok : vu pour tes <> qui signifient : combien de cellules remplies.

 

[Brigitte]

Re : Ne pas calculer le X

Re,

Dans ce cas, tente la formule suivante :

=SOMMEPROD((L10:T30<>"")*(L10:T30<>"X")*1)

Je te recommande de mettre des valeurs absolues à ta plage si tu dois la recopier vers le bas, la droite...

 

[Clochard]

Re : Ne pas calculer le X

Bonjour Brigitte....

Je joint un petit exemple de mon problème...

J'apprécie ton aide... merci

Clochard

 

[Clochard]

Re : Ne pas calculer le X

Merci beaucoup Brigitte...

Ta sugestion =SOMMEPROD((L10:T30<>"")*(L10:T30<>"X")*1)

Semble très bien fonctionner....

Merci beaucoup...

Clochard

 

[Brigitte]

Re : Ne pas calculer le X

Re,

Super.

Bien entendu, au vu de ton fichier, si tu voulais tous les montants, mais encaissés, il suffit de remplacer le <>"x" par ="x" ce qui comptabiliserait uniquement les cases avec montant et x en face.

 

[hbenalia]

Re : Ne pas calculer le X

Bonjour à tous,

Il faut tout simplement remplacer la formule dans la cellule D7 par la formule:

=NB.SI(L10:S30;"<>")-NB.SI(L10:S30;"=X")

Bonjour Brigitte....

Je joint un petit exemple de mon problème...

J'apprécie ton aide... merci

Clochard

 

[Clochard]

Re : Ne pas calculer le X

Bonjour Brigitte...

Pour abuser un peu de toi...

Et si je voulais obtenir le montant total en argent des chèques sans x
et le montant total des avec un X

Est-ce possible d'après toi

Merci de ton aide grandement appréciée

Clochard

 

[JCGL]

Re : Ne pas calculer le X

Bonjour à tous,
Salut T'ites Couettes 🙂,

Un simple :

=NB(L10:S30)

devrait suffire en D7

NB
Détermine le nombre de cellules contenant des nombres et les nombres compris dans la liste des arguments. Utilisez NB pour obtenir le nombre d'entrées numériques dans un champ numérique d'une plage ou d'une matrice de nombres.

Bises 🙂
A+ à tous

 

[Clochard]

Re : Ne pas calculer le X

Merci JCGL

Pour ta participation à ma question.... ainsi qu'à hbenalia

Clochard

 

[Brigitte]

Re : Ne pas calculer le X

Re, re,

Bises JC... et oui, pourquoi faire simple, quand on peut faire compliqué...

Sinon Clochard, comme dit dans mon post précédent :

Bien entendu, au vu de ton fichier, si tu voulais tous les montants, mais encaissés, il suffit de remplacer le <>"x" par ="x" ce qui comptabiliserait uniquement les cases avec montant et x en face.

Donc par déduction...


=SOMMEPROD((L10:T30<>"")*(L10:T30<>"X")*1)
donnera toutes les cellules remplies d'un chiffre dans la plage L à T, qu'il y ait un x en face ou non, mais sans compter celles qui contiennent un x, bien sûr.

=SOMMEPROD(($L$10:$L$30<>"")*($M$10:$M$30="x")*1)+SOMMEPROD(($N$10:$N$30<>"")*($O$10:$O$30="x")*1)+SOMMEPROD(($P$10:$P$30<>"")*($Q$10:$Q$30="x")*1)+SOMMEPROD(($R$10:$R$30<>"")*($S$10:$S$30="x")*1)

donnera tous les montants encaissés (ayant un "x" en face) dans ton tableau joint : 1

=SOMMEPROD(($L$10:$L$30<>"")*($M$10:$M$30="")*1)+SOMMEPROD(($N$10:$N$30<>"")*($O$10:$O$30="")*1)+SOMMEPROD(($P$10:$P$30<>"")*($Q$10:$Q$30="")*1)+SOMMEPROD(($R$10:$R$30<>"")*($S$10:$S$30="")*1)

donnera tous les montants non encaissés (sans "x") dans ton tableau joint : 4

A noter : pour ces deux dernières, il faut scinder le tableau par colonnes... et non plus la plage entière de tout le tableau.

 

[Brigitte]

Re : Ne pas calculer le X

Re,

Là j'ai compté les chèques encaissés ou non avec les deux dernières formules, pour avoir les montants, au lieu de multiplier par 1 : *1 à la fin de chaque sommeprod, il faut multiplier de nouveau par la colonne des montants, ainsi :

=SOMMEPROD(($L$10:$L$30<>"")*($M$10:$M$30="")*$L$10:$L$30)+SOMMEPROD(($N$10:$N$30<>"")*($O$10:$O$30="")*$N$10:$N$30)+SOMMEPROD(($P$10:$P$30<>"")*($Q$10:$Q$30="")*$P$10:$P$30)+SOMMEPROD(($R$10:$R$30<>"")*($S$10:$S$30="")*$R$10:$R$30)

pour tous ceux qui ne sont pas encaissés : 912

=SOMMEPROD(($L$10:$L$30<>"")*($M$10:$M$30="x")*$L$10:$L$30)+SOMMEPROD(($N$10:$N$30<>"")*($O$10:$O$30="x")*$N$10:$N$30)+SOMMEPROD(($P$10:$P$30<>"")*($Q$10:$Q$30="x")*$P$10:$P$30)+SOMMEPROD(($R$10:$R$30<>"")*($S$10:$S$30="x")*$R$10:$R$30)

pour tous ceux qui sont encaissés (avec "x") : 45

PS : note bien, Monique passerait par là, elle nous ferait surement une formule mille fois moins longue... mais son neurone bénéficie de l'air breton, ca compte.

 

[Clochard]

Re : Ne pas calculer le X

Encore une fois merci Brigitte

Quelle efficacité de ta part.... merci pour tout ce travail que tu me transmets...


Merci et passe une superbe journée

Clochard