Microsoft 365 Générer des quiitances de Loyer

flegeo.d@gmail.com · 5 Février 2026

Bonjour,

J'ai un fichier pour génerer des quittances de loyer mensuel.
Cependant, quand j'enregistre tous les mois mes quittances, elles s'enregistrent tous les mois sous le même nom de fichier.
Exemple:
Appart 01.pdf
Appart 02.pdf
Appart 03.pdf
....

Je souhaiterais que chaque mois, lors de l'enregistrement, il y ait le mois et l'année qui apparaissent devant (Janvier 2026 Appart 01.pdf et ainsi de suite .....).
Et là, je ne sais pas comment faire ça.
Est ce que quequ'un pourrait me modifier mon fichier dans ce sens?
Merci d'avance

TooFatBoy · 5 Février 2026

Bonjour,

Une proposition :

VB:

Sub printpdf()
    Application.ScreenUpdating = False
    chemin = "C:\Users\flege\OneDrive\Bureau\QUITTANCES CHOISEUL\" ' adapter le chemin
    Suffixe = " ( " & Format(Sheets("Locataires").Range("E3"), "mmmm yyyy") & " )"
    For Each ws In ThisWorkbook.Worksheets
        Select Case ws.Name
            Case "Locataires", "Quittance modiffiable" 'ne pas imprimer ces feuilles
            Case Else
                nf = chemin & ws.Name & Suffixe & ".pdf"
                On Error Resume Next
                Kill nf 'on efface le fichier pdf s'il existe déjà
                On Error Resume Next
                ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                nf, Quality:=xlQualityStandard, _
                IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
                False
        End Select
    Next ws
End Sub

Rheeem · 5 Février 2026

Cependent enregistrer sous ce format peut entraîner une confusion dans l'ordre des fichiers générés dans l'exploreur vaux mieux utiliser "yyyy-mm" 2026-02

TooFatBoy · 5 Février 2026

Rheeem à dit:
Cependent enregistrer ce sous ce format peut entraîner une confusion dans l'ordre des fichiers générés dans l'exploreur vaux mieux utiliser "yyyy-mm" 2026-02

C'est l'avantage d'utiliser Format : tu mets sous le format que tu veux. 😉

Et en français, sauf erreur de ma part, il n'y a pas d'espace après une parenthèse ouvrante, ni avant une parenthèse fermante. J'en ai pourtant mis.

Il y a aussi les espaces qui sont de potentielles sources de problèmes. Mais j'en ai quand même mis.

J'ai aussi mis la "date" en suffixe, alors que dans l'explorateur de fichiers il serait peut-être plus pratique de la mettre en préfixe.

Bref. Je pense que maintenant le demandeur a une méthode sur laquelle il peut s'appuyer pour fabriquer les noms qu'il veut. 😉

flegeo.d@gmail.com · 5 Février 2026

TooFatBoy à dit:

Bonjour,

Une proposition :

VB:

Sub printpdf()
    Application.ScreenUpdating = False
    chemin = "C:\Users\flege\OneDrive\Bureau\QUITTANCES CHOISEUL\" ' adapter le chemin
    Suffixe = " ( " & Format(Sheets("Locataires").Range("E3"), "mmmm yyyy") & " )"
    For Each ws In ThisWorkbook.Worksheets
        Select Case ws.Name
            Case "Locataires", "Quittance modiffiable" 'ne pas imprimer ces feuilles
            Case Else
                nf = chemin & ws.Name & Suffixe & ".pdf"
                On Error Resume Next
                Kill nf 'on efface le fichier pdf s'il existe déjà
                On Error Resume Next
                ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                nf, Quality:=xlQualityStandard, _
                IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
                False
        End Select
    Next ws
End Sub

Merci de votre réponse. Etant novice en la matière d'Excel, pourriez vous me l'intégrer dans mon fichier Svp?

TooFatBoy · 5 Février 2026

- Ouvre le classeur
- Fais <Alt>+<F11>
- Double-clique sur "Module1"
- Remplace la macro présente dans ledit module par celle proposée ici en #2.

flegeo.d@gmail.com · 5 Février 2026

TooFatBoy à dit:
- Ouvre le classeur
- Fais <Alt>+<F11>
- Double-clique sur "Module1"
- Remplace la macro présente dans ledit module par celle proposée ici en #2.

Un grand Merci pour vos conseils . ça fonctionne nickel comme je le souhaitais. Génial. MERCI

flegeo.d@gmail.com · 5 Février 2026

TooFatBoy à dit:

Bonjour,

Une proposition :

VB:

