Imbriquer "SI" "rechercheV" plusieurs fois

[bbloup47]

Bonjour à tous, je suis à monter un classeur servant à calculer les coûts. j'ai créé 3 bases de données sur la même feuille, correspondant à 3 fournisseurs. j'ai fait 2 champs déroulants, M4=liste fournisseurs, N4=liste produits correspondants. Jusque la ça va. En O4 et P4 j'essaye d'avoir respectivement le prix/unité et prix/once de l'item affiché en P4. il n'y a que le premier de la formule qui fonctionne! je n'arrive pas à faire fonctionner les autres...
je join un classeur exemple, si quelqu'un avais l'amabilité de me diriger j'en serais très heureux.
J'utilise Excel 2007 et windows 7

Merci de votre support

 

[Denis132]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Bonsoir BBloup,

Voir si ça te conviens.

@+

Denis

 

[Mytå]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Salut le forum

Ton tableau n'étant pas trier ajout le zéro dans la recherche

En O3

=SI($M$4=$A$23;RECHERCHEV($N$4;$A$3:$C$21;2;0);SI($M$4=$A$24;RECHERCHEV($N$4;$E$3:$G$21;2;0);SI($M$4=$A$24;RECHERCHEV($N$4;$I$3:$I$21;2;0);"")))

Mytå

 

[bbloup47]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Merci infiniment les amis ça fonctionne à merveille!!!

bonne soirée

@+🙂

 

[hoerwind]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Bonjour, salut Myta,

Une variante en O4 :

=RECHERCHEV($N4;DECALER($A$1;;EQUIV($M4;$A$1:$K$1;0)-1;20;3);COLONNE()-13;0)

cette formule peut être copiée vers la droite et vers le bas.

 

[bbloup47]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Merci beaucoup hoerwind, cette formule fonctionne également à merveille... je suis maintenant à essayer de la comprendre pour bine l'assimiler.

merci encore à tous et @+

 

[hoerwind]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Bonjour,

S'il tu désires un mot d'explication, n'hésites pas.
Il est tellement rare de rencontrer quelqu'un qui essaie de comprendre que je me ferai un plaisir de te mettre sur la voie.

 

[bbloup47]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Merci beaucoup hoerwind, j'en prend bonne note...la je suis entrain de faire des exercices avec DECALER et ça commence à rentrer dans mon petit coco la...🙂

bonne soirée et @+

=RECHERCHEV($N4;DECALER($A$1;;EQUIV($M4;$A$1:$K$1;0)-1;20;3);COLONNE()-13;0)

il y a 2 paramètres que je ne saisis pas : $A$1;; pourquoi les deux points virgules? et le -1 suivant les paramètres EQUIV. je sais que le -1 fait partie de DECALER, alors si je débute en A1 comment décaler une colonne vers la gauche?

Si tu as une minute pour expliquer... merci beaucoup

 

[hoerwind]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Bonjour,

Les arguments de la fonction :
DECALER(réf;lignes;colonnes;hauteur;largeur)


réf : on décale à partir de la cellule A1
lignes : on décale d'aucune ligne, cela peut s'écrire : ;0; ou ;;, le 0 n'étant pas obligatoire
colonnes : la fonction EQUIV renvoie le numéro de la colonne de la plage mentionnée ($A$1:$K$1) dans laquelle se trouve la valeur cherchée ($M4).
Si on décale A1 de cette valeur, on se trouve une colonne trop loin, d'où le -1.

 

[bbloup47]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Merci hoerwind, je saisis beaucoup mieux à présent.

passe une bonne journée

 

[hoerwind]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Bonjour,

Heureux que j'ai pu t'aider !

J'avais oublié de te signaler que pour ton exemple il n'est pas nécessaire d'imbriquer trois formules SI, mais que cette imbrication peut se faire dans une même formule.

Un exemple sera sans doute plus clair :
O4 : RECHERCHEV($N4;SI($M4=$A$1;$A$3:$C$21;SI($M4=$E$1;$E$3:$G$21;$I$3:$K$21));COLONNE()-13;0)
cette formule peut être copiée vers le bas et vers la droite.

 

[bbloup47]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Merci hoerwind cette formule est un vrai charme à comprendre 🙂
Je crois même que c'est elle que je vais intégrer à mon classeur.

encore merci et bonne journée

 

[bbloup47]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Suite... j'ai intégré la dernière formule et ça fonctionne vraiment bien sauf qu'il y a des NA qui apparaissent...j'ai voulu imbriquer SI(ESTNA mais ça me répond que le nombre maximum d'imbrication est atteint; j'ai un RECHERCHEV ET 7 SI IMBRIQUÉS... est ce qu'il y a un autre moyen de faire disparaitre les NA ????

merci @+

 

[hoerwind]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Bonjour,

La méthode les plus courante pour supprimer un #N/A est la suivante :
=SI(ESTERREUR(la formule);"";la formule)
Mais il se peut que Excel refuse cette formule car il y a une imbrication de 8 SI, sauf si tu es sur XL2007.
Dans ce cas tu peux dissocier cette dernière formule en deux formules en les concaténant, ou nommer des parties de la formule.

Quoiqu'il en soit, avec la 1ère formule proposée (DECALER) il ne devarit pas il y a voir ce problème d'imbrications.

D'après ce que je comprends, puisque tu travailles avec des listes déroulantes pour le choix, tu ne peux avoir ce message d'erreur que lorsque tu modifies ton premier choix (les en-têtes des petits tableaux) et que n'as pas encore modifié le deuxième choix.
Dans ce cas tu peux aussi appliquer une MFC (mise en forme conditionnelle) sur la cellule du 2ème choix (couleur police = couleur motif).

Si tu ne t'en sors pas, mets un exemple en pièce jointe, ce sera plus facile pour te proposer une ou plusieurs solutions.

 

[bbloup47]

Re : Imbriquer "SI" "rechercheV" plusieurs fois

Merci hoerwind de me répondre, je fait des test la dessus aujourd'hui avec tes suggestions et je te reviens. Merci encore et bonne journée

@+

bonjour hoerwind, j'ai fait plusieurs test aujourd'hui et je suis parvenu à un bon résultat sur le fichier original avec la suggestion de Monique soit avec sommeprod (non sans difficultées). maintenat je m'attaque à decaler histoire d'en venir à bout aussi avec cette formule. merci encore et je te tiens au courant de mes progrès si cela ne te dérange pas bien sur.

merci encore et @+