La méthode value de l'objet range a échoué

P

PBeaudet

XLDnaute Nouveau
Bonjour à tous,

J'ai le code suivant :

Private Sub Worksheet_Change(ByVal Target As Range)


If Worksheets("Personnage").Cells(4, 22).Value = "Matelassée" Then
Worksheets("Personnage").Cells(4, 24).Value = Worksheets("Équipements").Cells(3, 3).Value
End If

If Worksheets("Personnage").Cells(4, 22).Value = "Cuir" Then
Worksheets("Personnage").Cells(4, 24).Value = Worksheets("Équipements").Cells(4, 3).Value
End If

If Worksheets("Personnage").Cells(4, 22).Value = "Cuir renforcé" Then
Worksheets("Personnage").Cells(4, 24).Value = Worksheets("Équipements").Cells(5, 3).Value
End If

If Worksheets("Personnage").Cells(4, 22).Value = "Cuir à plaques" Then
Worksheets("Personnage").Cells(4, 24).Value = Worksheets("Équipements").Cells(6, 3).Value
End If

If Worksheets("Personnage").Cells(4, 22).Value = "Écailles" Then
Worksheets("Personnage").Cells(4, 24).Value = Worksheets("Équipements").Cells(7, 3).Value
End If

If Worksheets("Personnage").Cells(4, 22).Value = "Mailles" Then
Worksheets("Personnage").Cells(4, 24).Value = Worksheets("Équipements").Cells(8, 3).Value
End If

If Worksheets("Personnage").Cells(4, 22).Value = "Plaques" Then
Worksheets("Personnage").Cells(4, 24).Value = Worksheets("Équipements").Cells(9, 3).Value
End If

If Worksheets("Personnage").Cells(4, 22).Value = "Plaques renforcées" Then
Worksheets("Personnage").Cells(4, 24).Value = Worksheets("Équipements").Cells(10, 3).Value
End If

'If Worksheets("Personnage").Cells(4, 23).Value = "Légère" Then
' Worksheets("Personnage").Cells(4, 25).Value = Worksheets("Équipements").Cells(3, 4).Value
' Worksheets("Personnage").Cells(4, 26).Value = Worksheets("Équipements").Cells(3, 6).Value
' Worksheets("Personnage").Cells(4, 27).Value = Worksheets("Équipements").Cells(3, 7).Value
'End If

'If Worksheets("Personnage").Cells(6, 27).Value = "Rondache" Then
' Worksheets("Personnage").Cells(7, 27).Value = Worksheets("Équipements").Cells(3, 13).Value
'End If

End Sub


Le problème que j'ai c'est que dès que je met un des deux derniers IF en fonction en retirant les guillemets, j'ai de code d'erreur : la méthode value de l'objet range a échoué. Quand ils sont en commentaire, le code fonctionne correctement.

Je ne vois pas ce qu'il y a de différent qui fait que ça ne fonctionne pas.

Merci à vous!
 
Trier par date Trier par votes
sylvanu

sylvanu

XLDnaute Barbatruc
Supporter XLD
Bonjour PBeaudet, Job,
Votre sub Worksheet_Change est ré-entrante : elle est appelée quand vous modifiez votre feuille. Sub qui modifie cette même feuille donc qui rappelle la sub.
Il faut bloquer les events :
VB: 
Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
....
Application.EnableEvents = True
End Sub
En PJ une maquette qui fonctionne avec tous les IF.
D'autre part vous pouvez simplifier ces IF avec des Cases, ce sera plus rapide.
 

Pièces jointes

  • Classeur111.xlsm
    21.9 KB · Affichages: 10
Vote positif 0 Vote négatif
job75

job75

XLDnaute Barbatruc
Votre macro évènementielle va donc boucler sans fin si les tests If renvoient True.

Il faut donc en début de macro ajouter :
VB: 
Application.EnableEvents = False
Et en fin de macro :
VB: 
Application.EnableEvents = True
J'avais donné au départ ces informations mais j'ai préféré faire d'abord la demande du post #3.

Salut sylvanu.
 
Vote positif 0 Vote négatif
sylvanu

sylvanu

XLDnaute Barbatruc
Supporter XLD
Re le fil,
Les Case et With simplifie la lecture et accélère le processus. en PJ avec le code.
VB: 
Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
With Worksheets("Personnage")
    Select Case .Cells(4, 22)
        Case "Matelassée"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(3, 3).Value
        Case "Cuir"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(4, 3).Value
        Case "Cuir renforcé"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(5, 3).Value
        Case "Cuir à plaques"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(6, 3).Value
        Case "Écailles"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(7, 3).Value
        Case "Mailles"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(8, 3).Value
        Case "Plaques"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(9, 3).Value
        Case "Plaques renforcées"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(10, 3).Value
    End Select
    If .Cells(4, 23).Value = "Légère" Then
        .Cells(4, 25).Value = Worksheets("Équipements").Cells(3, 4).Value
        .Cells(4, 26).Value = Worksheets("Équipements").Cells(3, 6).Value
        .Cells(4, 27).Value = Worksheets("Équipements").Cells(3, 7).Value
    End If
    If .Cells(6, 27).Value = "Rondache" Then
        .Cells(7, 27).Value = Worksheets("Équipements").Cells(3, 13).Value
    End If
