importer données excel

[Tonio]

Bonjour à tous, je souhaiterais importer des données d'un fichier excel sur un serveur, j'ai trouver des macros pour m'aider mais cela ne fonctionne pas, le getvalue n'est pas reconnu ,quelqu'un peut-il m'aider?
voici cette macro:

Sub TestGetValue()
'Récupérer dans la feuille active 1000 lignes et 4 colonnes d'un fichier fermé
Dim P As String, f As String, S As String
Dim A As String
Dim C As Long, R As Long, I As Long
P = "\\hf14-001\APPLI_immeubles"
f = "immeubles.xls"
S = "ImmeublesCaisses"
'Vérifie l'existence du fichier, ajoute les séparateurs manquants
If (Right(P, 1) <> "\") Then P = P & "\"
If (Dir(P & f) <> "") Then
Range("A1").CurrentRegion.ClearContents
I = 0
Application.ScreenUpdating = False
For R = 1 To 1000
For C = 1 To 4
I = I + 1
Cells(R, C) = GetValue(P, f, S, Cells(R, C).Address)
Next C
Next R
Application.ScreenUpdating = True
End If
End Sub


Merci à tous ceux qui peuvent m'aider !!!!

 

[michel]

bonjour Tonio

je viens de tester avec Excel2002 , WinXP : pour moi la procedure de J.Walkenbach fonctionne tres bien

as tu bien inséré la fonction GetValue dans le module ?

Private Function GetValue(Path, File, Sheet, Ref)
'Récupération d'une valeur dans un fichier fermé
Dim Arg As String
'Crée l'argument de la fonction XL4
Arg = "'" & Path & "[" & File & "]" & Sheet & "'!" & Range(Ref) _
.Range("A1").Address(, , xlR1C1) '
'Exécute la macro XLM
End Function


bonne soiree
michel

 

[myDearFriend]

Bonsoir Tonio, Michel,

Michel, si je peux me permettre... il manque la ligne :

GetValue= ExecuteExcel4Macro(arg)

dans la Function.


Private Function GetValue(Path, File, Sheet, Ref)
'Récupération d'une valeur dans un fichier fermé
Dim Arg As String
'Crée l'argument de la fonction XL4
Arg = "'" & Path & "[" & File & "]" & Sheet & "'!" & Range(Ref) _
.Range("A1").Address(, , xlR1C1) '
'Exécute la macro XLM
GetValue= ExecuteExcel4Macro(arg) '<<<< ligne à rajouter ICI
End Function


Cordialement.
Didier_mDF

 

[michel]

bonjour MyDearFriend

merci d'avoir rectifié mon message
effectivement je me suis planté dans le copier/coller


bon week end
michel

 

[Tonio]

Merci Michel et MyDearFriend !!!

c'est ca je n'avais pas inserer la fonction GetValue, Je suis un débutant en vb, et maintenant il y a encore un petit problème, les données qu'excel importe sont #REF!, pourriez vous m'aider encore un petit peu?

Merci beaucoup

 

[Tonio]

En fait c'était mon chemin d'accès qui était mauvais!!

Merci encore michel et MyDearFriend !!!!
Bon Week end à tous