importer d'une feuille le texte des labels

[copayo]

Bonjour à tous,

J'ai crée un USF avec un controle mutlipage

Dans chaque page j'ai plusieurs labels

Je souhaite lié le texte de chaque label à une cellule excel (Excel => label)

J'ai nommé chaque label avec un nom qui correspond à la cellule excel.

J'aimerais faire une boucle plutot que de les lier 1 par 1.

Ca donnerait ca en substance mais je ne sais pas l'écrire correctement :

for each caption
caption.label = worksheets("Text").range("caption.name")
next


Merci pour vos contributions

 

[Bebere]

Re : importer d'une feuille le texte des labels

bonjour Copayo

Dim cel as Range,I as byte

for each cel in worksheets("Text").range("A1:F1")
i=i+1
controls("label" & I).Caption = Cel.address'ou Cel.value
next cel

à bientôt

 

[Pierrot93]

Re : importer d'une feuille le texte des labels

Bonsoir Copayo, Bebere

pas assez rapide mais c'est fait, alors je donne quand même, cela fera une 2ème solution, enfin si j'ai bien compris...

Private Sub UserForm_Initialize()
Dim Ctrl As Control, i As Byte
i = 1
For Each Ctrl In Me.Controls
If TypeOf Ctrl Is MSForms.Label Then Ctrl.Caption = Range("A" & i).Value: i = i + 1
Next Ctrl
End Sub

bonne soirée
@+

 

[Kotov]

Re : importer d'une feuille le texte des labels

Bonjour à tous,

Bien que battu au sprint (ca m'apprendra à répondre au téléphone !), je joins une autre possibilité qui se rapproche de la proposition de Pierrot93 (que je salue bien par ailleurs)

Hypothèse de départ :
-Un userform nommé "USF"
-4 labels (de label1 à label4)
-Les entêtes de label à importer des cellules A5 à A8 dans la feuille "A"
-un bouton sur la feuille "A" pour afficher le userform USF

d'où la macro suivante placée dans le module du USF :

Private Sub UserForm_Initialize()
LabelImport
End Sub


et la macro suivante placée dans le Module1
Private Sub LabelImport()
Dim i As Byte
Dim Sh As Worksheet
Set Sh = ActiveWorkbook.Sheets("A")
Sh.Activate

For i = 1 To 4
    USF.Controls("Label" & i).Caption = Sh.Cells(i + 4, 1)
Next

Set Sh = Nothing

End Sub

Testes le fichier XL en pièce jointe.

A+
Kotov

 

[Pierrot93]

Re : importer d'une feuille le texte des labels

Bonsoir Kotov, il y avait longtemps, cela fait plaisir de te croiser sur un fil.
amicalement.
@+

 

[Kotov]

Re : importer d'une feuille le texte des labels

Re Pierrot,
En fait, depuis un mois je suis sur un gros projet perso en VBA.
Alors je passe en coup de vent sur le forum et j'évite de me disperser.
Mais ca fait plaisir de te rencontrer.
A +
Kotov

 

[copayo]

Re : importer d'une feuille le texte des labels

MErci a tous c'est exactement ce que je cherchais.

En fait j'étais parti sur des nom de label sans chiffre.

A t'on besoin obligatoirement d'avoir un nom du type label2 ?

merci encore

 

[Pierrot93]

Re : importer d'une feuille le texte des labels

Re à tous

dans mon code je n'utilise pas la propriété "name" du label donc peu importe le nom, par contre Kotov et Bebere l'utilisent.

bonne soirée
@+

 

[Kotov]

Re : importer d'une feuille le texte des labels

Bonsoir Copayo,

Non, ton label n'a pas forcément besoin d'être nommé "Label" :
Tous les noms sont acceptables (à l'exception des noms réservés en VBA), en revanche, si tu veux procéder avec une boucle, tu dois naturellement lui attribuer un indice numérique.
Sinon, tu ne fais pas de boucle, et tu fais une ligne par Label

Syntaxe pour une boucle :
USF.Controls("NomDeTonChoix" & i).Caption = Sh.Cells(i + 4, 1)

A noter : le principe USF.Controls fonctionne évidemment avec les autres contrôles.


Bonne soirée
Kotov

 

[Pierrot93]

Re : importer d'une feuille le texte des labels

Bonjour Copayo, Kotov, bebere

@Kotov
Petite précision, tu as également la possibilité de faire une boucle sur tous les controles, en faisant un test sur le type de controle, comme effectué dans le code que j'ai communiqué. Dans ce cas tu n'est plus obligé de faire référence à un nom. Dans ce cas, Il faut bien sur que le code s'applique à tous les controles d'un même type.

bonne journée à tous
@+

 

[Bebere]

Re : importer d'une feuille le texte des labels

bonjour Pierrot,Kotov,Copayo
il y a aussi TypeName

Dim Ctrl As Control

For Each Ctrl In Me.Controls
If TypeName(Ctrl) = "TextBox" Then
'ce que tu veux faire,içi
End If
Next Ctrl

à bientôt

 

[ChTi160]

Re : importer d'une feuille le texte des labels

Salut copayo
Bonjour le fil
Bonjour le Forum

il y a aussi une propriété qui n'est pas souvent utilisée et qui peut servir à plein de choses, c'est la propriété Tag

là les Contrôles s'appellent comme on veut

on met dans la propiétée tag des contrôles concernés les Numeros
exemple on a 20 Labels seuls 10 sont concernés on met dans la propriété Tag du premier Concerné 1,ensuite 2... etc etc jusqu'a 10
puis ensuite on peut boucler (non testé)

Sub Test()
Dim Ctrl as Control
Dim L as Byte
With Worksheets("Feuil1")
For L=1 to 10
   For Each Ctrl in Userform1.Controls
       If Ctrl.Tag = L then
          Ctrl.Caption=.Cells(L,1) 'ou l'inverse .Cells(L,1)=Ctrl.Caption
             Exit For
       End If
  next
Next
End with
End Sub

cette intervention m'a permis de Saluer pas mal de personnes que j'apprécie
PS je joins un fichier LoL

Le Fichier :

Regarde la pièce jointe Tag.xls

Bonne journée

 

[copayo]

Re : importer d'une feuille le texte des labels

salut,

pierrot, comment te dire

c'est GENIAL !!

merci à tous les contributeurs, j'espère pouvoir vous renvoyer l'ascenceur.

à bientôt

 

[Pierrot93]

Re : importer d'une feuille le texte des labels

Re a tous, salut Jean Marie

Merci Bebere pour l'utilisation de la fonction "TypeName", cela simplifie efficacement le code...

bon après midi à tous
@+

 

[Pierrot93]

Re : importer d'une feuille le texte des labels

Re

Jean Marie, ta solution est également bonne, peu être un peu plus longue à mettre en place (renseigné la propriété tag), mais elle a un plus, elle permet de filtrer certains controles d'un même type sans être obligé de tester le nom... bonne fin de journée...

@+