impression d'une cellule fusionnée sur 2 pages d'un document

[odeonseb]

Bonjour,

Dans Excel 2007, je souhaite faire apparaître sur 2 pages une cellule fusionnée (cette cellule est scindée en 2 entre la page 1 et la page 2). Lors de l'impression, le texte de cette cellule n'apparaît pas sur la page 2.

Existe-t-il une fonction pour qu'elle apparaisse automatiquement?

Merci de votre aide.

Bonne journée.

 

[job75]

Re : impression d'une cellule fusionnée sur 2 pages d'un document

Bonjour odeonseb, bienvenue sur XLD,

Voyez le fichier joint et cette macro (Alt+F11) :

Sub Imprimer()
With ActiveSheet
  .PageSetup.PrintTitleRows = ""
  .PrintOut From:=1, To:=1
  .PageSetup.PrintTitleRows = "$10:$14"
  .PrintOut From:=2, To:=2
End With
End Sub

L'astuce consiste à imprimer chaque page avec ou sans lignes à répéter en haut (10:14).

Noter qu'il y a un saut de page au dessus de la ligne 15.

A+

 

[job75]

Re : impression d'une cellule fusionnée sur 2 pages d'un document

Re,

Si l'on veut avoir le choix d'imprimer ou non, utiliser l'Aperçu avant impression :

Sub Imprimer()
With ActiveSheet
  .PageSetup.PrintTitleRows = ""
  .PrintOut From:=1, To:=1, Preview:=True
  .PageSetup.PrintTitleRows = "$10:$14"
  .PrintOut From:=2, To:=2, Preview:=True
End With
End Sub

Fichier (2).

A+

 

[job75]

Re : impression d'une cellule fusionnée sur 2 pages d'un document

Re,

Une autre solution consistant, pour chaque page, à placer le saut de page au bon endroit :

Sub Imprimer()
With ActiveSheet
  .PageSetup.PrintTitleRows = "$1:$1" 'titre
  .ResetAllPageBreaks
  .Rows(15).PageBreak = xlPageBreakManual
  .PrintOut From:=1, To:=1, Preview:=True
  .ResetAllPageBreaks
  .Rows(10).PageBreak = xlPageBreakManual
  .PrintOut From:=2, To:=2, Preview:=True
End With
End Sub

Fichier (3).

A+

 

[job75]

Re : impression d'une cellule fusionnée sur 2 pages d'un document

Re,

En général le problème qui se pose est de ne pas couper les cellules fusionnées à l'impression.

Voyez le fichier joint avec cette macro :

Sub Imprimer()
Dim Nlig&, i&
Nlig = Val(InputBox("Entrez le nombre maximum de lignes d'une page :", "Imprimer"))
If Nlig < 1 Then Exit Sub
If Nlig < 6 Then MsgBox "Nombre trop petit...": Exit Sub
With ActiveSheet
  .ResetAllPageBreaks 'RAZ
  i = 1
  While Application.CountA(Cells(i, "B").Resize(.Rows.Count - i + 1))
    i = i + Nlig
    i = .Cells(i, "B").MergeArea.Row
    .HPageBreaks.Add .Rows(i)
  Wend
  .PrintOut Preview:=True 'aperçu avant impression
End With
End Sub

Chez moi elle donne de bons résultats avec des nombres de lignes par page compris entre 6 et 49.

A+

 

[odeonseb]

Re : impression d'une cellule fusionnée sur 2 pages d'un document

Merci des réponses et des fichiers, c'est beaucoup plus clair!

Bonne journée

Seb