modif de macro

[dede039]

bonjours le forum

j'ai besoin de votre aide j'ai se code qui marche bien mais quand ont l'exécute tout clignote
je voudrai que tout se face en "invisible"

Sub macro1()
    Sheets("Feuil2").Select
    Dim X As Range
        Set X = Range(Cells(1, 1), Cells(65535, 1)).Find("", , xlValues, xlWhole, , , False) 'recherche premiere ligne vide
        deb = 0
            If Not X Is Nothing Then
                deb = (X.Row) 'deb= num ligne vide
            End If
    Range("A1").Select
    Range(Cells(1, 1), Cells(deb - 1, 50)).Select ' nombre de colonne
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("Feuil1").Select
    Set X = Range(Cells(1, 1), Cells(65535, 1)).Find("", , xlValues, xlWhole, , , False)
    i = X.Row
    Range("A1").Select
    ActiveCell.Offset(i - 1, 0).Select
    ActiveSheet.Paste
    Application.CutCopyMode = False
    Cells.Select
    Selection.Sort Key1:=Range("C1"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
    Range("A1").Select
    i = 0
        Do Until ActiveCell.Offset(i, 0).Value = ""
            i = i + 1
            p = 0
            For j = 1 To 26 'nombres de colonne traite
                If ActiveCell.Offset(i, j).Value = ActiveCell.Offset(i - 1, j).Value Then
                    p = p + 1
                End If
                If p = 26 Then
                    Rows(i).Delete
                    i = i - 1
                End If
            Next j
        Loop
End Sub

 

[phlaurent55]

Re : modif de macro

Bonjour dédé,

à mettre en début de code:

Application.ScreenUpdating=False

et en fin de code:

Application.ScreenUpdating=True

à+
Philippe

 

[dede039]

Re : modif de macro

bonjours phlaurent

j'ai déjà essaye sa mais sa marche moyen
il vaudrai que se sois totalement invisible
cas cette macro pour être lance depuis plusieurs feuille
et si j'utilise sa marche pas trop bien (ont change de feuille et je ne veut pas)

 

[gege21]

Re : modif de macro

quelqu'un aurais t'il une ide pour moi sans passer par

Application.ScreenUpdating=False
Application.ScreenUpdating=True

😕😕

Dédé21 a judicieusement repris mon post d'hier

 

[ROGER2327]

Re : modif de macro

Bonsoir à tous

Sans support, difficile d'être sûr de ce qu'on fait ; à tout hasard, voyez si ceci arrange les choses :

Sub macro1()
Dim deb&, i&, j%, p As Boolean, X As Range
  Sheets("Feuil2").Activate
  With Sheets("Feuil1")
    Set X = .Range(.Cells(1, 1), .Cells(65535, 1)).Find("", , xlValues, xlWhole, , , False)
    i = X.Row
    Set X = Range(Cells(1, 1), Cells(65535, 1)).Find("", , xlValues, xlWhole, , , False)
    If X Is Nothing Then deb = 0 Else deb = X.Row
    Range(Cells(1, 1), Cells(deb - 1, 50)).Copy Destination:=.Range("A1").Offset(i - 1, 0)
    .Cells.Sort Key1:=.Range("C1"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
    i = 0
    Do Until .Cells(1, 1).Offset(i, 0).Value = ""
      i = i + 1
      p = True
      For j = 1 To 26
        p = p And (.Cells(1, 1).Offset(i, j).Value = .Cells(1, 1).Offset(i - 1, j).Value)
      Next j
      If p Then
        .Rows(i).Delete
        i = i - 1
      End If
    Loop
    .Activate
  End With
End Sub

​

ROGER2327
#4795

Lundi 23 Sable 138 (Sainte Viole, vierge et martyre, SQ)
3 Nivôse An CCXIX
2010-W51-4T17:29:37Z

 

[gege21]

Re : modif de macro

bonjours roger2327
voici le fichier

 

[ROGER2327]

Re : modif de macro

Re...

Il vous faudra essayer vous-même le code proposé car je ne dispose que d'Excel2003 qui n'ouvre pas les fichiers .xlsm. Désolé.​

ROGER2327
#4796

Lundi 23 Sable 138 (Sainte Viole, vierge et martyre, SQ)
3 Nivôse An CCXIX
2010-W51-4T18:20:29Z

 

[gege21]

Re : modif de macro

cela marche bien mieux mais il y a toujours les changement de feuille

je rejoint le ficher en version 2003

 

[ROGER2327]

Re : modif de macro

Re…

cela marche bien mieux mais il y a toujours les changement de feuille (…)

C'est le prix à payer si vous ne voulez pas bloquer le rafraichissement d'écran. (Je me demande encore pourquoi, d'ailleurs.)​

ROGER2327
#4797

Lundi 23 Sable 138 (Sainte Viole, vierge et martyre, SQ)
3 Nivôse An CCXIX
2010-W51-4T22:13:35Z

 

[gege21]

Re : modif de macro

ce surtout que lorsqu'on l'exécute on change de feuille moi j'aurai voulu reste sur la feuille ou elle exécute
(a savoir elle pourra être exécute a partir de plusieurs feuille)

 

[ROGER2327]

Re : modif de macro

Re...

Essayez ceci :

Sub macro1()
Dim deb&, i&, j%, p As Boolean, X As Range, sh As Worksheet
  Application.Calculation = -4135
  Set sh = ActiveSheet
  With Sheets("Feuil1")
    Set X = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1)).Find("", , xlValues, xlWhole, , , False)
    i = X.Row
    Set X = sh.Range(sh.Cells(1, 1), sh.Cells(sh.Rows.Count, 1)).Find("", , xlValues, xlWhole, , , False)
    If X Is Nothing Then deb = 0 Else deb = X.Row
    sh.Range(sh.Cells(1, 1), sh.Cells(deb - 1, 50)).Copy Destination:=.Range("A1").Offset(i - 1, 0)
    .Cells.Sort Key1:=.Range("C1"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
    i = 0
    Do Until .Cells(1, 1).Offset(i, 0).Value = ""
      i = i + 1
      p = True
      For j = 1 To 26
        p = p And (.Cells(1, 1).Offset(i, j).Value = .Cells(1, 1).Offset(i - 1, j).Value)
      Next j
      If p Then
        .Rows(i).Delete
        i = i - 1
      End If
    Loop
  End With
  Application.Calculation = -4105
End Sub

​

ROGER2327
#4798

Mardi 24 Sable 138 (Sainte Pochetée, gouvernante, SQ)
4 Nivôse An CCXIX
2010-W51-5T00:39:16Z

 

[gege21]

Re : modif de macro

cela ne marche que si je suis sur la feuille 2 sinon le code se plante sur cette ligne

sh.Range(sh.Cells(1, 1), sh.Cells(deb - 1, 50)).Copy Destination:=.Range("A1").Offset(i - 1, 0)

 

[ROGER2327]

Re : modif de macro

Re...

cela ne marche que si je suis sur la feuille 2

C'est fort possible : ça ne fonctionnera que si la feuille active au moment du déclenchement contient des données susceptibles d'être traitées. Pour en dire plus, il faudrait connaître les conditions exactes d'utilisation.​

ROGER2327
#4803

Mardi 24 Sable 138 (Sainte Pochetée, gouvernante, SQ)
4 Nivôse An CCXIX
2010-W51-5T10:59:42Z

 

[gege21]

Re : modif de macro

a l'heure actuel elle pourra être active en feuille 3.7et11

 

[ROGER2327]

Re : modif de macro

Re…

a l'heure actuel elle pourra être active en feuille 3.7et11

Pourquoi pas ? S'il y a des données du même genre que les données de la feuille Feuil2, ça devrait aller. Je ne peux guère en dire plus sans voir la chose…​

ROGER2327
#4805

Mardi 24 Sable 138 (Sainte Pochetée, gouvernante, SQ)
4 Nivôse An CCXIX
2010-W51-5T11:22:39Z