Liaison cellules et commentaires

[Moniato]

Bonsoir, peut être que pour les experts cette question pourra paraitre stupide mais étant novice je tente tout de même.
Peut on lier le commentaire d'une cellule à une cellule date je m'explique...
J'ai un calendrier perpétuel où dans certaines cellules je voudrais insérer un commentaire pour indiquer des précisions sur cette date (rdv et autres). Je sais qu'il existe des agendas mais le fichier que j'essaie de créer est plus adapté et personnalisé à mes besoins.
Donc pour revenir à ces commentaires, bien sûr lorsque je change de mois, les jours et les week-ends se décalent par contre les commentaires eux restent figés aux cellules du calendrier.

Je ne sais pas si c'est possible si la réponse.
Si quelqu'un peut me répondre.
Merci

 

[job75]

Bonjour Moniato,

Voyez le fichier joint et cette macro dans le code de la feuille :

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [A:A]) Is Nothing Then Exit Sub
Dim c As Range, p%, dat As Long, i As Variant
Application.ScreenUpdating = False
'---mémorisation des commentaires---
For Each c In [A1].CurrentRegion.Resize(, 1)
    If Not c.Comment Is Nothing Then
        p = InStr(c.Comment.Text & " ", " ")
        If IsDate(Left(c.Comment.Text, p - 1)) Then _
            If Application.CountIf(Columns("H"), c.Comment.Text) = 0 _
                Then Cells(Rows.Count, "H").End(xlUp)(2) = c.Comment.Text
        c.ClearComments
    End If
Next
'---restitution des commentaires aux bonnes dates ---
For Each c In [H1].CurrentRegion.Offset(1)
    If c <> "" Then
        p = InStr(c & " ", " ")
        dat = CDbl(CDate(Left(c, p - 1)))
        i = Application.Match(dat, Columns(1), 0)
        If IsNumeric(i) Then
            With Cells(i, 1).AddComment
                .Text c.Text
                .Shape.TextFrame.AutoSize = True
                .Visible = True
            End With
        End If
    End If
Next
End Sub

A+

 

[Moniato]

Bonjour et un grand merci pour votre réponse job75.
Alors effectivement cela fonctionne à merveille sur votre fichier joint, c'est exactement ce que je cherche à effectuer.
Malheureusement sur mon fichier et donc mes cellules cela ne fonctionnent pas.
Je pense que cela est peut être du au fait que mes cellules contiennent déjà une formule, je ne sais pas.
Je continue à chercher merci pour votre aide.

 

[job75]

Si vous voulez vraiment être aidé joignez votre fichier (sans données confidentielles).