Modification code VBA

teamtat

XLDnaute Occasionnel
Bonjour,
Voila j'aimerai modifier mon code VBA pour pouvoir choisir mon chemin d'enregistrement et non enregistrer ici :
Code:
 C:\Documents and Settings\peyret\Mes documents\camille\
comment faire ?


Code:
 Dim monfichier, jour As String
Dim wk As Workbook
Dim ws As Worksheet

On Error Resume Next
MkDir "C:\Documents and Settings\peyret\Mes documents\camille\Affaire " & Range("G4").Value
On Error GoTo 0
  
monfichier = "C:\Documents and Settings\peyret\Mes documents\camille\Affaire " & Range("G4").Value & "\" & "Appareil n° " & Range("C4").Value
   
   
   
If Dir(monfichier & ".xls") <> "" Then
jour = Format(Now, "dd-mm-yy hh mm ss")
monfichier = monfichier & " " & jour
End If
monfichier = monfichier & ".xls"
   
ThisWorkbook.SaveCopyAs monfichier

MsgBox "Sauvegarde terminée."

Merci
 

Minick

XLDnaute Impliqué
Re : Modification code VBA

Salut,

Un exemple:
Code:
Option Explicit

Sub SelectionDossier()
    Dim Dossier As FileDialog
     
    Set Dossier = Application.FileDialog(msoFileDialogFolderPicker)
    Dossier.Show
     
    If Dossier.SelectedItems.Count <> 0 Then
        MsgBox Dossier.SelectedItems(1)
    End If
End Sub
 

spidernono

XLDnaute Nouveau
Re : Modification code VBA

Bonjour,

Moi, j'étais passé bêtement par une inputbox ^^

Code:
Dim monfichier, jour As String
Dim wk As Workbook
Dim ws As Worksheet

On Error Resume Next
'MkDir "C:\Documents and Settings\peyret\Mes documents\camille\Affaire " & Range("G4").Value
On Error GoTo 0
  
'monfichier = "C:\Documents and Settings\peyret\Mes documents\camille\Affaire " & Range("G4").Value & "\" & "Appareil n° " & Range("C4").Value
monfichier = InputBox("Saisissez le chemin", "Chemin") & "\" & Range("G4").Value
   
   
If Dir(monfichier & ".xls") <> "" Then
jour = Format(Now, "dd-mm-yy hh mm ss")
monfichier = monfichier & " " & jour
End If
monfichier = monfichier & ".xls"
   
ThisWorkbook.SaveCopyAs monfichier

MsgBox "Sauvegarde terminée."

Mais je pense que la solution précédente est la meilleure ^^
 

Minick

XLDnaute Impliqué
Re : Modification code VBA

Re,

Par exemple:
Code:
    Dim monfichier As String, jour As String, nomDossier As String
    Dim wk As Workbook
    Dim ws As Worksheet
    Dim Dossier As FileDialog
    
    Set Dossier = Application.FileDialog(msoFileDialogFolderPicker)
    Dossier.Show
    If Dossier.SelectedItems.Count <> 0 Then nomDossier = Dossier.SelectedItems(1)
    Set Dossier = Nothing
    
    If nomDossier <> "" Then
        On Error Resume Next
        MkDir nomDossier & "\Affaire " & Range("G4").Value
        On Error GoTo 0
          
        monfichier = nomDossier & "\Affaire " & Range("G4").Value & "\" & "Appareil n° " & Range("C4").Value
           
           
           
        If Dir(monfichier & ".xls") <> "" Then
        jour = Format(Now, "dd-mm-yy hh mm ss")
        monfichier = monfichier & " " & jour
        End If
        monfichier = monfichier & ".xls"
           
        ThisWorkbook.SaveCopyAs monfichier
        
        MsgBox "Sauvegarde terminée."
    End If
 

Discussions similaires

Statistiques des forums

Discussions
311 707
Messages
2 081 746
Membres
101 812
dernier inscrit
trufu