Import Word --> Excel

[2rdev]

Bonjour,


(Pour lire le fichier le remettre en .doc)

Voila j'ai un fichier excel pour l'instant vierge dans lequel je dois rentrer des infos d'un document Word.

Simple pour le moment.
Première difficulté par VBA, sa va encore me direz vous.

Mais voila je suis débutant et ce fichier word est infâme. Je vous en fournis une légère partie

Maintenant voila j'ai un fichier Excel avec un entête en A

VersionSysteme | Composant | VersionComposant | Fichier | Version Fichier

En dessous je veux renseigner donc des infos extraits des tableaux de mon fichier word.


Présenter par exemple comme ceci:


I.1 VMS Display

Fields | Vdsp1.2 |vdsp1.3p2

Fichier 1 1.0.0.0 | 1.0.0.0

Fichier 2 1.2.3.4 | 1.3.3.5


Donc voila le composant c'est le vms display, les versions sytemes et composant les vdsp 1.2 ou 1.3p2
les versions Fichiers sont les 1.0.0.0 et les autres et dans fichier Fichier 1 ou Fichier 2 par exemple

et donc il faudrait que j'extraie ces données dans un fichier excel sachant que nous pouvons avoir plusieurs tableau sur le doc word.


Je vous remercie pour votre aide

Cordialement 2rdev

 

[Misange]

Re : Import Word --> Excel

Bonjour,
un joli code (testé !) que j'ai trouvé ici
Macro to export MS Word tables to Excel sheets - Stack Overflow

Option Explicit

Sub ImportWordTable()

Dim wdDoc As Object
Dim wdFileName As Variant
Dim tableNo As Integer 'table number in Word
Dim iRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel
Dim resultRow As Long
Dim tableStart As Integer
Dim tableTot As Integer



wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", , _
"Browse for file containing table to be imported")

If wdFileName = False Then Exit Sub '(user cancelled import file browser)

Set wdDoc = GetObject(wdFileName) 'open Word file

With wdDoc
    tableNo = wdDoc.Tables.Count
    tableTot = wdDoc.Tables.Count
    If tableNo = 0 Then
        MsgBox "This document contains no tables", _
        vbExclamation, "Import Word Table"
    ElseIf tableNo > 1 Then
        tableNo = InputBox("This Word document contains " & tableNo & " tables." & vbCrLf & _
        "Enter the table to start from", "Import Word Table", "1")
    End If

    resultRow = 4

    For tableStart = 1 To tableTot
        With .Tables(tableStart)
            'copy cell contents from Word table cells to Excel cells
            For iRow = 1 To .Rows.Count
                For iCol = 1 To .Columns.Count
                    Cells(resultRow, iCol) = WorksheetFunction.Clean(.Cell(iRow, iCol).Range.Text)
                Next iCol
                resultRow = resultRow + 1
            Next iRow
        End With
        resultRow = resultRow + 1
    Next tableStart
End With

End Sub