Lien hypertexte automatique

[walyddu59]

Salut a tous,

Je réalise en ce moment un code VBA qui puissent rechercher tout les fichier excel présent dans un répertoire , a partir de ces fichiers il me crée dans la colonne A un lien hypertexte pour chaque fichier présent dans le répertoire , j'ai cree la fonction mais je bloque au niveaux des boucles je n'arrive pas a programmer le code , si quelqu’un pouvez m'aidez merci .

voici mon debut de code :

Sub lien()

    Set Fichier = Application.FileSearch
       
    With Fichier
        .LookIn = "C:\" 'Dossier dans lequel chercher les fichiers
       .Filename = "*.xls" 'Extension des fichiers a trouver
       If .Execute > 0 Then 'S'il en trouve

        ActiveSheet.Hyperlinks.Add Anchor:=selection, Address:= _
            "", TextToDisplay:=""
           
    End Sub

 

[MichD]

Re : Lien hypertexte automatique

Bonjour,

Essaie ceci :

Sub test()

Dim Répertoire As String
Dim A As Integer, Fichier As String

'Variables à définir :
Répertoire = "c:\Users\DM\Documents\"
Fichier = Dir(Répertoire & "*.xl*")

Application.ScreenUpdating = False
Application.EnableEvents = False
Do While Fichier <> ""
    A = A + 1
    With Worksheets("Sheet1") 'Nom Feuille à adapter
        With Range("A" & A)
            .Hyperlinks.Add Anchor:=.Item(1, 1).Cells, _
                Address:=Répertoire & Fichier, _
                ScreenTip:=Répertoire & Fichier
        End With
    End With
    Fichier = Dir()
Loop
Application.EnableEvents = True
Application.ScreenUpdating = True
End Sub

 

[walyddu59]

Re : Lien hypertexte automatique

Salut,MichD

Merci pour la macro , c'est nickel , un grand merci pour toi mais je voulez savoir s'il y'avait moyen d'afficher uniquement le nom du fichier en retirant donc le chemin du fichier.

 

[francedemo]

Re : Lien hypertexte automatique

bonjour walyddu59, MichD

tu ajoutes :
TextToDisplay:= FIchier, _
avant ScreenTip
ça donne:
.Hyperlinks.Add Anchor:=.Item(1, 1).Cells, _
Address:=Répertoire & Fichier, _
TextToDisplay:= FIchier, _
ScreenTip:=Répertoire & Fichier

à+

 

[walyddu59]

Re : Lien hypertexte automatique

Salut francedemo,

Merci a toi pour la modification c'est plus lisible de cette façon, merci a vous deux pou avoir régler mon problème aussi rapidement.