mélange de ET et de OU

[JJ1]

Bonjour à tous,
je voudrais dans une formule combiner des ET et des OU:
A2 et B2 contiennent chacune 2 lettres.
La formule au dessus en A1 renverra 1 (sinon 0) si:
A2=UA et B2= UB ou UE ou DA ou DB ou DE
OU SI
A2=UB et B2= UA et UB ou UE ou DA ou DB ou DE
OU SI
A2= UC et B2= DB
OU SI
A2= UD et B2= DB
OU SI
A2= UE et B2= UA ou UB ou DA ou DB ou DE

ouf!!!
Quelle formule !!!
Si quelqu'un a une idée de formule pour condenser tout ça, je suis preneur!!
merci

 

[wilfried_42]

Re : mélange de ET et de OU

bonjour jj1

= (1*(A2="UA")*(esterreur(cherche(B2;"UBUEDADBDE"))=FAUX))+(1*(A2="UB")*(esterreur(cherche(B2;"UAUBUEDADBDE"))=FAUX))+(1*(A2="UC")*(B2="DB")) + (1*(A2="UD")*(B2="DB")) + (1*(A2="UE")*esterreur(cherche(B2;"UAUBDADBDE"))=FAUX)

c'est une formule de calcul, * --> ET, + --> OU

ouf, c'etait dur, j'espere que c'est bon, sinon un ptit fichier nous aiderait

 

[SergiO]

Re : mélange de ET et de OU

Bonjour JJ1,

Je n'ai pas compris la 2ème ligne : A2=UB et B2= UA et UB ou UE ou DA ou DB ou DE

Dans la formule qui suit, ça marche donc pour : A2=UB et B2= UA ou UE ou DA ou DB ou DE

Voici la formule pas si condensée que ça tout de même :

=((A2="UA")*((B2="UB")+(B2="UE")+(B2="DA")+(B2="DB")+(B2="DE")))+((A2="UB")*((B2="UA")+(B2="UE")+(B2="DA")+(B2="DB")+(B2="DE")))+((A2="UC")*(B2="DB"))+((A2="UD")*(B2="DB"))*((A2="UE")*((B2="UA")+(B2="UB")+(B2="DA")+(B2="DB")+(B2="DE")))

@+

Attention : pense à enlever les espaces !!!

 

[Bebere]

Re : mélange de ET et de OU

bonsoir JJ1,Sergio,Wilfried
formule en A1

=SI(ET(A2="UA";OU(B2="DA";B2="DB";B2="DE";B2="UB";B2="UE"));1;SI(ET(A2="UB";OU(B2="DA";B2="DB";B2="DE";B2="UA";B2="UB";B2="UE"));1;SI(ET(A2="UE";OU(B2="DA";B2="DB";B2="DE";B2="UA";B2="UB"));1;SI(ET(OU(A2="UC";A2="UD");B2="DB");1;0))))


à bientôt

 

[JJ1]

Re : mélange de ET et de OU

Bonsoir à tous et merci pour vos formules.
je commençais moi aussi avec la fonction SI (très longue....) quand soudain j'ai eu une idée (non pas la grâce ! ):
j'ai concaténé les 2 cellules A2 et B2 avec & dans une autre cellule
j'ai inscris dans une colonne les différentes possibilités acceptées:
UAUB
UAUE
etc...
et ensuite je n'ai eu qu'a faire un rechercheV ?
simplifié non?
bonne soirée et merci à tous