Formules imbriquées

[aandre01]

Je souhaite imbriquer plus de 7 formules dans excel.
Pourriez-vous me donner la manip pour résoudre ce problème.
Ex:je vais chercher une valeur en fonction des mois de l'année. (Si XX=01; ZZ) Lorsque j'arrive à 7 mois, impossible d'imbriquer les formules.

 

[Ronan]

Bonsoir à tous,

La méthode la plus simple pour imbriquer plusieurs formules est la suivantes :

Inscrire chaque formule dans des cellules adjacentes (par exemple en ligne)
1ère formule inscrite par exemple en b1
2ème formule inscrite en c1
3ème formule inscrite en d1
etc....

On constatera que en faisant F2 sur une cellule contenant une formule, la référence à une autre cellule se met en couleur ainsi que la cellule concernée.

Pour imbriquer le tout, rien de plus simple. on commence par l'avant dernière formule saisie.On fait F2, puis on sélectionne toute la formule, on la copie et on appuie sur la touche ENTREE.
On sélectionne la dernière cellule contenant la formule saisie puis on fait F2.
On sélectionne toute la partie faisant référence à la cellule contenant la formule que l'on vient de copier (la partie colorée de la même couleur que la cellule précédente). On colle à la place la formule copiée et ainsi de suite jusqu'à n'avoir plus qu'une seule formule.

Si cela réponds à ta question.

@+

Ronan

 

[Jean-Marie]

Bonsoir, André, Ronan

Il y a plusieurs possibilités pour éviter l'imbrication des si().
André mais un fichier zippé de ton problème.

Bonne soirée.

@+Jean-Marie

 

[aandre01]

Salut à tous,
Excusez pour le retard, je vous joins un fichier zippé de mon problème.


@ndré.

 

[Monique]

Bonjour,

C'est quoi, le "EST" au début de la formule ?
Voici une formule qui fait la somme des colonnes O ou Q ou S ou U etc si A4 = 1 ou 2 ou 3 ou 4 etc jusqu'à 12

Le signe * équivaut au ET des formules conditionnelles
Le signe + équivaut au OU
On peut aller jusqu'à 30 critères (ça fait quand même 2 ans 1/2)

=SOMMEPROD((($A$4=1)*$O$2:$O$15000)+(($A$4=2)*$Q$2:$Q$15000)+(($A$4=3)*$S$2:$S$15000)+(($A$4=4)*$U$2:$U$15000)+(($A$4=5)*$W$2:$W$15000)+(($A$4=6)*$Y$2:$Y$15000)+(($A$4=7)*$AA$2:$AA$15000)+(($A$4=8)*$AC$2:$AC$15000)+(($A$4=9)*$AE$2:$AE$15000)+(($A$4=10)*$AG$2:$AG$15000)+(($A$4=11)*$AI$2:$AI$15000)+(($A$4=12)*$AK$2:$AK$15000))

 

[Jean-Marie]

Bonjour

Déjà en premier lieu, je fais une petite mise en forme style VBA de ta formule, et franchement ça aide.

=SOMME.SI('C:\Gestion\CA\[CA.xls]CA'!$A$2:$A$15000;"EST";
SI($A$4=1;'C:\Gestion\CA\[CA.xls]CA'!$O$2:$O$15000;
SI($A$4=2;'C:\Gestion\CA\[CA.xls]CA'!$Q$2:$Q$15000;
SI($A$4=3;'C:\Gestion\CA\[CA.xls]CA'!$S$2:$S$15000;
SI($A$4=4;'C:\Gestion\CA\[CA.xls]CA'!$U$2:$U$15000;
SI($A$4=5;'C:\Gestion\CA\[CA.xls]CA'!$W$2:$W$15000;
SI($A$4=6;'C:\Gestion\CA\[CA.xls]CA'!$Y$2:$Y$15000
)
)
)
)
)
)
)

Que voit-on dans ta formule que la plage du 3ème argument bouge en fonction du mois.
1ère plage, colonne O (la 15ème)
2ème plage, colonne Q (la 17ème)
3ème plage, colonne S (la 19ème)
...
Donc la plage de calcul de la fonction somme.si, commence en colonne 0 avec 1 colonne entre chaque mois.

Avec d'autres fonctions, tu peux arriver au même résultat.

En utilisant la fonction Index(;0
=SOMME.SI('C:\Gestion\CA\[CA.xls]CA'!$A$2:$A$15000;"EST";INDEX('C:\Gestion\CA\[CA.xls]CA'!$O$2:$AL$15000;0;(($A$4-1)*2)+1))

en utilisant la fonction Decaler(;
=SOMME.SI('C:\Gestion\CA\[CA.xls]CA'!$A$2:$A$15000;"EST";DECALER('C:\Gestion\CA\[CA.xls]CA'!$O$2:$O$15000;;(($A$4-1)*2))

Il y a en d'autres.

En espérant avoir montré une autre approche de ton problème, je te souhaite une bonne journée

@+Jean-Marie

 

[Jean-Marie]

Re...

Pour la présentation de la formule façon VBA c'est raté.

Dommage

@+Jean-Marie

 

[Jean-Marie]

Oups, il manque une parenthèse fermante à la fin de la formule.

@+Jean-Marie

 

[aandre01]

Merci à tous de votre aide, c'est super.
Pour monique, à titre d'information le "EST" correspondait en fait à la région EST mais tu ne pouvais pas le savoir.
Encore merci

@ndré.