macro calendriers outlook

[dewoud]

bonjour a tous,

je cherche une macro qui puisse m'enregistrer mes differents calendriers outlook vers differents fichiers ou feuille excel.
je dois pourvoir indiquer la date de debut et de fin avant l'extraction.

je sais que c'est possible manuellemnt, mais j'ai plus de 20 calendriers et j'aimerais que ca ce fasse auto.

cela est il possible ?

j'ai fouiller un peu partout, je n'ai rien trouver

si vous avez une piste, et si vous voulez m'aider dans le projet, alors merci beaucoup.

la finalité, imprimer des feuilles de routes hebdomadaire

je boss sur office 2007

merci de m'avoir lu

david

 

[MichelXld]

Re : macro calendriers outlook

Bonjour,


En fait ça dépend ou sont stockés tes calendriers.
Un exemple qui extrait les rendez vous du répertoire Calendrier par défaut, et tous ses sous dossiers :

Option Explicit
 
Sub BoucleSousDossiersCalendrier()
    'nécessite d'activer la référence
        'Microsoft Outlook xx.xx Object Library

    Dim olApp As Outlook.Application
    Dim olNs As NameSpace
    Dim Dossier As MAPIFolder, SousDos As MAPIFolder
 
    Set olApp = New Outlook.Application
    Set olNs = olApp.GetNamespace("MAPI")
 
    'Indique le calendrier définit par défaut
    Set Dossier = olNs.GetDefaultFolder(olFolderCalendar)
    ExtractionCalendrier Dossier
 
    'Boucles sur les sous dossiers
    For Each SousDos In Dossier.Folders
            ExtractionCalendrier SousDos
    Next SousDos
 
    Set Dossier = Nothing
    Set olNs = Nothing
    Set olApp = Nothing
End Sub
 
 
Sub ExtractionCalendrier(Rep As MAPIFolder)
    Dim olRdv As AppointmentItem
 
    'Boucle sur les éléments du répertoire
    For Each olRdv In Rep.Items
        'Affichage dans la fenêtre d'exécution : CTRL+G
        Debug.Print Rep.Name & "/ " & olRdv.Subject & " / " & olRdv.Start
    Next olRdv
End Sub

bonne journée
michel
Microsoft Excel MVP