Sub printpdf()
    Application.ScreenUpdating = False
    chemin = "C:\Users\flege\OneDrive\Bureau\QUITTANCES CHOISEUL\" ' adapter le chemin
    Suffixe = " ( " & Format(Sheets("Locataires").Range("E3"), "mmmm yyyy") & " )"
    For Each ws In ThisWorkbook.Worksheets
        Select Case ws.Name
            Case "Locataires", "Quittance modiffiable" 'ne pas imprimer ces feuilles
            Case Else
                nf = chemin & ws.Name & Suffixe & ".pdf"
                On Error Resume Next
                Kill nf 'on efface le fichier pdf s'il existe déjà
                On Error Resume Next
                ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                nf, Quality:=xlQualityStandard, _
                IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
                False
        End Select
    Next ws
End Sub

Un grand Merci pour vos conseils . ça fonctionne nickel comme je le souhaitais. Génial. MERCI

TooFatBoy · 5 Février 2026

flegeo.d@gmail.com à dit:
Un grand Merci pour vos conseils . ça fonctionne nickel comme je le souhaitais. Génial. MERCI

Comme l'a fort justement suggéré Rheeem, si tu as compris le principe tu peux modifier le format que j'ai arbitrairement imposé pour le nom du fichier (préfixe au lieu de suffixe, mois écrit en nombre plutôt qu'en texte, etc.).

Je viens de relire ta question initiale, et c'est d'ailleurs un préfixe que tu demandais, et moi j'ai proposé un suffixe... 🙄

Si tu n'arrives pas à donner le format exact que tu veux pour les noms de tes fichiers, n'hésite pas à le dire, on verra ce qu'on peut faire. 😉

patricktoulon · 5 Février 2026

bonsoir
juste en passant moi les gestions d'erreurs sauf si indispensables, je m'en passe

VB:

Sub printpdf()
    Dim chemin$, ws As Worksheet, Nf$
    Application.ScreenUpdating = False
    
    chemin = "C:\Users\flege\OneDrive\Bureau\QUITTANCES CHOISEUL" ' adapter le chemin
    If Dir(chemin, vbDirectory) = "" Then MsgBox "le dossier est inaccessible" & vbCrLf & "Vérifiez l'existence du dossier", vbInformation: Exit Sub
    
    For Each ws In ThisWorkbook.Worksheets
        
        Select Case Left(ws.Name, 6)
                
            Case "Appart"
                Nf = chemin & "\" & ws.Name & "_" & Format([Locataires!E3].value, "mmmm yyyy") & ".pdf"
                If Dir(Nf) <> "" Then Kill Nf 'on efface le fichier pdf s'il existe déjà
                ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:=Nf, Quality:=xlQualityStandard, _
                                                IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
            Case Else
        End Select
    Next ws
    Application.ScreenUpdating = True
End Sub

Valtrase · 6 Février 2026

Bonjour à tous,

juste en passant moi les gestions d'erreurs sauf si indispensables, je m'en passe

@patricktoulon
Non Patrick, il ne faut pas que tu apprenne des choses comme cela aux néophytes.
Bon regardons cela de plus près...
Sur la ligne :

VB:

Nf = chemin & "\" & ws.Name & "_" & Format([Locataires!E3].value, "mmmm yyyy") & ".pdf"

Tu utilises les crochets pour faire référence à une cellule de la feuille. Excel n'interprétera cela qu'au moment de l'exécution; Et pas au moment de la compilation.
Faisons un test supprimons le "s" de locataires, que va t-il se passer selon toi ? Excel ne va rien voir au moment de la compilation, mais au moment de l'exécution tu va avoir droit à une belle fenêtre du débogueur.

Cette erreur pourrait être interceptée par une gestion d'erreur, n'est-ce pas ? Où mieux une fonction pourrait renvoyer une variable de type Excel.Worksheet, il ne resterait plus qu' a tester si elle est égale à 'Nothing', et décider de la suite à donner...
Mon conseil même si cela demande un peu plus d'investissement et d'écritures. et pour respecter le SRP

Utiliser de petite fonction qui n'ont qu'un rôle
- Tester la validité d'un chemin.
- Tester la présence d'une feuille.
- Etc...

La méthode PrintPdf comme son nom l'indique ne devrait qu'imprimer le fichier au format PDF. (Ici elle l'exporte) son nom prête à confusion, Non ?
Patrick, Je prends quand même note que le code était déjà pré rédigé, et que tu l'as juste adapté. 😉

@flegeo.d@gmail.com puisque vous avez : un tableau de locataires, et un feuille modèle pour l'impression des quittances, pourquoi ne pas l'utiliser ? Vous pourriez les enregistrer au format Pdf dans un répertoire de votre choix et ne garder, dans votre classeur que le strict minimum.
Vous pourriez aussi ajouter une colonne dans le tableau locataires pour y ajouter par exemple un acompte qui aurait été versé.

patricktoulon · 6 Février 2026

bonjour @valtraze
argument non recevable
pour la simple et bonne raison que le"s" peut très bien être oublié dans l'autre contexte( en variablisation
exemple ici

VB:

 Suffixe = " ( " & Format(Sheets("Locataire").Range("E3"), "mmmm yyyy") & " )"

le résultat serait le même ca plante une ligne plus haut c'est tout
après oui je suis d'accords presque tout ce que les débutants gèrent avec on error peut l'être autrement

@flegeo.d@gmail.com puisque vous avez : un tableau de locataires, et un feuille modèle pour l'impression des quittances, pourquoi ne pas l'utiliser ? Vous pourriez les enregistrer au format Pdf dans un répertoire de votre choix et ne garder, dans votre classeur que le strict minimum.
Vous pourriez aussi ajouter une colonne dans le tableau locataires pour y ajouter par exemple un acompte qui aurait été versé.

là oui par contre j'abonde deux fois même c'est ce que j'ai pensé la première fois que j'ai ouverts le fichier
mais je me suis dit peut être fait il toutes ses quittances et les imprimes toutes en même temps
d'ailleurs n'est il pas fait dans ce sens le code
cela dit oui après impression on peut virer
c'est un choix

Valtrase · 7 Février 2026

Bonjour à tous, Patrick
On ne se comprends pas bien, ce que je pointe c'est le fait que tu dise que si tu peux te passer de la gestion d'erreur tu le fait. Dans ce cas là elle devient nécessaire et même obligatoire, je dirais. Car si il y a un problème, c'est le débogueur qui va prendre le relais avec une belle fenêtre de débogage.
Pour ma part, (ce n'est peut-être pas la meilleure méthode) j'initialise toujours mes tableaux dans un module 'Factory' avec une fonction qui renvoie un 'ListObject', comme cela plus besoin de me tracasser sur le nom du tableau et de sa feuille parente. L'avantage c'est que l'on a plus qu'a tester si le 'ListObject' est à 'Nothing'. Et cela ne lève pas d'erreur.
Donc pour moi la gestion d'erreur est pratiquement obligatoire :

Quand on travaille avec le propriété 'EnableEvents' de l'application. (Tout le monde comprendra pourquoi.)
Si l'on travaille sur des 'ListObjects', 'ListRows' etc...
Si l'on travaille sur une feuille qui peut être protégée.
Etc....

Dans tout les cas, je pars sur le principe que ce n'est pas le code le plus court le meilleur, (Comme j'entends souvent sur le forum.)

Bonne programmation à tous,

TooFatBoy · 7 Février 2026

Valtrase à dit:
Pour ma part, (ce n'est peut-être pas la meilleure méthode) j'initialise toujours mes tableaux dans un module 'Factory' avec une fonction qui renvoie un 'ListObject', comme cela plus besoin de me tracasser sur le nom du tableau et de sa feuille parente. L'avantage c'est que l'on a plus qu'a tester si le 'ListObject' est à 'Nothing'. Et cela ne lève pas d'erreur.

Tu pourrais peut-être ouvrir un fil discussion pour expliquer ta méthode qui semble "magique".
En tout cas, moi ça m'intéresse.

patricktoulon · 7 Février 2026

re

On ne se comprends pas bien, ce que je pointe c'est le fait que tu dise que si tu peux te passer de la gestion d'erreur tu le fait. Dans ce cas là elle devient nécessaire et même obligatoire

non mon test dir joue le rôle de fusible

Microsoft 365 Générer des quiitances de Loyer

flegeo.d@gmail.com

XLDnaute Nouveau

Pièces jointes

TooFatBoy

XLDnaute Barbatruc

Rheeem

XLDnaute Occasionnel

TooFatBoy

XLDnaute Barbatruc

flegeo.d@gmail.com

XLDnaute Nouveau

TooFatBoy

XLDnaute Barbatruc

flegeo.d@gmail.com

XLDnaute Nouveau

flegeo.d@gmail.com

XLDnaute Nouveau

TooFatBoy

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Valtrase

XLDnaute Occasionnel

patricktoulon

XLDnaute Barbatruc

Valtrase

XLDnaute Occasionnel

TooFatBoy

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Discussions similaires

Microsoft 365 Générer des quiitances de Loyer

XLDnaute Nouveau

Pièces jointes

XLDnaute Barbatruc

XLDnaute Occasionnel

XLDnaute Barbatruc

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Nouveau

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Occasionnel

XLDnaute Barbatruc

XLDnaute Occasionnel

XLDnaute Barbatruc

XLDnaute Barbatruc

Discussions similaires

Privacy & Transparency

Privacy & Transparency