Power Query Formule power query qui renvoie une erreur

Expression.Error : Désolé... Nous n'avons pas pu appliquer l'opérateur < aux types Number et Time.
Détails :
    Operator=<
    Left=0,791666667
    Right=18:32:00

• tu fait cette comparaison : Time.From([Début Intervention]) < 1/24 * 19 > à remplacer par Time.From([Début Intervention]) < Time.From(1/24 * 19)
• tu fait ce calcul : Time.From([Fin Intervention]) - 1/24 * 19 > à remplacer par Time.From([Fin Intervention]) - Time.From(1/24 * 19)
• tu fait cette comparaison : Time.From([Début Intervention]) < 1/24 * 7 > à remplacer par Time.From([Début Intervention]) < Time.From(1/24 * 7)
• tu fait ce calcul : 1/24 * 7 - Time.From([Début Intervention]) > à remplacer par Time.From(1/24 * 7) - Time.From([Début Intervention])
• tu fait ce calcul : [Fin Intervention] - (Date.From([Début Intervention]) + 1/24 * 19) > à remplacer par DateTime.From([Fin Intervention]) - (DateTime.From([Début Intervention]) + Duration.From(1/24 * 19))

mromain à dit:

Bonjour Menibelus, merinos, le forum,

Ci-dessous un essai :

PowerQuery:

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    TypesModifiés = Table.TransformColumnTypes(Source,{{"Début Intervention", type datetime}, {"Fin Intervention", type datetime}}),
    AjoutColonneDépassement = Table.AddColumn(TypesModifiés, "Dépassement", each
        let
            interventionPeriod = [From=[Début Intervention], To=[Fin Intervention]],
            fnIntersect = (P1 as record, P2 as record) as duration => List.Max({#duration(0,0,0,0), List.Min({P1[To], P2[To]})-List.Max({P1[From], P2[From]})}),
            daysList = {Number.From(Date.From([Début Intervention])) .. Number.From(Date.From([Fin Intervention]))},
            periodsList = List.Combine(List.Transform(daysList, each {[From=DateTime.From(_)+#duration(0,0,0,0), To=DateTime.From(_)+#duration(0,7,0,0)], [From=DateTime.From(_)+#duration(0,19,0,0), To=DateTime.From(_)+#duration(0,24,0,0)]})),
            intersectList = List.Transform(periodsList, each fnIntersect(interventionPeriod, _))
        in
            List.Sum(intersectList), type duration)
in
    AjoutColonneDépassement

A+

Cliquez pour agrandir...