Microsoft 365 Mettre la 4ème colonne d'une ListBox au format [h]:mm

NONO14 · Hier à 09:55

Bonjour à toutes et à tous,

Dans mon application j'ai supprimé la ComboBox (ceux qui me suivent comprendront - https://excel-downloads.com/threads...omboBox à 3 colonnes avec les données d'un TS ) et je l'ai remplacé par une ListBox.
La ListBox est bien alimentée selon le code ci-joint, cependant je souhaiterai que la 4ème colonne soit au format [h]:mm.
Avec le code ci-joint, la 4ème colonne donne le résultat ":12".
Qu'ai-je fais qui ne convienne pas ?
Merci par avance pour votre aide

VB:

Sub RempliListBox()
Dim Ws As Worksheet
Dim Tbl As ListObject
Dim I As Long, Col As Long
Dim Data As Variant

'Définir la feuille de calcul et le tableau structuré
    Set Ws = Sheets("Liste_agents")
    Set Tbl = Ws.ListObjects("t_Noms")
   
'On récupére les données du TS
    Data = Tbl.DataBodyRange.Value
   
   
    With UfGestTemps.MultiPage1.Pages(0)

'On définie le nbre de colonnes de la ListBox
    .Lst_Employ.ColumnCount = 4

'On remplit la ListeBox avec les données du TS
    For I = 1 To UBound(Data, 1)
        .Lst_Employ.AddItem
            For Col = 1 To 4

'On formate la 4ème colonne au format "[h]:mm"
                If Col = 4 Then
                    .Lst_Employ.List(I - 1, Col - 1) = Format(Data(I, Col), "[h]:mm")
                Else
                    .Lst_Employ.List(I - 1, Col - 1) = Data(I, Col)
                End If
            Next Col
    Next I
End With
End Sub

TooFatBoy · Hier à 13:33

Bonjour,

Ta macro de #1 :

VB:

Sub RempliListBox()
'
Dim Ws As Worksheet
Dim Tbl As ListObject
Dim I As Long, Col As Long
Dim Data As Variant

    ' Définir la feuille de calcul et le tableau structuré
    Set Ws = Sheets("Liste_agents")
    Set Tbl = Ws.ListObjects("t_Noms")

    ' On récupére les données du TS
    Data = Tbl.DataBodyRange.Value

    With UfGestTemps.MultiPage1.Pages(0)

        ' On définie le nbre de colonnes de la ListBox
        .Lst_Employ.ColumnCount = 4

        ' On remplit la ListBox avec les données du TS
        For I = 1 To UBound(Data, 1)
            .Lst_Employ.AddItem
            For Col = 1 To 4
                ' On formate la 4e colonne au format "[h]:mm"
                If Col = 4 Then...

Franc58 · Hier à 10:18

Bonjour, peut-être un problème de donnée source qui ne serait pas numérique ?

NONO14 · Hier à 10:23

Franc58 à dit:
Bonjour, peut-être un problème de donnée source qui ne serait pas numérique ?

Bonjour
Je vais regarder

vgendron · Hier à 11:08

Bonjour

essaie de remplacer
.Lst_Employ.List(I - 1, Col - 1) = Format(Data(I, Col), "[h]:mm")

par

.Lst_Employ.List(I - 1, Col - 1) = application.text(Data(I, Col), "[h]:mm")

patricktoulon · Hier à 11:27

re
bonjour juste en passant
pour être sur
.Lst_Employ.List(I - 1, Col - 1) = Format(cdate(Data(I, Col)), "hh:mm")

au cas ou tes cellules serait du texte de date

Oupss !! edit :j'ai réédité le format

job75 · Hier à 11:36

Bonjour à tous,

@patricktoulon, la fonction VBA Format ne reconnait pas le format "[h]:mm".

En utilisant la fonction Excel Application.Text il n'y a plus de problème.

A+

patricktoulon · Hier à 11:46

Bonjour @job75
à oui c'est vrai il faut enlever les crochets
a voir si data(i,col) est du texte ou une date (num de serie excel date)

job75 · Hier à 11:50

Application.Text doit fonctionner que la date soit un nombre ou du texte.

job75 · Hier à 12:03

Bah @NONO14 je viens de dire que la solution de patricktoulon ne fonctionne pas !

patricktoulon · Hier à 12:11

re
je vous laisse le soin d'en tirer vos conclusions

VB:

Sub test()
    Dim t As String, C As Double
    t = "24/05/2024 22:33:55"
    MsgBox Application.Text(t, "[h]:mm")
    
    t = "22:33:55"
    MsgBox Application.Text(t, "[h]:mm")

    t = "24/05/2024 22:33:55"
    MsgBox Format(CDate(t), "hh:mm")

    t = "22:33:55"
    MsgBox Format(CDate(t), "hh:mm")

    C = 145437.456
    MsgBox Format(CDate(C), "hh:mm")

End Sub

NONO14 · Hier à 12:18

Bonjour à tous,
Effectivement le code proposé par patricktoulon au #5 ne fonctionne pas.
Par contre celui de Vgendron au #4 fonctionne bien.
Merci à tous pour votre aide.
Encore un problème de résolu.

vgendron · Hier à 12:18

patricktoulon à dit:
re
je vous laisse le soin d'en tirer vos conclusions

Bonjour

et avec ceci..??
tu ne le sais sans doute pas.. mais le besoin est d'afficher une durée..pas une date

VB:

Sub test()
    Dim t As String, C As Double
  
    
    t = "25:33:55"
    MsgBox Application.Text(t, "[h]:mm")



    t = "25:33:55"
    MsgBox Format(CDate(t), "hh:mm")

End Sub

patricktoulon · Hier à 12:21

Bonjour @vgendron
ce que j'ai donné est une formulation universelle qui accepte toute date ou timecode valide sous toute ses formes
comme vous avez pu le constater avec ma petite sub (si vous l'avez testé)
c'est pas le cas avec application.text

le principe est simple
on met la chaine dans le bloc Cdate qui en fait une date avec time code ou pas ou rien que le timecode et on applique le format

en interne cdate transforme la chaine en valeur numérique de date
parti de la comme avec le dernier exemple on applique donc le format a un numéro de serie de date (excel)

c'est simple et ça passe partout ( à condition que la chaine soit valide bien entendu)

vgendron · Hier à 12:23

bien sur que je l'ai testée..
et vous..? avez vous testé la mienne.. qui est la votre avec juste des valeurs de t différentes...

patricktoulon · Hier à 12:32

d'ailleurs même son homologue en formiule excel en perd les pédale contrairement à ce que l'on croit

Microsoft 365 Mettre la 4ème colonne d'une ListBox au format [h]:mm

NONO14

XLDnaute Occasionnel

TooFatBoy

Franc58

XLDnaute Occasionnel

NONO14

XLDnaute Occasionnel

vgendron

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

NONO14

XLDnaute Occasionnel

vgendron

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

vgendron

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Discussions similaires