Masquer et afficher plusieurs colonnes

[apdf1]

Bonsoir,

Je suis à la recherche d'un code plus simple pour cacher et afficher deux zones de colonnes.

Private Sub CommandButton1_Click()

If CommandButton1.Caption = "Masquer" Then
    CommandButton1.Caption = "Afficher"
    ' Worksheets(1).Columns("E:S").Hidden = True
     
        Columns("E:S").Select
    Selection.EntireColumn.Hidden = True
    Columns("V:AC").Select
    Selection.EntireColumn.Hidden = True
Else
    CommandButton1.Caption = "Masquer"
  ' Worksheets(1).Columns("E:S").Hidden = False
   
      Columns("E:S").Select
    Selection.EntireColumn.Hidden = False
    Columns("V:AC").Select
    Selection.EntireColumn.Hidden = False
   
   
End If
End Sub

Un très grand merci à tout ceux qui pourront m'aider...
Cordialement
Max

 

[dra72]

Re : Masquer et afficher plusieurs colonnes

Bonsoir,
Tu peux supprimer tous les select inutiles et qui ralentissent le code, même si c'est imperceptible pour le code présent.
d'où:

Private Sub CommandButton1_Click()

If CommandButton1.Caption = "Masquer" Then
    CommandButton1.Caption = "Afficher"
    ' Worksheets(1).Columns("E:S").Hidden = True
     
    Columns("E:S").EntireColumn.Hidden = True
    Columns("V:AC").EntireColumn.Hidden = True
Else
    CommandButton1.Caption = "Masquer"
  ' Worksheets(1).Columns("E:S").Hidden = False
   
    Columns("E:S").EntireColumn.Hidden = False
    Columns("V:AC").EntireColumn.Hidden = False
   
   
End If
End Sub

Bonne soirée.

 

[dra72]

Re : Masquer et afficher plusieurs colonnes

Et pour aller plus loin:
Private Sub CommandButton1_Click()

If CommandButton1.Caption = "Masquer" Then
    CommandButton1.Caption = "Afficher"
    ' Worksheets(1).Columns("E:S").Hidden = True
     
    Columns("E:S").Hidden = True
    Columns("V:AC").Hidden = True
Else
    CommandButton1.Caption = "Masquer"
  ' Worksheets(1).Columns("E:S").Hidden = False
   
    Columns("E:S").Hidden = False
    Columns("V:AC").Hidden = False
   
   
End If
End Sub

 

[Pierrot93]

Re : Masquer et afficher plusieurs colonnes

Bonjour,

une autre solution, à placer dans le module de la feuille où se trouve le bouton et les colonnes, sinon préciser les objets "sheets" concernés :

Option Explicit
Private Sub CommandButton1_Click()
With Range("E:S,V:AC").EntireColumn
    .Hidden = Not .Hidden
    CommandButton1.Caption = IIf(.Hidden, "AFFICHER", "MASQUER")
End With
End Sub

bonne journée
@+

 

[apdf1]

Re : Masquer et afficher plusieurs colonnes

Bonjour Pierrot

Je te remercie beaucoup.

Bonne journée

@+

Max

 

[TempusFugit]

Re : Masquer et afficher plusieurs colonnes

Bonjour


En utilisant un ToggleButton plutot qu'un CommandButton

Private Sub ToggleButton1_Click()
Range("E:S,V:AC").EntireColumn.Hidden = ToggleButton1
End Sub

Quand le togglebutton est "appuyé" : les colonnes sont masquées
Quand il est "relaché": les colonnes sont affichées

Post scriptum: mieux vaut cocher dans les propriétés du contrôle
Ne pas déplacer ou dimensionner avec les cellules