Power Query importer fichier CSV, dont le chemin est dans une cellule Excel

 Chemin =Excel.CurrentWorkbook(){[Name="CheminCSV"]}[Content]{0}[Column1],
    Fichier=Excel.CurrentWorkbook(){[Name="FichierCSV"]}[Content]{0}[Column1],
    Source = Csv.Document(File.Contents(Chemin&Fichier),[Delimiter=";", Columns=15, Encoding=1252, QuoteStyle=QuoteStyle.None]),

source=Csv.Document(File.Contents(Table.FirstValue(Excel.CurrentWorkbook(){[Name="Table1"]}[Content])),[Delimiter=",", Columns=15, Encoding=1252]))

let fnFileExists = (
                    pFilePathFullName as any
        ) as logical =>
        let
            FilePathNameString = pFilePathFullName,

            //=========================================================================================
            // Longueur totale du nom de fichier avec son chemin
            //=========================================================================================
            Length = Text.Length(FilePathNameString),

            //=========================================================================================
            // On calcule la position du dernier slash pour identifer le fichier
            //=========================================================================================
            PositionLastSlash = Text.PositionOf(FilePathNameString,"\",Occurrence.Last),

            //=========================================================================================
            // Chemin du fichier
            //=========================================================================================
            FolderPathName = Text.Start(FilePathNameString,PositionLastSlash + 1),

            //=========================================================================================
            // Nom du fichier
            //=========================================================================================
            FileName = Text.End(FilePathNameString,Length - PositionLastSlash - 1),

            //=========================================================================================
            // Vérification de l'existance du fichier
            //=========================================================================================
            RecordAttributes = try Folder.Contents(FolderPathName){[Name=FileName]}[Attributes] otherwise false,
            FileExists=if RecordAttributes is record then true else false,
            isExists = if FileExists then true else false
        in
            isExists
in
    fnFileExists

let fnGetParameters =
    (pTable as text, pName as any) =>
    let
        ParamSource = Excel.CurrentWorkbook(){[Name=pTable]}[Content],
        ParamRow = Table.SelectRows(ParamSource, each ([PARAMETRE] = pName)),
        Value=
        if Table.IsEmpty(ParamRow)=true
            then null
        else Record.Field(ParamRow{0},"VALEUR")
    in
        Value
in
    fnGetParameters

let fnGetRangeValue = (
            pRangeName as text,
            optional pRow as number,
            optional pColumn as number
        ) =>
     
        let
            //***********************************************************************************************************
            // Gestion des paramètres
            //***********************************************************************************************************
            RangeName=pRangeName,
            Row=if pRow is null or pRow = 0 then 0 else pRow - 1,
            Column=if pColumn is null or pColumn = 0 then 1 else pColumn,
            WbExcel=Excel.CurrentWorkbook(),

            //***********************************************************************************************************
            // Construction de la liste des objets connus dans Excel
            //***********************************************************************************************************
            TbList=WbExcel[Name],
            bFound=List.Contains(TbList,RangeName),

            //***********************************************************************************************************
            // La recherche est uniquement effectuée si le champ est trouvé dans la liste des objets connus dans Excel
            //***********************************************************************************************************
            Value=if bFound
                      then
                            let
                              //--------------------------------------------------------
                              // Traitements de recherches si le nom de champ est connu
                              //--------------------------------------------------------
                              StrRange="WbExcel{[Name=RangeName]}[Content]{Row}[Column" & Text.From(Column) & "]",
                              RecEval=[WbExcel=WbExcel, Row=Row, Column=Column, RangeName=RangeName],
                              Eval=Expression.Evaluate(StrRange,RecEval)
                            in
                              Eval
                      else
                            "#N/A"
 
        in
            Value
in
    fnGetRangeValue