Impression des 10 dernières lignes d'une zone variable

[libellule85]

Bonsoir le forum,

Actuellement j'utilise la macro suivante pour imprimer ma zone variable :

Private Sub Label1_Click()
Dim DerLig As Integer
Application.ScreenUpdating = False
DerLig = Range("a65536").End(xlUp).Row
ActiveSheet.PageSetup.PrintArea = "$a$1:$G$" & DerLig
ActiveWindow.SelectedSheets.PrintPreview
Application.ScreenUpdating = True
End Sub

J'aimerais, si cela est possible n'imprimer par exemple que les dix dernières lignes de ma zone variable.
Quelqu'un a-t'il une idée ?
D'avance je vous en remercie

 

[Staple1600]

Re : Impression des 10 dernières lignes d'une zone variable

Bonsoir à tous

libellule85
Essaie la macro ci-dessous

Private Sub Label1_Click()Dim DerLig As Long, Plg As Range
Application.ScreenUpdating = False
DerLig = Cells(Rows.Count, 1).End(xlUp).Row
Set Plg = Range("A" & DerLig - 10).Resize(11, 7)
ActiveSheet.PageSetup.PrintArea = Plg.Address
ActiveWindow.SelectedSheets.PrintPreview
Application.ScreenUpdating = True
End Sub

 

[libellule85]

Re : Impression des 10 dernières lignes d'une zone variable

Bonjour Staple1600,

Merci beaucoup pour ta réponse, cela fonctionne impeccablement.
Bonne journée

 

[job75]

Re : Impression des 10 dernières lignes d'une zone variable

Bonjour,

Il s'agit des 10 dernières lignes et pas 11 non ?

Set Plg = Range("A" & DerLig - 9).Resize(10, 7)

A+

 

[libellule85]

Re : Impression des 10 dernières lignes d'une zone variable

Bonjour Job75,

Merci pour la rectification

Bonne journée

 

[libellule85]

Re : Impression des 10 dernières lignes d'une zone variable

Bonjour le forum,

Je reprends mon fil car la question suivante est dans la continuité de celui-ci :

Comment faire pour choisir le nombre de x dernières lignes à imprimer ?

D'avance merci pour vos réponses.

 

[JCGL]

Re : Impression des 10 dernières lignes d'une zone variable

Bonjour à tous,

Peux-tu essayer avec :

Option Explicit


Sub Imprime_X_Lignes()
Dim DerLig&, Plage As Range, X&
DerLig = Cells(Rows.Count, 1).End(xlUp).Row
X = InputBox("Choisir la valeur", " X Dernières Lignes", 10)
Set Plage = Range("A" & DerLig - (X - 1)).Resize(X, 5)
ActiveSheet.PageSetup.PrintArea = Plage.Address
ActiveWindow.SelectedSheets.PrintPreview
End Sub

A+ à tous

 

[libellule85]

Re : Impression des 10 dernières lignes d'une zone variable

Bonjour LCGL,

Je te remercie pour ta réponse, c'est exactement ce que je recherchais.
Bonne journée

 

[JCGL]

Re : Impression des 10 dernières lignes d'une zone variable

Bonjour à tous,

Avec gestion des erreurs :

Option Explicit


Sub Imprime_X_Lignes()
Dim DerL&, Plage As Range, X&
DerL = Cells(Rows.Count, 1).End(xlUp).Row
X = InputBox("Choisir la valeur", " X Dernières Lignes", 10)
If X > DerL Then
MsgBox "Le nombre de lignes demandé est supérieur au nombre de lignes", vbCritical, "Oups !!!"
Exit Sub
End If
Set Plage = Range("A" & DerL - (X - 1)).Resize(X, 5)
ActiveSheet.PageSetup.PrintArea = Plage.Address
ActiveWindow.SelectedSheets.PrintPreview
End Sub

A+ à tous

 

[libellule85]

Re : Impression des 10 dernières lignes d'une zone variable

Re JCGL,

Je te remercie à nouveau pour ce complément