Formule trop longue ! simplification ?

[ya_v_ka]

Salut tout le monde,

Et re'v'là qu'ca coince... une formule qui me servait depuis 10 ans pourtant, mais je dois rajouter 30 colonnes..et l'annonce "formule trop longue" me bloque...
voilà ce que j'ai:
=($C$36*C10)+($E$36*E10)+($G$36*G10).....etc jusqu'à......($II$36*II10)+($IK$36*IK10)+($IM$36*IM10)+($IO$36*IO10)+($IQ$36*IQ10)+($IS$36*IS10)+($IU$36*IU10)
et pour bien faire faudrait aller jusqu'à HI, alors si quelqu'un voit une simplification de formule... je suis preneur
Merci d'avance à toutes et tous
ya'v

 

[Rénato]

Ya plus qu'à...... utiliser sommeprod, et je crois qu'on peut pas faire plus court !!!

=SOMMEPROD((C36:IU36)*(C10:IU10))

Et on pense bien à faire brûler un cierge pour la sainte MONIQUE.


Cordialement

Rénato

 

[Monique]

Bonjour,

=SOMMEPROD((MOD(COLONNE(C10:HI10);2)=1)*(C10:HI10*C36:HI36))
Ne prend en compte que les colonnes impaires. Mod(valeur;2)=1

 

[ya_v_ka]

Merci vous deux
mais avant que je ne m'énerve, si j'ai bien compris je n'ai qu'à remplacer le 1 par un 0 pour prendre en compte les colonnes paires...
encore merci et bonne soirée ;-)
Ya'v

 

[ya_v_ka]

et pendant que je suis par là, je dois REmercier Monique encore une fois, je viens de ressortir ton dernier conseil pour les listes de validations plus petites que la zone à remplir... je commence à me demander ce que je ferais sans toi...
Merci
Ya'v

 

[Monique]

Re,

Oui, tu remplaces le 1 par un 0 pour les colonnes paires.
Tu peux jouer à le faire 1 colonne sur 3, aussi
Mod(valeur;3)=1 ou 2 ou 0

 

[ya_v_ka]

Merci,
malheureusement ca ne marche pas ....

=($C$36*D11)+($E$36*F11)+($G$36*H11)+...........etc.......+($HC$36*HD11)+($HE$36*HF11)+($HG$36*HH11)+($HI$36*HJ11)

voilà ce que j'avais dans l'autre colonne....

;-/ un Ya'v tout triste d'être aussi Na'v.....

 

[ya_v_ka]

Oups, désolé, je l'ai...
crié au loup trop tôt... un parasite s'était glissé dans la formule, mais là c'est bon alors
M E R C I encore et encore et..... à mon prochain problème ;-)

ya'v

 

[Monique]

Re,

Elle est toute faite, je te la donne quand même (ça peut servir)
La 1ère :
=SOMMEPROD((MOD(COLONNE($C$10:$HJ$10);2)=1)*($C$10:$HJ$10*$C$36:$HJ$36))

La 2ème :
=SOMMEPROD((MOD(COLONNE($C$10:$HJ$10);2)=1)*(DECALER($C$10:$HJ$10;1;1)*$C$36:$HJ$36))
En fait, pour la 2ème, tu fais croire à Excel que tu ne prends en compte que les colonnes impaires,
mais tu décales la plage C10:HJ10 d'une ligne vers le bas et d'une colonne vers la droite.

 

[ya_v_ka]

hello, ;-)

grrrrr v'la qu'elle m'embrouille...

moi j'avais:
=SOMMEPROD((MOD(COLONNE(C10:HI10);2)=1)*(C10:HI10*$C$36:$HI$36)) que tu m'as donné et pour la colonne paire j'ai changé en:
=SOMMEPROD((MOD(COLONNE(D10:HJ10);2)=0)*(D10:HJ10*$C$36:$HI$36))
qui fonctionne (il me semble) à merveille... et ce grace à qui ???

Merci
Ya'v

 

[Monique]

Re,

Si ça marche, c'est bon.
C'était au cas où tu n'aurais pas crié au loup trop tôt.

 

[ya_v_ka]

re ;-)

et en plus si je comprends qqchose, en décalant d'une colonne, ca marcherais, mais en décalant aussi d'une ligne j'arriverais à des résultats etonnants...

mais en tous cas merci pour le "décoincage"... ;-)
ya'v

 

[Rénato]

Désolé ya'v ka,

Dans ma réponse, je n'ai pas intégré ton besoin relatif aux colonnes impaires, mais je vois que Monique a rectifié immédiatement le tir.

Bonne journée.

Rénato

 

[Jean-Marie]

Bonjour tout le monde

Dans cette formule =SOMMEPROD((MOD(COLONNE($C$10:$HJ$10);2)=1)*($C$10:$HJ$10*$C$36:$HJ$36)), il est inutile de faire une comparaison =1 la valeur à obtenir étant la valeur 1 ou 0
=SOMMEPROD(MOD(COLONNE($C$10:$HJ$10);2)*($C$10:$HJ$10*$C$36:$HJ$36))

Ce n'est valable que pour la colonne impaire,

Dans le cas d'une colonne paire il y a aussi cette possibilité.
=SOMMEPROD(non(MOD(COLONNE($C$10:$HJ$10);2))*($C$10:$HJ$10*$C$36:$HJ$36))


@+Jean-Marie