journée de présence entre 2 dates

[cora]

Bonjour à tous

je souhaiterai connaitre la formule qui me décompterais les journées de présence entre deux date, en fonction de dates précises.
ci joint mon fichier.

Merci encore

 

[Jocelyn]

Re : journée de présence entre 2 dates

Bonjour le Forum,
Bonjour Cora,

A tester en D5 et a étirer vers le bas et la droite

=SI($B5>D$2;0;SOMMEPROD((JOURSEM(LIGNE(INDIRECT(MAX($B5;D$1)&":"&MIN($C5;D$2)));2)<=7)*((MOIS($C5)>=MOIS(D$2))+(($C5="")*(MOIS(D$1)<>1)))))

Voir fichier

Cordialement

EDIT légère modification de la formule

 

[CPk]

Re : journée de présence entre 2 dates

Bonjour à toutes et à tous, Deux fois déjà que tu me grilles aujourd'hui Jocelyn ! Grrr.

Avec une autre formule plutôt dans le genre classique

=SI(ET($B5<D$2;OU($C5>D$2;$C5=""));JOUR(D$2);SI(MOIS($C5)=MOIS(D$2);JOUR($C5);0))

 

[cora]

Re : journée de présence entre 2 dates

Les 2 fonctionnent je vous remercie fortement, j'y étais depuis ce matin..

 

[Dranreb]

Re : journée de présence entre 2 dates

Bonjour.
Moi je dirais :
En E1, à propager sur 11 colonnes :

=DATE(ANNEE(D1);MOIS(D1)+1;1)

En D5, à propager sur 10 lignes et 12 colonnes :

=MAX(SI($C5<>"";MIN($C5;D$2);D$2)-MAX(D$1;$B5)+1;0)

Ou bien, en D5 :

=MAX(SI([@[date
de sortie]]<>"";MIN([@[date
de sortie]];D$2);D$2)-MAX([@[date d''entrée]];D$1)+1;0)

à copier et coller sur D5:O14 (chez moi la propagation vers la droite change les noms de colonnes. Chaque versions d'Excel apporte son lot de bogues)

 

[CPk]

Re : journée de présence entre 2 dates

Mise à jour de la formule et du fichier pour prendre en compte l'entré en service durant le mois en cours, merci Jocelyn.