Lier animateurs avec ses jeunes

Private Sub Worksheet_Change(ByVal Target As Range)
 Dim Trouve As Range
 Dim Pointe As Long
 Dim ici As String
' si la cellule ayant changée est la C4
 If Target.Cells(1, 1).Address = "$C$4" Then
'Désactive les évenementiels le temps d'éxecuter l'ensemble des instructions
 Application.EnableEvents = False
'Cherche le nom de l'animateur
  Set Trouve = Sheets("Animateurs  jeunes ").Range("C4:AZ4").Find(Target.Value, lookat:=xlWhole)
'Si animateur trouvé
  If Not Trouve Is Nothing Then
 ' pour les lignes 8 à 15 
 For Pointe = 8 To 15
 'Remise à zéro des cellules B et C pour la ligne en cours
  Range("B" & Pointe) = ""
  Range("C" & Pointe) = ""
 'Calcul de la 1ere cellule de la liste des noms des jeunes
  ici = Sheets("Animateurs  jeunes ").Range(Trouve.Address).Offset(1, 0).Address
'Appel une routine pour mettre en place une liste de validation , selon les paramètres passés soit cellule où l'on 'doit posé la liste de validation et la liste elle même
'pour colonne B 
 Valid_Données "B" & Pointe, ici
  ici = Sheets("Animateurs  jeunes ").Range(ici).Offset(0, 1).Address
'pour colonne C 
 Valid_Données "C" & Pointe, ici
  Next Pointe
  End If
'Réactivation des évenements
  Application.EnableEvents = True
 End If
End Sub

Sub Valid_Données(adresse As String, liste As String)
'
Dim Derlig As Long
Dim Lieu As String
' Macro1 Macro
'Recupére la lettre définissant la colonne
Lieu = Split(liste, "$")(1)
'Cherche la dernière ligne de la liste
Derlig = Sheets("Animateurs  jeunes ").Range(Lieu & Rows.Count).End(xlUp).Row
'Pose des éléments de validation
    With Range(adresse).Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
        xlBetween, Formula1:="='Animateurs  jeunes '!" & liste & ":" & Lieu & Derlig
        .IgnoreBlank = True
        .InCellDropdown = True
        .InputTitle = ""
        .ErrorTitle = ""
        .InputMessage = ""
        .ErrorMessage = ""
        .ShowInput = True
        .ShowError = True
    End With
End Sub