XL 2016 formule pour somme plage contigue

[rafi93]

bonjour à tous

je cherche une formule (non VBA) qui me permettrait de sommer une partie de colonne située "juste en dessous à gauche" d'une cellule.
cette formule devrait donc déterminer automatiquement l'ensemble de cellules délimitée par 2 cases vides (ou éventuellement contenant un texte prédéfini pour delimiter la plage)
et encore mieux : retourner une erreur si la plage contient une cellule vide

voir exemple dans cette copie d'écran :
le sous total de ensemble_1 est la somme de C3..C5

existerait il une solution ?

merci !!

 

[job75]

Bonjour rafi93,

Voyez le fichier joint et cette formule matricielle en D2 :

=SI(ESTTEXTE(B2)*ESTVIDE(C2);"Erreur";SI(ESTTEXTE(A2);SOMME(C3:INDEX(C:C;MIN(SI(ESTTEXTE(A$1:A$21)*(LIGNE(A$1:A$21)>LIGNE());LIGNE(A$1:A$21)))));""))

à valider par Ctrl+Maj+Entrée et à tirer vers le bas jusqu'à la ligne 19.

A+

 

[chris]

Bonjour à tous

Une autre également à valider par Ctrl+Maj+Entrée et à tirer vers le bas jusqu'à la ligne précédant le total général

=SI(A2<>"";SOMME(DECALER(C3;0;0;MIN(SI(B3:$B$40="";LIGNE(B3:$B$40);""))-EQUIV("ZZZ";$A$2:A2;1)-1;1));"")

 

[job75]

Bonsoir chris,

Oui effectivement en utilisant DECALER(C3... la formule est plus simple mais je l'écris finalement comme ceci :

=SI((B2<>"")*(C2="");"Erreur";SI(A2="";"";SOMME(DECALER(C3;;;MIN(SI(A3:$A$21<>"";LIGNE(A3:A$21)))-INDEX(LIGNE();1)))))

Le début de la formule répond à cette demande :

et encore mieux : retourner une erreur si la plage contient une cellule vide

Fichier (2).

A+

 

[Modeste geedee]

bonjour à tous

je cherche une formule (non VBA) qui me permettrait de sommer une partie de colonne
voir exemple dans cette copie d'écran :
le sous total de ensemble_1 est la somme de C3..C5

existerait il une solution ?

l'utilisation des fonctionnalités de base des feuilles de calcul permet cette approche ...
sans formule ni VBA !!!

Tableau Croisé Dynamique ...

 

[rafi93]

merci à vous 3 !

ça marche.... presque :
voir fichier joint sur mon exemple, j'ai un sous total "2400" qui apparait en ligne 29, je ne sais pas d'où il sort

pour le tableau croisé, je vais y reflechir mais comme c'est pour rédiger des devis, je crains que je ne sois contraint par la mise en forme

 

[chris]

Re

Cela ne se produit pas avec ma formule

 

[job75]

Re,

Pas de problème avec :

- A$34 à la place de A$32 dans la formule matricielle

- un espace en A34 pour borner la colonne A (puisqu'on teste les textes sur cette colonne).

Votre post #1 montre bien un texte en A21 (ligne du total).

A+

 

[mapomme]

Bonsoir à tous,

Y'a pas de raison, j'y vas aussi 😛

Un essai avec une formule normale en D2, à tirer vers le bas jusqu'à D20:

=SI(A2<>"";D$21-SOMME(C$1:C1)-SOMME(D3:D$20);"")

et une autre formule unique en D21:

=SOMME(C3:C21)

edit: Bonsoir @job75 😉

 

[job75]

Bonsoir mapomme,

Bravo pour cette formule hyper simple, il fallait y penser !

A+

 

[mapomme]

Re,

Je me suis aperçu que le fichier initial joint par rafi93 avait changé de présentation depuis le msg. n°6 -> les données commencent à la ligne 1 au lieu de la ligne 2.
De ce fait, il faut en tenir compte dans la formule en D1 qui devient :

=SI(A1="";"";D$34-SOMME(D2:D$33)-SI(LIGNE()<>1;SOMME(C$1:C1)))

et toujours en D34:

=SOMME(C1:C32)

 

[rafi93]

merci Mapomme !

effectivement très simple, super

et merci aussi à tous

bonne soirée

 

[Modeste geedee]

pour le tableau croisé, je vais y reflechir mais comme c'est pour rédiger des devis, je crains que je ne sois contraint par la mise en forme