Moyenne d'une SOMME.SI

[JeankTecha]

Bonjour,

Voici ma situation :

Je souhaite créer un tableau qui regrouperait les valeurs résiduelles moyenne de voitures selon leur utilisation (nombre de kilomètre parcourus) à partir d'une feuille qui regroupe 250 voitures.

Par exemple, pour les voitures de 1967, qui auraient parcourues entre 0 et 5000 kilomètres, j'ai la fonction suivante
=(MOYENNE.SI('1967'!B2:B250;"<5000";'1967'!A2:A250))

Par contre, je n'arrive pas à figurer quelle formule entrée pour trouver la valeur moyenne des voitures ayant parcourues entre 5001 et 10 000 kilomètres. J'ai la fonction suivante pour trouver la somme de leur valeur :
=SOMME.SI('1967'!B2:B250;"<10000";'1967'!A2:A250)-SOMME.SI('1967'!B2:B250;"<5000";'1967'!A2:A250)

Est-ce que quelqu'un pourrait m'aider? Comment pourrais-je inscrire une formule qui me donnerait le nombre de voiture correspondant à mon critère, pour que je puisse ensuite divisé ma SOMME.SI par ce nombre total de voiture et ainsi obtenir ma moyenne?

MERCI!

 

[mutzik]

Re : Moyenne d'une SOMME.SI

bonjour,

tu as également la fonction NB.SI qui fonctionne comme SOMME.SI
tu divises l'un par l'autre et tu auras ta moyenne

 

[R@chid]

Re : Moyenne d'une SOMME.SI

Bonjour et Bienvenue sur XLD,
Salut Mutzik,

tu es sur XL2007 alors pourquoi ne pas profiter de MOYENNE.SI.ENS()...

=MOYENNE.SI.ENS('1967'!A2:A250;'1967'!B2:B250;">=5000";'1967'!B2:B250;"<10000")

ou formule matricielle pour les versions précédentes,

=MOYENNE(SI(('1967'!B2:B250>=5000)*('1967'!B2:B250<10000);'1967'!A2:A250))

@ valider par Ctrl+Maj+Entree

Un fichier exemple est recommandé pour faire le test

@ +

 

[JeankTecha]

Re : Moyenne d'une SOMME.SI

La raison est simple : je n'en connaissais pas l'existence!

Ça fonctionne parfaitement! Merci!

 

[JeankTecha]

Re : Moyenne d'une SOMME.SI

Si je peux abuser de votre bonté un peu, j'aurais une deuxième question!

Comme cette même formule =MOYENNE.SI.ENS('1967'!A2:A250;'1967'!B2:B250;">5000";'1967'!B2:B250;"<=10000") s'applique à plusieurs années de véhicules (de 1930 à 2013) et que j'ai 8 catégories de bornes, je doit modifier 664 fois pour chaque modèle de véhicule le champ '1967' de la formule.

Je souhaiterais qu'automatiquement, lorsque je descend la formule dans mon tableau, le 1967 soit changé pour correspondre au nom de la feuille suivante de mon classeur. Il est à noter que la première colonne de mon tableau correspond toujours au nom de la feuille qui doit être utilisée pour le calcul de la rangée.

En espérant avoir été clair :S

MERCI!!!!

 

[R@chid]

Re : Moyenne d'une SOMME.SI

Bonjour,
Un fichier exemple va nous aider de te donner une réponse précise...
@ +

 

[JeankTecha]

Re : Moyenne d'une SOMME.SI

Voici le fichier en question!

Je veux trouver une façon d'éviter d'avoir à modifier manuellement la formule dans la feuille "récapitulatif"

 

[R@chid]

Re : Moyenne d'une SOMME.SI

Bonsoir,
essayer en B2,

=SIERREUR(MOYENNE.SI.ENS(INDIRECT("'"&$A2&"'!A2:A250");INDIRECT("'"&$A2&"'!B2:B250");">=0";INDIRECT("'"&$A2&"'!B2:B250");"<5001");"")

@ tirer vers le bas

A adapter pour les autres colonnes en modifiant juste les criteres

@ +

 

[JeankTecha]

Re : Moyenne d'une SOMME.SI

wow ok merci beacoup! je vous donne des nouvelles sous peu si ça a fonctionné!

 

[JeankTecha]

Re : Moyenne d'une SOMME.SI

Tout fonctionne! Excellent!