XL 2016 Impression plage sur deux feuilles

[KTM]

Bonsoir chers tous

Je voudrais imprimer ma plage de données A1: P42 a l'aide d''une macro :

- A1😛30 sur une feuille

-et A31😛42 sur la deuxième feuille

Merci

 

[kiki29]

Salut, pour cela tu as Excel et l'enregistreur de macro à lire et pratiquer.
Il en existe une version PDF téléchargeable une fois un compte créé.

 

[job75]

Bonjour KTM, kiki29, le forum,

Sub Imprimer()
With ActiveSheet
    With .PageSetup
        .Orientation = xlLandscape
        .Zoom = False
        .FitToPagesWide = 1
        .PrintArea = "A1:P42"
    End With
    .ResetAllPageBreaks
    .HPageBreaks.Add .Rows(31) 'saut de page
    .PrintOut
End With
End Sub

Bon dimanche.

 

[kiki29]

Salut, une autre vision

Option Explicit

Sub Impression_02()
Dim sNomPDF As String
    Application.ScreenUpdating = False

    Feuil1.PageSetup.PrintArea = "$A$1:$P$30"
    Application.Goto Reference:="Print_Area"

    sNomPDF = ThisWorkbook.Path & "\" & "Zone_01.pdf"
    Selection.ExportAsFixedFormat Type:=xlTypePDF, _
                                  Filename:=sNomPDF, _
                                  Quality:=xlQualityStandard, _
                                  IncludeDocProperties:=True, _
                                  IgnorePrintAreas:=False, _
                                  OpenAfterPublish:=False

    Feuil1.PageSetup.PrintArea = "$A$31:$P$42"
    Application.Goto Reference:="Print_Area"

    sNomPDF = ThisWorkbook.Path & "\" & "Zone_02.pdf"
    Selection.ExportAsFixedFormat Type:=xlTypePDF, _
                                  Filename:=sNomPDF, _
                                  Quality:=xlQualityStandard, _
                                  IncludeDocProperties:=True, _
                                  IgnorePrintAreas:=False, _
                                  OpenAfterPublish:=False

    Feuil1.Range("A1").Select
    Application.ScreenUpdating = True
End Sub

 

[job75]

Je sais bien que KTM s'exprime peu mais je crois que s'il voulait des fichiers PDF il l'aurait dit.

 

[KTM]

Merci à Job75 et kiki29
Les deux solutions me vont très bien.
1- Celle de Job75 pour imprimer
2-Celle de kiki29 pour enregistrer au format pdf

Merci pour les deux pistes. Bon Dimanche à vous à tous ceux qui vous sont chers !!!