Imprimer les onglets graphiques dans un PDF

[Wana]

Bonjour à vous tous !

Et tout d'abord, merci !! Grâce à ce forum et vos réponses, j'arrive en général à me débrouiller pour faire ce que 'jai besoin... sauf cette fois -ci.
Voilà mon souci :
J'ai un classeur Excel avec beaucoup d'onglets, des onglets tableurs et des onglets graphiques. Je voudrais pouvoir récupérer tous les onglets graphiques et les imprimer dans un PDF.
Voilà le code que j'ai déjà écrit, mais il me parait bien compliqué pour mon besoin.

---------------------------------------------
Option Explicit

Private Const Fichier As String = "C:\Users\...\SQCDP.pdf"


Sub Bouton1_Cliquer()

'Recherche du nom de tous les onglets graphiques du classeur
Dim i As Integer
For i = 1 To Charts.Count
Cells(32 + i, 2) = Charts(i).Name
Next i

'Sélection des onglets graphiques
Sheets(Array(Range("B33").Value, Range("B36").Value)).Select


'Export en un fichier PDF - effaçage du fichier si déjà existant à l'adresse indiquée
If Dir(Fichier) <> "" Then Kill Fichier

'Export en un fichier PDF - création et sauvegarde du PDF
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
Fichier, Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=False


End Sub
---------------------------------------------

Y'a-t-il une façon de faire en sorte que ma fonction Array aille automatiquement chercher les intitulés des Onglets qui sont écrits dans les cellules (grâce aux lignes de code supérieures) ? Parce que si je dois taper les 30 titres d'onglets à la main, je suis pas sortie ! Et dès qu'on va en modifier un, il ne va plus apparaitre dans le pdf.
Ou encore mieux : peut-on inclure la recherche des onglets graphiques dans la fonction Array ?

J'espère avoir bien expliqué mon problème.
Et par avance, je vous remercie, une nouvelle fois, de votre aide !

 

[Yaloo]

Re : Imprimer les onglets graphiques dans un PDF

Bonjour Wana et bienvenu sur XLD,

Avec ceci, tu n'as pas besoin de mettre tes noms de graphique dans les cellules :

Option Explicit
Private Const Fichier As String = "C:\SQCDP.pdf"
Sub Bouton1_Cliquer()
Dim a()
'Recherche du nom de tous les onglets graphiques du classeur
 Dim i As Integer, j&
 For i = 1 To Charts.Count
 ReDim Preserve a(i - 1)
 a(i - 1) = Charts(i).Name
 Next i
'Sélection des onglets graphiques
Sheets(a).Select
 'Export en un fichier PDF - effaçage du fichier si déjà existant à l'adresse indiquée
 If Dir(Fichier) <> "" Then Kill Fichier
'Export en un fichier PDF - création et sauvegarde du PDF
 ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
 Fichier, Quality:= _
 xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
 OpenAfterPublish:=False
End Sub

A te relire

Martial

 

[Wana]

Re : Imprimer les onglets graphiques dans un PDF

Merci beaucoup Martial/Yaloo !!!!!
C'est exactement ce dont j'avais besoin, ça fait exactement la job que je voulais !

Encore merci, et à une prochaine