Formule "si" imbriqué

[Diop]

Bonjour à tous
j'ai un souci dans une formule de "si" imbriqué qui a cette tete

SI($H4<I$2;F4*0;SI(ET($H4>I$2;$H4>=I$3);F4*1;$F$4/360*JOURS360(I$2;$H4))))

Jusque là çà marche mais apres j'ai besoin de rajouetr une autre condition qui est la suivant s'il trouve dans la cellule colonne g le symbole "$" alors de me convertir les donnees avec un cours qui se trouve dans la cellule p4
donc de me faure f4*0*p4 ainsi de suite
mais çà ne marche pas lorsque j'essaie d'ajouter cette derniere condition
SI(G4="$)

merci de votre aide

 

[Monique]

Bonjour,

=SI($H4<I$2;F4*0*SI(G4="$";P4;1);SI(ET($H4>I$2;$H4>=I$3);F4*1*SI(G4="$";P4;1);$F$4/360*JOURS360(I$2;$H4)*SI(G4="$";P4;1)))
Mais * 0 n'est pas utile, donc :
=SI($H4<I$2;0;SI(ET($H4>I$2;$H4>=I$3);F4*SI(G4="$";P4;1);$F$4/360*JOURS360(I$2;$H4)*SI(G4="$";P4;1)))
Mais il te manque la condition = I2. Et les 2 conditions > I2 et > I3, les 2 ensemble, ça ne va pas,
il doit y avoir une inversion de signe, donc :
=SI($H4<I$2;0;SI(ET($H4>=I$2;$H4<=I$3);F4*SI(G4="$";P4;1);$F$4/360*JOURS360(I$2;$H4)*SI(G4="$";P4;1)))

 

[Diop]

monique je n'ai pas trop bien compris ta formule
je vois que tu as procede à des simplifications mais je ne vois pas où est ce que tu veux en venir

merci

 

[Dugenou]

Diop, Monique,

Il me semble qu'il suffit d'ajouter à la formule de Diop :

*si(G4="$";p4;1) soit au final :

=SI($H4<I$2;F4*0;SI(ET($H4>I$2;$H4>=I$3);F4*1;$F$4/360*JOURS360(I$2;$H4))))*SI(G4="$";p4;1)

Salut

[http://annuaire.coolgifs.free.fr/gifs/smileys/04.gif]

 

[Dugenou]

ooouups

j'utilisais le xla de composition des posts pour la première fois et j'étais sur wiki et pas sur post !!

La honte

 

[Monique]

Bonjour,

Mais oui, bien sûr et elle est beaucoup plus facile à lire.
Sauf que j'insiste : multiplier F4 par 0 revient à taper 0
Multiplier F4 par 1 revient à taper F4
> I2 et > I3, c'est plutôt >= I2 et <=I3 (si I2 est sup au plus grand des 2, il est aussi supérieur au plus petit)
Mais... on ne sait pas où est le petit et où est le grand.

Sinon, c'est la formule entière qui est à multiplier par *SI(G4="$";P4;1)
Et ça donne :
=(SI($H4<I$2;0;SI(ET($H4>=I$2;$H4<=I$3);F4;$F$4/360*JOURS360(I$2;$H4))))*SI(G4="$";P4;1)

Alors, Diop, tu n'as plus besoin d'explications, du coup.