Lancer Macro du fichier A en action sur le Fichier B Erreur:(ThisWorkbook.Sheets)

[bloomby]

Bonjour à tous,

Je dois à partir du fichier A lancer une macro qui roule sur le fichier B
je croyais qu'en indiquant Windows("B.xls").Activate au début de la macro cette dernière prendrais en considération ce fichier pour :

Set f = ThisWorkbook.Sheets("Sheet1")
Set f2 = ThisWorkbook.Sheets("Data1")

mais ce n'est pas le cas

voici la macro

Sub Formules1()
Dim f As Worksheet: Dim f2 As Worksheet
Dim formule As String: Dim i: Dim fin As Range

Windows("B.xls").Activate

Set f = ThisWorkbook.Sheets("Sheet1")
Set f2 = ThisWorkbook.Sheets("Data1")

Application.ScreenUpdating = False
f.Range("B200").CurrentRegion.ClearContents

formule = _
  "..."

For i = 2 To Evaluate(ActiveWorkbook.Names("Nbr").Value)
Set fin = f2.Cells(275, i)
    f.Range(f.Cells(200, i), _
    fin.Address).FormulaR1C1 = formule
Next
Application.ScreenUpdating = True
End Sub

merci

 

[kjin]

Re : Lancer Macro du fichier A en action sur le Fichier B Erreur🙁ThisWorkbook.Sheets

Bonsoir,
Difficile de comprendre ce que tu veux faire, mais si tu actives le fichier B, pourquoi faire compliqué

Sub Formules1()
Dim f As Worksheet, f2 As Worksheet
Dim formule As String, i, fin As Range

Windows("B.xls").Activate
Set f = Sheets("Sheet1")
Set f2 = Sheets("Data1")
'....

Vaudrait peut-être mieux mettre un contrôle pour t'assurer que le fichier est bien ouvert !
A+
kjin

 

[youky(BJ)]

Re : Lancer Macro du fichier A en action sur le Fichier B Erreur🙁ThisWorkbook.Sheets

Bonsoir,
Si les classeurs sont dans le mm répertoire
voici une maniere de faire, fichier B.xls ouvert ou fermé...
On gère l'erreur si le fichier est fermé et on l'ouvre si erreur

chemin = ThisWorkbook.Path
On Error Resume Next
Workbooks("B.xls").Activate
If Err.Number = 9 Then
Err = 0
Workbooks.Open Filename:=chemin & "\B.xls"
End If

 

[skoobi]

Re : Lancer Macro du fichier A en action sur le Fichier B Erreur🙁ThisWorkbook.Sheets

Bonjour bloomby, youky
kjin 🙂,

en complément de ce que dis kjin, ThisWorkbook ne fait pas référence au classeur actif mais au classeur auquel appartient la macro.
Pour spécifier le classeur actif, il faut utiliser ActiveWorkbook.

 

[bloomby]

Re : Lancer Macro du fichier A en action sur le Fichier B Erreur🙁ThisWorkbook.Sheets

Bonsoir Kjin Youky et skoobi,

merci de vos précieux conseils, j'ai pus résoudre ce problème.
maintenant, je me questione sur la façon d'ouvrire le userform1 du classeur B
à partir du classeur A
ex:
CLasseurB.Userform1.Show

merci

 

[youky(BJ)]

Re : Lancer Macro du fichier A en action sur le Fichier B Erreur🙁ThisWorkbook.Sheets

Re bonjour,
ceci en classeur A

Workbooks("B.xls").Activate
Application.Run ("B.xls!OuvreUser")

dans le classeur B tu mets dans un module
Sub OuvreUser()
Userform1.Show
'si besoin remplir les listes ou textbox
End Sub

J'ai testé ca marche

 

[bloomby]

Re : Lancer Macro du fichier A en action sur le Fichier B Erreur🙁ThisWorkbook.Sheets

Bonjour Youky,
cela fonctionne effectivement très bien
merci