insertion nom de feuille

[bellic]

Bonjour,

Je rencontre encore un petit problème dans vba...
Voilà j'ai commencé un code de macro afin d'enregistrer une feuille dans un classeur.
Cependant je veux que cette feuille est comme nom (honoraire).
Avec si c'est la première feuille (Honoraire1)
la deuxième (honoraire2)
et ainsi de suite, sachant que le nombre de feuille est indéterminé

Voila le début :
Sub archiver_facture()
'
' archiver_facture Macro
'

'
Columns("A:L").Select
Selection.Copy
Sheets.Add After:=Sheets(Sheets.Count)
Selection.PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
, SkipBlanks:=False, Transpose:=False
Cells.Select
ActiveWindow.DisplayGridlines = False
Range("E16").Select
Sheets("matrice").Select

Range("K1").Value = Range("K1").Value + 1

End Sub

Merci

 

[Pierrot93]

Re : insertion nom de feuille

Bonjour,

tu as déjà un fil d'ouvert à ce sujet :
https://www.excel-downloads.com/threads/vba-et-nouveau-classeur.157060/

auquel tu n'as pas donné suite d'ailleurs....

bon après midi
@+

 

[bellic]

Re : insertion nom de feuille

Bonjour Pierrot93,
Oui je sais mais je n'arrive pas à le remettre dans ce nouveau code

 

[Guest]

Re : insertion nom de feuille

Bonjour,

voici une petite fonction qui devrait te donner le nom de la prochaine feuille "honoraire", s' il n'y pas pas de feuille "honoraire" elle retournera "honoraire1"

utilisation:
Dim NomFeuille as string
NomFeuille= GetNewName()

Function GetNewName() As String
    Dim sh As Worksheet
    Dim idx As Integer, idxMax As Integer
    For Each sh In Worksheets
        If sh.Name Like "honoraire*" Then
            idx = Val(Replace(sh.Name, "honoraire", ""))
            If idx > idxMax Then idxMax = idx
        End If
    Next
    GetNewName = "honoraire" & idxMax + 1
End Function

A+

 

[bellic]

Re : insertion nom de feuille

Bonjour,
Merci pour ta réponse mais comment insérer ce code dans ma macro ci-dessus?

 

[Guest]

Re : insertion nom de feuille

Re,

Si j'avais vu que tu avais un autre fil sur le sujet auquel tu n'as pas donné suite, je n'aurai pas répondu😡

Sub archiver_facture()
    Dim NomFeuille As String
    NomFeuille = GetNewName()
    Columns("A:L").Select
    Selection.Copy
    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Name = NomFeuille
    Selection.PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
                         , SkipBlanks:=False, Transpose:=False
    Cells.Select
    ActiveWindow.DisplayGridlines = False
    Range("E16").Select
    Sheets("matrice").Select
    Range("K1").Value = Range("K1").Value + 1
End Sub
Function GetNewName() As String
    Dim sh As Worksheet
    Dim idx As Integer, idxMax As Integer
    For Each sh In Worksheets
        If sh.Name Like "honoraire*" Then
            idx = Val(Replace(sh.Name, "honoraire", ""))
            If idx > idxMax Then idxMax = idx
        End If
    Next
    GetNewName = "honoraire" & idxMax + 1
End Function

A+

 

[bellic]

Re : insertion nom de feuille

Re,
oui je sais j'ai laissé un poste en stand by, désolé....
Je vais y répondre de suite.
Je viens d'essayer ce que tu m'as envoyé et sa marche...Super!!!
Merci beaucoup de vos aides respectives...
Bonne journée,

Cordialement