Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuille

[Yaloo]

Bonjour à tous,

Pour aider un demandeur et pour mon savoir personnel.

Dans une feuille "Base", est-il possible de récupérer le N° d'un bouton (juste après le mot "Bouton ") pour lancer une macro permettant, par exemple, d'ouvrir la feuille dont le CodeName est "Feuil" & N°Bouton ?

J'ai essayé avec Application.Caller mais....

Voici mes premiers essais, non concluant :

Option Explicit
Sub ActFeuille()
Dim Feuille, Num&
 Num = Right(Application.Caller, Len(Application.Caller) - 7)
 Feuille = "Feuil" & Num
 Active_Feuille Feuille
End Sub
Private Sub Active_Feuille(Feuille As Worksheet)
  Feuille.Activate
  'plus si affinité
  'copie
  'mise en forme
End Sub

Difficile d'expliquer tout ça, voir l'exemple dans le fichier ci-joint

Merci d'avance

Martial

PS : Est-il possible de le faire avec des boutons ActiveX ?

 

[Pierrot93]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Bonjour,

si tu veux activer la feuille par son codename et non par son nom, regarde peut être ceci :

Option Explicit
Sub ActFeuille()
Dim Feuille, Num&
Num = Right(Application.Caller, Len(Application.Caller) - 7)
Feuille = "Feuil" & Num
Active_Feuille Feuille
End Sub
Private Sub Active_Feuille(ByVal Feuille As String)
ThisWorkbook.VBProject.VBComponents(Feuille).Activate
End Sub

bon après midi
@+

 

[Yaloo]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Salut Pierrot,

Merci pour ta réponse mais il m'indique une erreur 1004 lorsque je suis sur la ligne

ThisWorkbook.VBProject.VBComponents(Feuille).Activate

Faut-il cocher une référence particulière ?

A+

 

[Pierrot93]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Re,
A priori tu as une espace ici "Activ ate"... sinon cocher l'equivalent de "faire confiance au projet visual basic", sous 2010 ca doit être "accès approuvé au modèle d'objet du projet vba"

 

[Pierrot93]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Re,

viens de tester chez moi sous 2010 fonctionne, avec l'option indiquée précédemment cochée....

 

[Yaloo]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Re,

Il n'y avait pas d'espace dans "Active" par contre c'est bien ok lorsque l'on coche l'option.

Sais-tu si ça peut fonctionner avec des Bouton de commande ActiveX ?

A+

 

[Pierrot93]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Re,

Sais-tu si ça peut fonctionner avec des Bouton de commande ActiveX ?

bah... "Application.Caller" renverra une erreur.... regarde avec un module de classe devrait faire l'affaire...

 

[Yaloo]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Bah !!!! justement j'ai essayé mais .... je ne suis pas très doué en module de classe.

 

[Pierrot93]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Re,

là en l'état pas beaucoup de code 🙂

dans un module standard :

Option Explicit
Public tb() As New Classe1

Dans un module de classe, nom du module (classe1) :

Option Explicit
Public WithEvents mbouton As MSForms.CommandButton
Private Sub mbouton_Click()
ThisWorkbook.VBProject.VBComponents("Feuil" & Mid(mbouton.Name, 14)).Activate
End Sub

dans le module thisworkbook :

Option Explicit
Private Sub Workbook_Open()
Dim x As OLEObject, i As Byte
For Each x In Sheets("Base").OLEObjects
    If TypeName(x.Object) = "CommandButton" Then
        i = i + 1
        ReDim Preserve tb(1 To i)
        Set tb(i).mbouton = x.Object
    End If
Next x
End Sub

 

[Yaloo]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Re,

Merci Pierrot, ça fonctionne tout à fait.

Je me le garde dans mes archives, c'est sûr il va resservir à un moment ou à un autre.

Merci encore

Martial

 

[Si...]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

salut

autres solutions (ActiveX ou pas) avec une seule macro commune.

 

[Yaloo]

Re : Lancer une macro depuis plusieurs boutons pour récupérer le CodeName d'une feuil

Merci Si...