imprimer que les lignes remplies

[nrdz83]

Re bonsoir le forum,

J'utilise le code ci-dessous pour imprimer mais je cherche à remplacer la partie en rouge afin de n'imprimer que les lignes saisies.

Sub print_Inventaire()
    Range("B2:K99").Select
    [COLOR="Red"]ActiveSheet.PageSetup.PrintArea = "$B$2:$K$99"[/COLOR]
    With ActiveSheet.PageSetup
        .PrintTitleRows = "$2:$2"
        .PrintTitleColumns = ""
    End With
    ActiveSheet.PageSetup.PrintArea = "$B$2:$K$99"
    With ActiveSheet.PageSetup
        .LeftHeader = ""
        .CenterHeader = ""
        .RightHeader = ""
        .LeftFooter = ""
        .CenterFooter = ""
        .RightFooter = "&""Times New Roman,Italique""&9Imprimé le&D"
        .LeftMargin = Application.InchesToPoints(0.393700787401575)
        .RightMargin = Application.InchesToPoints(0.393700787401575)
        .TopMargin = Application.InchesToPoints(0.196850393700787)
        .BottomMargin = Application.InchesToPoints(0.590551181102362)
        .HeaderMargin = Application.InchesToPoints(0)
        .FooterMargin = Application.InchesToPoints(0.511811023622047)
        .PrintHeadings = False
        .PrintGridlines = False
        .PrintComments = xlPrintNoComments
        .CenterHorizontally = True
        .CenterVertically = False
        .Orientation = xlLandscape
        .Draft = False
        .PaperSize = xlPaperA4
        .FirstPageNumber = xlAutomatic
        .Order = xlDownThenOver
        .BlackAndWhite = False
        .Zoom = 100
        '.PrintErrors = xlPrintErrorsDisplayed
    End With
    ActiveWindow.SelectedSheets.PrintPreview
    ActiveWindow.SelectedSheets.PrintOut Copies:=1
    Range("B3").Select
End Sub

D'avance merci à tous ,
Mes amitiés 🙄

 

[Cousinhub]

Re : imprimer que les lignes remplies

Bonsoir,

et non, pas encore à la SSF de Nouméa (début Août.....)

essaie ainsi :

Sub print_Inventaire()
Dim DerLig As Long
DerLig = [A65000].End(xlUp).Row
With ActiveSheet.PageSetup
    .PrintArea = "$B$2:$K$" & DerLig
    .PrintTitleRows = "$2:$2"
    .RightFooter = "&""Times New Roman,Italique""&9Imprimé le&D"
    .CenterHorizontally = True
    .Orientation = xlLandscape
End With
With ActiveWindow
    .SelectedSheets.PrintPreview
    .SelectedSheets.PrintOut Copies:=1
End With
End Sub

 

[nrdz83]

Re : imprimer que les lignes remplies

re bonsoir bhbh,
tu dois commencer à trouver le temps long non ?

Je viens d'essayer ton code mais il me prend que ma ligne de titre.

Merci pour ton aide , amitiés

 

[Cousinhub]

Re : imprimer que les lignes remplies

Re-,

quelle colonne est sûre d'être remplie?

Dans mon code, je supposais que la colonne A était remplie....

Tu peux adapter, sinon, on peut trouver un autre code, pour déterminer la dernière ligne utilisée...

Au plaisir

 

[ledzepfred]

Re : imprimer que les lignes remplies

Bonsoir Mr Bean, re Bh2,


tu ne dois pas avoir de données en colonne A,

dans le code de Bh2 remplace cette ligne

DerLig = [A65000].End(xlUp).Row

par

DerLig = [B65000].End(xlUp).Row

A+

 

[Cousinhub]

Re : imprimer que les lignes remplies

Re-,

un exemple :

Sub print_Inventaire()
Dim DerLig As Long
DerLig = ActiveSheet.Cells.Find("*", , , , xlByRows, xlPrevious).Row
With ActiveSheet.PageSetup
    .PrintArea = "$B$2:$K$" & DerLig
    .PrintTitleRows = "$2:$2"
    .RightFooter = "&""Times New Roman,Italique""&9Imprimé le&D"
    .CenterHorizontally = True
    .Orientation = xlLandscape
End With
With ActiveWindow
    .SelectedSheets.PrintPreview
    .SelectedSheets.PrintOut Copies:=1
End With
End Sub

Re, LedZep'....

 

[nrdz83]

Re : imprimer que les lignes remplies

bonsoir ledzepfred et re bhbh ok autant pour moi effectivement ça venais de la colonne.
Ma colonne A etait masquée.

Merci encore pour tout, bonne fin de week end à tous , amitiés