Mise en forme de données multi-colonnes en une colonne

[Merimac]

Bonjour,

Tout d'abord un grand merci pour ce forum et les personnes qui l'anime, je l'ai consult2 plus d'une fois pour trouver des réponses à mes questions mais aujourd'hui je ne trouve pas de solution 😕

Je vous expose ce que je désir faire avec non pas un long discours mais directement à petite échèle ce que je cherche à faire en allant ici example

Ce que je souhaite faire c'est le résultat de la colonne G, qui met ligne après ligne ce qu'il y a dans les 4 première colonnes.

J'ai regardé du côté de TRANSPOSE, DECALER, et VRECHERCHE, mais ne maitrisant pas ces fonctions je n'arrive pas à mes fins.

Si vous pouviez m'aider ça serait super et ça me faciliterais grandement la lecture de mes résultats réel qui sont bien plus long que les aaa, bbb, ccc... que j'ai mis en guise d'exemple.

Merci

 

[jeanpierre]

Re : Mise en forme de données multi-colonnes en une colonne

Bonsoir Merimac et Bienvenue pour ta première question,

Déjà que je pense avoir du mal à pouvoir y répondre, mais s'il faut travailler sur une "image" alors ce n'est même pas la peine.

Peux-tu déposer un petit fichier exemple avec ce que tu as et ce que tu souhaites comme résultat... ?

Normalement tu devrais avoir des réponses

Bonne soirée.

Jean-Pierre

 

[job75]

Re : Mise en forme de données multi-colonnes en une colonne

Bonjour Merimac, jeanpierre,

Avec la disposition du tableau comme sur votre "image", entrez en F2, ou G2 (en tout cas en ligne 2) la formule :

=INDEX(A:D;2+ENT((LIGNE()-2)/4);1+MOD(LIGNE()-2;4))

A tirer vers le bas.

Edit : en fait on peut se passer de la fonction ENT :

=INDEX(A:D;2+(LIGNE()-2)/4;1+MOD(LIGNE()-2;4))

A+

 

[job75]

Re : Mise en forme de données multi-colonnes en une colonne

Re,

Bien sûr si vous êtes sur une version anglaise, remplacez LIGNE par ROW...

A+

 

[job75]

Re : Mise en forme de données multi-colonnes en une colonne

Re,

Revoyant votre "image", je vois que quand une cellule est vide, vous voulez la sauter.

Alors par formule c'est trop compliqué pour moi, je laisse Monique ou Tibo vous trouver éventuellement une solution 🙂

Avec une macro VBA c'est très simple mais je n'ai plus le temps ce soir, désolé.

A+

 

[Merimac]

Re : Mise en forme de données multi-colonnes en une colonne

Bonsoir jeanpierre & job75,

Merci pour vos réponses, qui font grandement avancer mon schilblique.

job75, j'ai fait l'essaie de ta formule, elle marche mais comme tu l'as dis dans ton second message elle ne fait pas l'impasse sur les cellules vides... Je vais donc essayer voir de mon côté si avec des conditions ça peut être retirer...

Pour ce qui est de VBA, je ne sais pas si dans mon cas ça serait une bonne chose car mon tableur est sur Google Docs. A ma connaissance il n'y a pas encore de VBA sur cette plateforme.

Encore Merci

 

[job75]

Re : Mise en forme de données multi-colonnes en une colonne

Bonjour Merimac, le fil, le forum,

On peut utiliser 2 colonnes de restitution :

- en F2 la formule déjà indiquée :

=INDEX(A:D;2+(LIGNE()-2)/4;1+MOD(LIGNE()-2;4))[COLOR="red"]&""[/COLOR]

- en G2 la formule matricielle :

=SI(LIGNES(G$2:G2)>NBVAL(A$2:D$1000);"";INDEX(F:F;PETITE.VALEUR(SI(F$2:F$1000<>[COLOR="Red"]""[/COLOR];LIGNE(F$2:F$1000));LIGNES(G$2:G2))))

Il faut valider cette dernière formule matriciellement : cliquer dans la barre de formule et appuyer simultanément sur les touches Ctrl Maj Entrée.

La colonne F peut être masquée.

NOTA : j'ai ajouté &"" (en rouge) dans la 1ère formule

Edit : si version anglaise, en G2 :

=IF(ROWS(G$2:G2)>COUNTA(A$2:D$1000),"",INDEX(F:F,SMALL(IF(F$2:F$1000<>"",ROW(F$2:F$1000)),ROWS(G$2:G2))))

A+

 

[Merimac]

Re : Mise en forme de données multi-colonnes en une colonne

Bonjour job75,

Je vois votre réponse mais je suis au travail et sans mon document, je teste donc ça ce soir.

Encore Merci pour le coup de main.

 

[Merimac]

Re : Mise en forme de données multi-colonnes en une colonne

Bonjour job75,

J'ai fais l'essai de ce que tu m'as donné, et ça marche \0/ aussi bien dans Excel, que dans Google Spreadsheet. Merci.

Et encore Merci pour m'avoir fournit la version anglaise 😉

PS : j'ai mis à jour mon document Google Spreadsheet, et ne le supprimerais pas pour que ça puisse en aider d'autre 😉

 

[Monique]

Re : Mise en forme de données multi-colonnes en une colonne

Bonjour,

Sans colonne intermédiaire :

[FONT=Verdana][FONT=Verdana]=INDIRECT(ADRESSE(MIN(SI((Zone<>"")*(NB.SI(F$1:F1;Zone)=0);LIGNE(Zone)));MIN(SI((Zone<>"")*(NB.SI(F$1:F1;Zone)=0)*(LIGNE(Zone)=MIN(SI((Zone<>"")*(NB.SI(F$1:F1;Zone)=0);LIGNE(Zone))));COLONNE(Zone)))))[/FONT]
[/FONT]

En angliche :

[FONT=Verdana][FONT=Verdana][FONT=Verdana]=INDIRECT(ADDRESS(MIN(IF((Zone<>"")*(COUNTIF(F$1:F1,Zone)=0),ROW(Zone))),MIN(IF((Zone<>"")*(COUNTIF(F$1:F1,Zone)=0)*(ROW(Zone)=MIN(IF((Zone<>"")*(COUNTIF(F$1:F1,Zone)=0),ROW(Zone)))),COLUMN(Zone)))))[/FONT]
[/FONT][/FONT]

En partant de la 1ère ligne ou en partant de la 1ère colonne

Formule matricielle, à valider par ctrl, maj et entrée.