Insertion image dans une feuille sans l'intéger au fichier xls

'###########################################
'#   Ajouter impérativement la référence   #
'#   à partir  de Menu Outils/Références   #
'#                                         #
'#   Library MSForms                       #
'#   C:\WINDOWS\system32\FM20.DLL          #
'#   Microsoft Forms 2.0 Object Library    #
'###########################################

Sub CreeUserForm(myPathName As String)
Dim UF As Object
Dim IM As MSForms.Image
Dim A$
Dim i&
On Error GoTo Erreur
'--- Crée dynamiquement un UserForm ---
Set UF = ThisWorkbook.VBProject.VBComponents.Add(3)    ' 3=UserForm
With UF
  .Properties("Caption") = "Image de " & myPathName
  .Properties("Top") = Application.Top + 20
  .Properties("Left") = Application.Left + 20
  .Properties("Height") = Application.Height - 40
  .Properties("Width") = Application.Width - 40
End With
'--- Crée le contrôle Image ---
Set IM = UF.designer.Controls.Add("forms.Image.1")
With IM
  .Picture = LoadPicture(myPathName)
  .Height = Application.Height - 40
  .Width = Application.Width - 40
  .PictureSizeMode = fmPictureSizeModeClip
End With
'--- Code évènementiel ---
A$ = "Private Sub Image1_Click()" & _
    vbCrLf & "Unload Me" & _
    vbCrLf & "End Sub"
With UF.CodeModule
  i& = .CountOfLines
  .InsertLines i& + 1, A$
End With
'--- Affiche le UserForm ---
VBA.UserForms.Add(UF.Name).Show
'--- Détruit le UserForm ---
Erreur:
If Not UF Is Nothing Then ThisWorkbook.VBProject.VBComponents.Remove UF
If Err = 1004 Then MsgBox "Erreur : " & Err.Number & vbCrLf & _
    Err.Description & vbCrLf & vbCrLf & _
    "Dans Excel faites menu Outils/Macro/Sécurité..." & vbCrLf & _
    "Dans l'onglet Editeurs approuvés cochez 'Faire confiance au projet visual Basic'"
End Sub

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
Dim A$
Dim rep$
A$ = UCase(Mid(Target, InStrRev(Target, ".") + 1))
If A$ = "BMP" Or A$ = "JPG" Or A$ = "JPEG" Then
  rep$ = Dir(Target)
  If rep$ <> vbNullString Then
    Call CreeUserForm(Target.Value)
    Cancel = True
  End If
End If
End Sub