End With
Application.EnableEvents = True
End Sub
 

Pièces jointes

  • Classeur111 (V2).xlsm
    19.8 KB · Affichages: 8
Vote positif 0 Vote négatif
sylvanu

sylvanu

XLDnaute Barbatruc
Supporter XLD
Re le fil,
A l'examen de votre macro vous exécutez toute la macro à chaque fois qu'une valeurs change dans la feuille.
Or seules les cellules V4,W4 et AA6 sont concernées.
Alors autant n'effectués les calculs que si une de ces trois cellules a été modifiée.
On y gagne en temps.
VB: 
Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
With Worksheets("Personnage")
If Target.Address = "$V$4" Then
    Select Case Target.Value
        Case "Matelassée"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(3, 3).Value
        Case "Cuir"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(4, 3).Value
        Case "Cuir renforcé"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(5, 3).Value
        Case "Cuir à plaques"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(6, 3).Value
        Case "Écailles"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(7, 3).Value
        Case "Mailles"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(8, 3).Value
        Case "Plaques"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(9, 3).Value
        Case "Plaques renforcées"
            .Cells(4, 24).Value = Worksheets("Équipements").Cells(10, 3).Value
    End Select
End If
If Target.Address = "$W$4" Then
    If Target.Value = "Légère" Then
        .Cells(4, 25).Value = Worksheets("Équipements").Cells(3, 4).Value
        .Cells(4, 26).Value = Worksheets("Équipements").Cells(3, 6).Value
        .Cells(4, 27).Value = Worksheets("Équipements").Cells(3, 7).Value
    End If
End If
If Target.Address = "$AA$6" Then
    .Cells(7, 27).Value = Worksheets("Équipements").Cells(3, 13).Value
End If
End With
Application.EnableEvents = True
End Sub
 

Pièces jointes

  • Classeur111 (V3).xlsm
    21.3 KB · Affichages: 7
Vote positif 0 Vote négatif
job75

job75

XLDnaute Barbatruc
Avec des Arrays c'est nettement plus simple :
VB: 
Private Sub Worksheet_Change(ByVal Target As Range)
Dim i As Variant
i = Application.Match(Cells(4, 22), Array("Matelassée", "Cuir", "Cuir renforcé", "Cuir à plaques", "Écailles", "Mailles", "Plaques", "Plaques renforcées"), 0)
Application.EnableEvents = False
With Sheets("Équipements")
    If IsNumeric(i) Then Cells(4, 24) = .Cells(i + 3, 3)
    If Cells(4, 23) = "Légère" Then Cells(4, 25).Resize(, 3) = Array(.Cells(3, 4), .Cells(3, 6), .Cells(3, 7))
    If Cells(6, 27) = "Rondache" Then Cells(7, 27) = .Cells(3, 13)
End With
Application.EnableEvents = True
End Sub
 
Vote positif 0 Vote négatif

Discussions similaires

T
  • Résolu(e)
XL 2016 macro et feuille protégé
2
Réponses
18
Affichages
491
laurent950
laurent950
Nicolas JACQUIN
  • Question
XL 2021 Exportation feuille msgbox yes no avec module Thisworkbook
2
Réponses
21
Affichages
880
Nicolas JACQUIN
Nicolas JACQUIN
L
  • Question
VBA : erreur sur boucle
Réponses
2
Affichages
253
Latias
L
yojema
  • Question
XL 2021 faire évoluer un code VBA
Réponses
3
Affichages
380
Dranreb
Dranreb
T
  • Question
XL 2016 Erreur d'exécution 1004 : Impossible de définir la propriété Hidden de la classe Range
Réponses
3
Affichages
251
Phil69970
Phil69970
M
  • Question
XL 2010 Aide à la suppression d'un produit en double dans un magasin spécifique avec conditions
Réponses
9
Affichages
659
Mody200
M
T
  • Question
XL 2016 Optimisation d'une boucle
2 3
Réponses
30
Affichages
2 K
thivame
T
D
  • Question
XL 2021 Filtre Multi Critères Listview VBA
2
Réponses
21
Affichages
1 K
Dranreb
Dranreb
G
  • Question
Microsoft 365 Réduire la taille de la macro ?
Réponses
9
Affichages
781
Staple1600
Staple1600
E
  • Question
Microsoft 365 Listbox avec plus de 10 colonnes
Réponses
6
Affichages
371
Excellearning
E

Membres actuellement en ligne

7 membres et 75 invités.

Partager cette page

Tutos vidéos

Power Query : Ajouter des requêtes (Excel et Power BI)
Créez votre première fonction LAMBDA dans Excel en 3 étapes!
LAMBDA, l’arme secrète de Microsoft pour Excel !
Office Insider - Découvrez les nouveautés Excel avant tout le monde

Statistiques des forums

Discussions
314 628
Messages
2 111 341
Membres
111 107
dernier inscrit
cdel