Index - Equiv

[Victor]

Bonjour le forum,

Il est encore t^t pour certain, mais cela fait un moment que je bute sur un problème et je n'arrive pas à trouver la solution, j'ai fait une recherche avec index et equiv , qui à mon sens est le plus juste, mais comme je suis pas encore un XLent XLien je vous pose encore la question.

Merci à vous tous et bonne journée. A+ Victor

 

[Moa]

Salut Victor !

Impossible d'ouvrir ton fichier !

@ +

Moa

 

[Victor]

Re,

voici le dossier joint pour voir le problème plus facilement,

déjà merci Moa si tu peux résoudre mon petit problème.

A+ Victor

 

[andré]

Salut Victor,

En E5 la formule : =RECHERCHEV(JOUR(C5);Points!$A$1:$M$32;MOIS(C5)+1;0)
A copier vers le bas.

Bon dimanche.
Ândré.

 

[Victor]

Salut André,

Encore merci, mais si j'ai bien compris, avec index cela n'est pas possible ?

ou alors c'est plus simple avec recherchev ?

A+ Victor

 

[Monique]

Bonjour,

De Index Equiv à Index tout court,
en passant par Decaler.

Un Index Equiv :
=INDEX(Points!B$2:M$32;EQUIV(JOUR(C5);Points!A$2:A$32;0);EQUIV(TEXTE(C5;"mmmm");Points!B$1:M$1;0))

Les mois de la feuille "Points" sont dans l'ordre chrono,
pour avoir la colonne de janvier, on décale la colonne A de 1 colonne,
pour avoir février, on décale de 2, etc :
=INDEX(DECALER(Points!A$2:A$32;0;MOIS(C5));EQUIV(JOUR(C5);Points!A$2:A$32;0))

Les jours de la feuille "Points" sont dans l'ordre chrono,
pas besoin d'Equiv (Equiv = le n° du jour)
=INDEX(DECALER(Points!A$2:A$32;0;MOIS(C5));JOUR(C5);1)

Le 0 est inutile (0 ligne de décalage)
Le 1 est inutile (il n'y a qu'une colonne)
=INDEX(DECALER(Points!A$2:A$32;;MOIS(C5));JOUR(C5))

Si on nomme "Jr" la colonne A2:A32 de la feuille "Points" :
=INDEX(DECALER(Jr;;MOIS(C5));JOUR(C5))

 

[Victor]

Re André,

Il me faut ajouter à ta formule, 2 choses,

1 s'il y a rien : ne rien mettre,
2 s'il y a du texte: ne rien mettre

j'ai essayé avec un =SI(OU(C5="";SI(ESTTEXTE(C5);"";RECHERCHEV(JOUR(C5);Points!$A$1:$M$32;MOIS(C5)+1;0)))

Mais cela ne va pas ??????

 

[Monique]

Re,

Pas besoin d'Index non plus :
=DECALER(Points!$A$1;JOUR(C5);MOIS(C5))
=DECALER(Réf;nb de lignes;nb de colonnes)

 

[Victor]

Salut Monique,

MERCI MERCI

Mais met moi pas trop de formule, sinon je vais nager.........

Il me faut juste encore savoir comment mettre devant ta dernière formule le =SI(OU(C5="";(ESTTEXTE(C5);"";DECALER(Points!$A$1;JOUR(C5);MOIS(C5)))

De ce genre à mon avis mais cela ne fonctionne pas, comme j'ai déjà dit à André.

Parenthèse peut-être.

Merci Victor

 

[Monique]

Re,

Parenthèse, oui.
Encore 2, au choix :
=SI(OU(C5="";ESTTEXTE(C5));"";DECALER(Points!A$1;JOUR(C5);MOIS(C5)))
Plus court :
=SI(NON(ESTNUM(C5));"";DECALER(Points!A$1;JOUR(C5);MOIS(C5)))

 

[Victor]

Re Monique,

SI je peux me permettre, je te fait milles bisous (o)

Fonctionne très très bien voir XLent et surtout plus court que ce que je vais chercher, mais il y a un début à tout.

Encore un grand merci Monique et bonne journée.

Victor

 

[andré]

Merci Monique, je n'ai plus rien à faire, le tout étant résolu !

Puisque j'ai pris mon premier apéro à la santé de Celeda (autre post), le second sera à la tienne !

Bon dimanche.
Ândré.