formule recherche 3 feuils excel

[jebbayou]

Bonjour a tous,
voila je vous expose mon problème:

j'ai 3 feuils excel feuil1, feuil2, feuil3 et je veux:

algotithme : si ( (c2 feuil1 trouvé dans feuil2) et (k1= ou k1=dsl dans feuil2) ) alors faire (rechercher a1 dans feuil 3 et afficher I1)

j'ai utilisé cette formule mais elle ne marche pas :

=SI(ET(RECHERCHEV(C2;feuil2!A:AK;0);OU(K1="DSL";K1="TEL";K1="IPM";K1="VGA"));RECHERCHEV(A1;feuil3!A:I;8;"pas de test");FAUX).

merci de votre aide je galère depuis 3 jours.

 

[Tibo]

Re : formule recherche 3 feuils excel

Bonjour,

Sans fichier, pas évident de bien cerner ton problème.

La formule RECHERCHEV fonctionne comme suit :

=RECHERCHEV(valeur_cherchée;base_données;n°_colonne;0)

Dans le 1er RECHERCHEV que tu nous soumets, il manque le n° de colonne

Dans le 2ème, on y trouve "pas de test" ???

il manque sans doute ;0) après le 8 (qui doit correspondre au n° de colonne).

Je te laisse tenter de corriger.

Si problème persiste, reviens avec un extrait de ton fichier (anonymisé).

@+

 

[jebbayou]

Re : formule recherche 3 feuils excel

alors j'ai esayé de creer un fichier exemple normalement il est bon.
donc le resultat est sur la la colonne b de la feuil 2.
le resultat doit etre la colonne I de la feuil 3 par rapport aux condition.

merci pour votre aide.

 

[Tibo]

Re : formule recherche 3 feuils excel

re,

Pas compris grand chose.

Peut-être ceci en B2 (Feuil1) :

=SI(NB.SI(Feuil2!A:A;Feuil1!C2)>0;SI(OU(H2="DSL";J2="TEL";J2="IPM";J2="VGA");
INDEX(Feuil3!I:I;EQUIV(Feuil1!A2;Feuil3!E:E;0));""))

à recopier vers le bas

Si pas ça, reviens en nous indiquant manuellement pour les 5 lignes de ton fichier les résultats attendus. Connaissant le résultat, on pourra peut-être comment rechercher celui-ci.

A te (re)lire

@+

 

[jebbayou]

Re : formule recherche 3 feuils excel

non ca ne retourne rien.
donc dans b2:LBE, b3:LBE, b4😀SQ, b5:vide, b6:vide.
en gros c la colonne I de la feuil 3 mais ca doit passé par toutes les conditions avant.

voila

 

[Tibo]

Re : formule recherche 3 feuils excel

re,

Avec ceci :

=SI(ET(NB.SI(Feuil2!A:A;C2);OU(K2="DSL";K2="TEL";K2="IPM";K2="VGA"));
RECHERCHEV(A2;Feuil3!E:I;5;0);"")

Souci :

Tu nous indiques que pour la colonne K, on doit avoir DSL ou REL ou IPM ou VGA, or dans ton fichier, on a ni l'un ni l'autre...

Je te laisse tester avec les valeurs en colonne K correspondant aux valeurs prévues dans la formule.

@+

Edit : dans ton premier post, tu fais référence à la colonne K et dans ton dernier fichier joint, tu fais référence aux colonnes H et J...

Que faut-il retenir ?

@+

 

[jebbayou]

Re : formule recherche 3 feuils excel

en fait c J et non K et cette colonne est sur la feuil2.donc la condition est que j egale soit dsl ou ipm ou ...dans la feuil 2.

 

[Tibo]

Re : formule recherche 3 feuils excel

rere,

On va finir par avoir les bonnes infos ...

Essaye avec :

=SI(ESTNUM(EQUIV(INDEX(Feuil2!J:J;EQUIV(C2;Feuil2!A:A;0));
{"DSL";"TEL";"IPM";"VGA"};0));INDEX(Feuil3!I:I;EQUIV(A2;Feuil3!E:E;0))&"";"")

à recopier vers le bas

@+

 

[jebbayou]

Re : formule recherche 3 feuils excel

ca a l'air de fonctionner je vais quand meme l'essayé sur le gros fichier demain au boulot et je reviendrai vers toi.

Merci pour ton aide et ca fait plaisir de voir qu'il y a des personne comme toi.

 

[jebbayou]

Re : formule recherche 3 feuils excel

Bonjour TIBO,

donc j'ai essayé la formule sur le gros fichier et ca ne fonctionne pas elle me retourne #N/A j'ai verifié toutes les conditions qui sont bien vrai.
j'ai isolé un cas en PJ si tu peux regarder ca ???.

merci

 

[Tibo]

Re : formule recherche 3 feuils excel

Bonjour,

La valeur en A2 Feuil1 est dans un format Texte alors que la valeur en E2 (Feuil3) est dans un format numérique.

Pour Excel, ce n'est pas la même chose.

Je te propose ceci :

=SI(ESTNUM(EQUIV(INDEX(Feuil2!K:K;EQUIV(C2;Feuil2!A:A;0));
{"DSL";"TEL";"IPM";"VGA"};0));INDEX(Feuil3!I:I;EQUIV(A2[B][COLOR=red]*1[/COLOR][/B];Feuil3!E:E;0))&"";"")

ou

=SI(ESTNUM(EQUIV(INDEX(Feuil2!K:K;EQUIV(C2;Feuil2!A:A;0));
{"DSL";"TEL";"IPM";"VGA"};0));INDEX(Feuil3!I:I;EQUIV(A2[B][COLOR=red]&""[/COLOR][/B];Feuil3!E:E;0))&"";"")

Je te laisse tester les 2 hypothèses

@+